gentoo auto-resync : 21:10:2024 - 04:04:33

2 files changed, 163 insertions, 0 deletions

diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index ef87b22d7097..7b2a36862f8d 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -3,9 +3,11 @@ AUX twistd.init 563 BLAKE2B 24488118b025bf2068bbf07af900064ff6a7ee99106c3da30f15
 AUX twisted-24.3.0-skip-dsa-tests.patch 2821 BLAKE2B cb3458d0a25fbfbe2c6f6ba0678de34c4776ff3b0007cb148886178914888ab85dfa84260053233d75143aca1cd4fae98b65010fc5315a5d2c1d64e4e8f65346 SHA512 0decf83cad5cc725dcb44993a6c688b06ba20f72a4b906281fd2bfbfcc1f9a043777e4574119224fe6d16964be7c8977224a1233d6a48db6aa9c232a18c5157e
 AUX twisted-24.3.0_p20240628-skip-py313-test.patch 1275 BLAKE2B f2b0f08635de429e1fe780cc0176e1590db5f2f290f89cb2796ad5f2b5728382c22a2470e7fe1140071a94356dc2a0e15084008124fa5185e314252e75702469 SHA512 e1b7b7602658576d61a7a79592f839d5cf514571d56d51a53cf6fdcf7ab889cec510081e59ac813ac68908990f26303d30f70f7ec393fa2a1e995e41a380fd2d
 AUX twisted-24.7.0_rc1-skip-py313-tests.patch 1927 BLAKE2B f2647c913cf594eaed6bc9c270930cfe6f0b91275bd4701249dce4922aa2868764311ccce1323565ddcbc1b65bb7fedee34bfc57eadaf8827a78cdbe8e25b401 SHA512 1a5972d4b8d575758c0dc824b90c53f8317f52e40f1893264e21743a3cbf6705043bfbd9d35d82518f91f578f2e5ba7458be5a7839e4e2657ae5ab8ecb73a4fb
+DIST twisted-24.10.0rc1.tar.gz 3526429 BLAKE2B f027cb52ea844d3b4ae641c97001c68c74b41e5fe0e31d255a8e3b0eef3188d91db5f66242b624ca98140b520b94569ccf5a0d103c7fd5e435cf867bb83648d1 SHA512 b747bb4443d91543776d89e8393e0f0536650222cee52701abb3ca9cb22504062c1e04005c8034ad5a249bd1fc639439abebb89018fe0bc89c3a9ef574379bcb
 DIST twisted-24.3.0.tar.gz 3500456 BLAKE2B b2cebb2f3482dbeba250786b1977ddbb09e1a9a81f71ce5906efe8289b0e134a8b26c191c2262e8ee8ba3fccccea508c34145016b29ecf301541134dcea19e08 SHA512 c3dd227f5936ffa586a0b7447f5df4c2257dce0c0ba740373d82197a72029e7eeb0aef9789247dde73e2f24dd043f3b0b7d795f16e6e908583b054aad9b9eb6a
 DIST twisted-24.7.0.tar.gz 3516844 BLAKE2B 169347260b473ea1c50806ce50324ebd51388186098886ccaad1f94e55f6b14eb7a7fc42728dbeaf4b5649d0e6dc1e4624cd5ab6d79feeaa733e18d09cfd689f SHA512 cd5a993c8f1dfdc82597bdc095e07c1016a2a86d1ce5b011b27f9f760db428fcba4579dda5733244979827f9c772c2480d1d419d2d24ae7af8697e2b8e852f62
 DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
+EBUILD twisted-24.10.0_rc1.ebuild 4571 BLAKE2B c3509b6045e6afeee08544c51d4a02e73f1228ed9783a5b6ebf7f627a296abc38d7cecf0f880dd7c961b536bcda1cbb01115191dcbd9c4143445eaaf11aff3b6 SHA512 fa71a84b1df31afdb515548f16cc52b6dfd616cc41ccc84c6444c3bbf68439651408d97d7238bdb1f305cdf29a197c32ec93f7341ee8c8ddde15928af3fca944
 EBUILD twisted-24.3.0.ebuild 4266 BLAKE2B 80f0a8869356a3a66342ab7765f4e42559d0387dda711e05ec1d283fb46e3d71774b706cedccffcab4ff30d8cd777791a4bd00cd09ddf0e9d285fbcc90bb4af7 SHA512 3a14afb93e17e190bba1e62c0e7810579b6b3c6f6f10dc660e3c6ffd9d618e6a81c0ec27cef71ebd5af5dade0fcae52ad9b6c3ca405d6aa1538356aea274ac31
 EBUILD twisted-24.7.0.ebuild 4697 BLAKE2B debbd364dc444ac4fb2dedc35a713cba1d94b46242ed3ddd9fe367d28976ca68b2f67a392949091824dc9a4852da7789d35bc00f32bde7a3bb0b70ed4605ae34 SHA512 56a1b0d66dbe72f785a26647c23e8e3958023d9d932fdf46c19134902c2f2324d584b0031dabe2fe7e06cc756f86e3146b01692d988454307e59eaaa0d9fea90
 MISC metadata.xml 1231 BLAKE2B 60cd09e34c32152e6f08727c1281c65e871a51e64310a62a3104342fcb0e87e96b10cd4c7601668f054f9a2cb01fdf8ebeca3ed86b61ae2496a4d941897aa296 SHA512 800d9cd783d95cecb268362619deb346783149fa9226df714f9ce990da2d45edd3c8e5669e24ad15dfdf986a5816a5361c00f13719bb0dee3e6ae1578a889339
diff --git a/dev-python/twisted/twisted-24.10.0_rc1.ebuild b/dev-python/twisted/twisted-24.10.0_rc1.ebuild
new file mode 100644
index 000000000000..ca55e6158b82
--- /dev/null
+++ b/dev-python/twisted/twisted-24.10.0_rc1.ebuild
@@ -0,0 +1,161 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 multiprocessing pypi virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="
+	https://twisted.org/
+	https://github.com/twisted/twisted/
+	https://pypi.org/project/Twisted/
+"
+SRC_URI+="
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="conch http2 serial ssl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-24.8.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-22.10.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-5[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/bcrypt-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-3.3[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	http2? (
+		<dev-python/h2-5.0[${PYTHON_USEDEP}]
+		>=dev-python/h2-3.2[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+	)
+	serial? (
+		>=dev-python/pyserial-3.0[${PYTHON_USEDEP}]
+	)
+	ssl? (
+		>=dev-python/pyopenssl-21.0.0[${PYTHON_USEDEP}]
+		>=dev-python/service-identity-18.1.0[${PYTHON_USEDEP}]
+		>=dev-python/idna-2.4[${PYTHON_USEDEP}]
+	)
+"
+IDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
+	>=dev-python/incremental-22.10.0[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+			>=dev-python/bcrypt-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+			<dev-python/cython-test-exception-raiser-2[${PYTHON_USEDEP}]
+			>=dev-python/cython-test-exception-raiser-1.0.2[${PYTHON_USEDEP}]
+			>=dev-python/idna-2.4[${PYTHON_USEDEP}]
+			>=dev-python/httpx-0.27[${PYTHON_USEDEP}]
+			>=dev-python/hypothesis-6.56[${PYTHON_USEDEP}]
+			dev-python/pyasn1[${PYTHON_USEDEP}]
+			>=dev-python/pyhamcrest-2[${PYTHON_USEDEP}]
+			>=dev-python/pyserial-3.0[${PYTHON_USEDEP}]
+			virtual/openssh
+			ssl? (
+				>=dev-python/pyopenssl-21.0.0[${PYTHON_USEDEP}]
+				>=dev-python/service-identity-18.1.0[${PYTHON_USEDEP}]
+			)
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	# the test suite handles missing file & failing ioctl()s gracefully
+	# but not permission errors from sandbox
+	addwrite /dev/net/tun
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON} (xfail)"
+		return
+	fi
+
+	# breaks some tests by overriding empty environment
+	local -x SANDBOX_ON=0
+	# for py3.13, see
+	# https://github.com/twisted/twisted/pull/12092#issuecomment-2194326096
+	local -x LINES=25 COLUMNS=80
+	"${EPYTHON}" -m twisted.trial  -j "$(makeopts_jobs)" twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# own the dropin.cache so we don't leave orphans
+	> "${D}$(python_get_sitedir)"/twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	if [[ -z ${ROOT} ]]; then
+		python_foreach_impl python_postinst
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}