gentoo resync : 03.03.2021

2 files changed, 169 insertions, 0 deletions

diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index ec0b582ef662..65a091cf090d 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -9,7 +9,9 @@ AUX twisted-20.3.0-py39-b64.patch 6747 BLAKE2B 1bb6960e5049f43b08e2ba7a56a16616e
 AUX twisted-20.3.0-py39-combined.patch 3752 BLAKE2B 687698bccf6af3213812ae29e7e234c36941f0f7ecfdcfa8c14a6a7b5a433b9ff2a40c2ad870e46b3437210202cf0dc58e17c8d29ebf506c499780355cf60bdb SHA512 81f0b597a7b2609bae5f405388bccf759dd6b0295cf05e6ef2aee76d0f3ab4367a474704aab2753d101be2580d097f30d94acc529035bdb3c3ec43dd035fb733
 DIST Twisted-19.10.0.tar.bz2 3118485 BLAKE2B a0d532b67177aa017e463bf823d7842d4f6ff694f78cd7600865718ffe861023a53ea6a922f7de232133edba26f5255074d7ef277ce8f3bdf02d556ccf4abf41 SHA512 de8d7fd0b2081cebeff68b060c8469377011648bc563a94a993d3530fb007ed42c3a54925c9a10c465ee7a3065cc9108ace12d10d358223fab13494becb9ac4b
 DIST Twisted-20.3.0.tar.bz2 3127793 BLAKE2B 2e85fc3ec26d89e563c9e79a5d2adea81ff1745d18f0f92b8d45ae3729fbddf09998664257880372c7a4caeb5977c5cad7c863596b8c27ad7890275cead9f763 SHA512 1b850e5fc21a3630ead4c2cc3622c16e78bb3be38ab11d021779b7ce3d3c30acc4e19d79c7791a5fce6c5c6e09c2baa349901dffe952de67dd98eec419846365
+DIST twisted-21.2.0.tar.gz 3882978 BLAKE2B ba37572b0f9eadf2962a2730e4c2c0ed65f582b11b3350034660a2c53c5cd0892b19867d19e0201d4808c09fca621dbe540d153dc6c7d5827d45d2423d19d28b SHA512 fa743dcf22f3c17dfd17f39b7df0cc31fb8ce3e989478ada9a026424ec2de35e6a403ef35acdef5905eed008d42e3c2fee6b7ccdda433e6c250f1feaa83ea8a4
 DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
 EBUILD twisted-19.10.0.ebuild 5777 BLAKE2B 163fac4a0cdc830f9be404a69c43287f8594f2a71dacee4d4b37a56e5fd140c060b1a3e765e63bcd4b1a4fefff0bb30a1df007b6f7ad0f01adb0b6ad8f1687ee SHA512 124513b07e486caf4655534cfa0fd3c34facce3f16fe42977d41f2fcd7fa032e3dfd0ea85cf461941539ca8e0768e015809f33c798e49582aaef657aa02ce499
 EBUILD twisted-20.3.0.ebuild 5611 BLAKE2B 598bfa6c58c1acae83610bf1472d49ddf65ba75689e7c76eb356af50b1c786b5201dfb696afc7ab0ac0439878e2119de9f359250d2ba373de146ebe9edb5b37e SHA512 bbebee3ed4a72f34d346dbc38141f2a461b61c3d3a8ca99be711d16ee10a8759aaefc9f780daa0ee2dca589b4f273fb47c69b6b694c19a437ea3ef94d3ca2d14
+EBUILD twisted-21.2.0.ebuild 4685 BLAKE2B 6bd631d322a8a8a48508578a2e4011cf6b1a9434d43e5c93399bd0cb9526aa416dabce547cb8d4ec4c1f18cbee60a06814bc74ce94d4b67c5f7483e4a5981560 SHA512 4eceb533fcde6b215983005c57cb56d273f3300270396715f913a109f6081765e835d0f069e1c6c9432ac3f94facd9ebe4977c144cbb38f896bea2e8c77b9a10
 MISC metadata.xml 1351 BLAKE2B b3a4ccdc922dd4aa902b24b2545f3cc5517b2842c92f1195e8eaa2a8b62558c1ea86059cc23b9ad6a8e6093216a11a01f46360b5ba259e5eadcb351ad3bc0094 SHA512 403d692122913d079c5a93cb5b226f33316776360663a171cd757584d219d0789b24809c9e65840aaeb63eae4cb7cc79258757837abb1e3dd92536369fff6604
diff --git a/dev-python/twisted/twisted-21.2.0.ebuild b/dev-python/twisted/twisted-21.2.0.ebuild
new file mode 100644
index 000000000000..7e25407c0205
--- /dev/null
+++ b/dev-python/twisted/twisted-21.2.0.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="https://www.twistedmatrix.com/trac/"
+SRC_URI="
+	https://github.com/twisted/twisted/archive/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="conch crypt http2 serial test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
+	http2? (
+		>=dev-python/hyper-h2-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/hyper-h2-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+	!dev-python/twisted-core
+	!dev-python/twisted-conch
+	!dev-python/twisted-lore
+	!dev-python/twisted-mail
+	!dev-python/twisted-names
+	!dev-python/twisted-news
+	!dev-python/twisted-pair
+	!dev-python/twisted-runner
+	!dev-python/twisted-words
+	!dev-python/twisted-web
+"
+BDEPEND="
+	>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
+		dev-python/gmpy[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		net-misc/openssh
+	)
+"
+
+S=${WORKDIR}/${PN}-${P}
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# puts system in EMFILE state, then the exception handler may fail
+	# trying to open more files due to some gi magic
+	sed -e '/SKIP_EMFILE/s:False:True:' \
+		-i src/twisted/internet/test/test_tcp.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	# accesses /dev/net/tun
+	sed -e '/class RealDeviceTestsMixin/a\
+    skip = "Requires extra permissions"' \
+		-i src/twisted/pair/test/test_tuntap.py || die
+
+	# relies on the pre-CVE parse_qs() behavior in Python
+	sed -e '/d=c;+=f/d' \
+		-i src/twisted/web/test/test_http.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	# TODO: upstream seems to override our build paths
+	distutils_install_for_testing
+
+	"${EPYTHON}" -m twisted.trial twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	cd "${D}$(python_get_sitedir)" || die
+
+	# own the dropin.cache so we don't leave orphans
+	touch twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	python_foreach_impl python_postinst
+
+	einfo "Install complete"
+	if use test ; then
+		einfo ""
+		einfo "Some tests have been disabled during testing due to"
+		einfo "known incompatibilities with the emerge sandboxes and/or"
+		einfo "not runnable as the root user."
+		einfo "For a complete test suite run on the code."
+		einfo "Run the tests as a normal user for each python it is installed to."
+		einfo "  ie:  $ python3.6 /usr/bin/trial twisted"
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}