gentoo auto-resync : 29:10:2024 - 03:04:53HEADmaster

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/starlette/starlette-0.41.2.ebuild b/dev-python/starlette/starlette-0.41.2.ebuild
new file mode 100644
index 000000000000..a7637ab5fa89
--- /dev/null
+++ b/dev-python/starlette/starlette-0.41.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+# no docs or tests in sdist, as of 0.27.0
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/python-multipart-0.0.13[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+: ${EPYTEST_TIMEOUT:-180}
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Unpackaged 'databases' dependency
+		tests/test_database.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p anyio
+}