gentoo auto-resync : 08:09:2024 - 12:29:27

2 files changed, 99 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 7b6f00a229b6..d7eddad48bbc 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,5 @@
 DIST tox-4.18.0.tar.gz 180782 BLAKE2B dc9832ad75c3e8564317bd618fa644ff2f393e507d7ff03292f65f0b10884d010708820768b6acd403783fd78868eddedb1ce931280d1e06e8d83214d85d4879 SHA512 4934b6d9406cc4500e75da76157ceb2dd9d7d0fd5e803fcd2c2bc9b5d2837678eead5af21dd6eb82ae7fe04c90aef78cc3db445daeed194a444ad88687ec1eeb
+DIST tox-4.18.1.tar.gz 181159 BLAKE2B db9b2233363b6214b1c0bae2c0319b72a7ef4a7f833628833fecb7a8d04eef0594f1a93e17f8273d45873c2130e96b7adad8afe69662cb8fe37251028ba1581f SHA512 289ee3e8b7c941dbeb94adea24442169b33cfe3ae2c4d6eadd12974ee01488325d05beb92cc3b3d5aa1f795f9d3ffe65ed3da81bc62b0527edf56f5ddb9ceb32
 EBUILD tox-4.18.0.ebuild 3017 BLAKE2B 454121fc002ecd267298b4abcdf9167997ec2ec7812e7c0b0820a830f111fc58855a33042f115d291548ee8571eb87385a6d42f4c4ce0184fefbfbed7fc86554 SHA512 339ac1fe5e2a5c6fa6b949d3b1d814fb08b7f5eef6da6abfec7f476c1f909d3d55cdc6a367572fc622f70ede37ef755bc5c00047726d804ef841f92342fc86d6
+EBUILD tox-4.18.1.ebuild 3025 BLAKE2B a30ba7f669ab2da51c7f73c6dda2de44134f69b3c061fdf1131a1e5c854c2a469e8b652f60a2291bda030d90ab76de812c5be7a1277742a7973e662dd58423cd SHA512 0dea63105a9468a6b0fd0f21f6beaf1d2fcd8a0fa29824c9078fb44443a738ff56107191cbdb8054612f9c91a159e66ec9872dbe8820564469d470b908c5da45
 MISC metadata.xml 382 BLAKE2B 7c0704c5c187ce4a7972fe0372b23c5537a81a8d62fd83436d9558a61761f10764adb5a4d5f6795f0dd1fe905afa604c0be77fe1d48d291847f6ae65dc1b032c SHA512 9d0ced4df9352a81034a50d5766a01534ae8fa889985d99cc9e2a8d0889e31c6c11550677d9a5a74e2aab57c320192ce3a42708a6d23b0419ee34a6054398344
diff --git a/dev-python/tox/tox-4.18.1.ebuild b/dev-python/tox/tox-4.18.1.ebuild
new file mode 100644
index 000000000000..44a2547684f8
--- /dev/null
+++ b/dev-python/tox/tox-4.18.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# https://github.com/tox-dev/tox/issues/3290
+				'tests/config/loader/test_str_convert.py::test_str_convert_ok_py39[1,2-value1-Optional]'
+			)
+			;;
+	esac
+
+	epytest
+}