gentoo auto-resync : 12:12:2022 - 21:25:47

2 files changed, 93 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index af7ec78efc31..fc660a5769b7 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,5 +1,7 @@
 DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498b26d2d124d9f88a64806b9ac0578c1886845b25aa024907f6a782c45609fa6c7657d9e1f538b59c2d9f0f4e14 SHA512 5f568bc6c53f871aae91928681dd6f2419b876a8e6ca925e65abae845b548ee3d00513741882875bbbacb78bf64935228d98213f940d3da8c3f788b73f177b79
 DIST tox-4.0.5.gh.tar.gz 277741 BLAKE2B 19250ec4365a38a149c59de99ebd3b819cc4aba7721c076cc6700a17eb56b7c4b61d5c3b11046dc6857d082f1c04e98c6a78b8c768551468bca5a6810c4b7749 SHA512 7bc6f5479df577b66a7e43b61520995d1d31d056baf5b6297d9dc6acb19da58ed1f7d0db13930ab114417f0ad752799ac512765af18041ec800022b18676db20
+DIST tox-4.0.8.gh.tar.gz 278697 BLAKE2B ef87b02d95447d52135aa745fd224f7ec1f76f5e99e37ee8dc4990a1577a5f4d2103f21d26e4b32946c20ccbc44aa7e3954e167dcf7599f548466574121ff7dd SHA512 bac13d4a74d76405c658a05eb50df258ae8f5ae8b821b36bc41d473562a0930667bf3b4eb96d873e92f89811af2a8dfd19009622efca8836f163aed53476b46a
 EBUILD tox-3.27.1.ebuild 1916 BLAKE2B ab2496317d588c05936d57132d1c759c9a14f18c10fb50d6188b7bee5bd20de9f06b5d8945a908cbf021f4b7036ba6d23dcf19aad63af9d6cd6bf6baa598ad32 SHA512 b038f9976de8af46ac663faa169a06fad1bd28ef61738679fd70faa5e655c0c85ed3a8e4efddee2dd2aff8cc3fe9f5ec133311d122c6bab15c487a5a074a6c11
 EBUILD tox-4.0.5.ebuild 2398 BLAKE2B a8a4d53f19e306c32fe542fb0ebb132bcbfe29c54a96f6f090b1beec6c85763ea04d77ab592a7fe20214724295e1a5d4c0740d99644d513dc9f7a311f4c3c5dc SHA512 be8ec59aad967e10ae4c3b03313c6f3ea2bf4491084517875130e737836e3a66c9e7acf29de522cb3ae7b4d445910334d64e070a53db15b8f761e7b3b886aa06
+EBUILD tox-4.0.8.ebuild 2398 BLAKE2B a8a4d53f19e306c32fe542fb0ebb132bcbfe29c54a96f6f090b1beec6c85763ea04d77ab592a7fe20214724295e1a5d4c0740d99644d513dc9f7a311f4c3c5dc SHA512 be8ec59aad967e10ae4c3b03313c6f3ea2bf4491084517875130e737836e3a66c9e7acf29de522cb3ae7b4d445910334d64e070a53db15b8f761e7b3b886aa06
 MISC metadata.xml 382 BLAKE2B 7c0704c5c187ce4a7972fe0372b23c5537a81a8d62fd83436d9558a61761f10764adb5a4d5f6795f0dd1fe905afa604c0be77fe1d48d291847f6ae65dc1b032c SHA512 9d0ced4df9352a81034a50d5766a01534ae8fa889985d99cc9e2a8d0889e31c6c11550677d9a5a74e2aab57c320192ce3a42708a6d23b0419ee34a6054398344
diff --git a/dev-python/tox/tox-4.0.8.ebuild b/dev-python/tox/tox-4.0.8.ebuild
new file mode 100644
index 000000000000..ed83ca51ba13
--- /dev/null
+++ b/dev-python/tox/tox-4.0.8.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.2.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
+
+	epytest
+}