gentoo resync : 05.12.2021

3 files changed, 216 insertions, 0 deletions

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 70b526d33ba6..82f41a4710d3 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -2,13 +2,17 @@ AUX spyder-4.1.5-doc-theme-renamed.patch 375 BLAKE2B f4c902b331e9e6f034018d781d4
 AUX spyder-4.2.1-build.patch 1232 BLAKE2B 54bef30dca6cc94a7a32fab200bceed1a01f730f4758f03b97688d3ecf5709e8c7b37af82746452520c2f3135722b4e387f3ef9d9219e1d159b8abe937d8165f SHA512 052f249b5f6b2195a472750f42b16721de9e8020481cb57bb5e180267507df6f6b5f1a36b8a45f28b64d098c8a02a4814c1c03f1efdcd1ffedaca77a28ad8705
 AUX spyder-5.0.0-build.patch 1147 BLAKE2B 68e62f6bd7a021d82f1da8d86c16e2289faac7f760f9bb5dc975053c7f8bb409c79b90eeaf06c5121ca5833442b61929cc640e4f25e6cc27f6118f0fa8f27b5e SHA512 e88cbbeca42ac2720f4e0888df9432d912d3907af267d3fe6a5e658d18d1242c998a70dee88fa0efe9edfcf87a46a40cf75685037d75fce1d596b708acc32096
 AUX spyder-5.0.1-doc-theme-renamed.patch 346 BLAKE2B d0f894f5f736a32e78aaaac6c9c8f051dfdf5f12b09038c047be8885d05ca149830fbebc0bcc2764bbb24033817874be0e1b2609e2a6cae591254bb139488954 SHA512 0a2e0eaee4386ab85881ff67669a4820c26a17993c85b33a6df3576a07aba1c331eef5853db1ef8a760e95c315036411f6f13880510efda20933ee3cc0600741
+AUX spyder-5.2.0-doc-theme-renamed.patch 356 BLAKE2B 666ba289498026ab0679776b8af8f6efe7561a9a736ff19b32eaefcac87d142a55a055556c09f94373869711e81a35ef90832fbfe68acc6cee0f2023742de0be SHA512 396944e6f242bf3b6a27ac9d47f0cc07fd99a55c50f174dbee2fccd1f0b3edf355347bf6291943c3003f55996304d96ce2d2fe45ae7c4291e8425bff73a3a861
 DIST spyder-4.2.5.tar.gz 11539071 BLAKE2B 9d7a98da018aae934803d640995fe2dfa6bbb20bfc7140bd00f5e7a00a09c47922fefd8df84f4b217a50176ee190515da6f4cbf498a03cae68e2ac4f5ec70664 SHA512 081b047a45b7522a69b1b21a221ab5cdef47f87f36ed4423ff63297d205f924c1627517c50622acb2d10efa094bc506fed4ec88f861775d3f58e81ac6ef017ac
 DIST spyder-5.0.5.tar.gz 20606379 BLAKE2B 52f05ffcf0b6aabdac23a055af1c674c6aa80a7d4f3608779df1d46e0e51de63a71b4e97db286dc92e071cbb44a0dc827aa750d8ca538e6764b5e780f493d615 SHA512 17654ee76eb51c5f5b9f494d009af3d7813f869f27f22ceb8ad8ca96dcedcbcd6b86c7a3895bb63eba3cc60e4a57ab94128abb8d21f05c4672b8bb8d545fe1ff
 DIST spyder-5.1.5.tar.gz 23849672 BLAKE2B a0a4db5105d4ecbb76bf3c996ea8ea17142bc4f9dfca989098ffdee32b620c711b343746e5dc5dce0c6c0a092a20b47d6bb28181c363f81af394bb8bccb5b6e2 SHA512 2204fe46ad3e4e14bebb51ef6a53074b657f6d970553decd0b2f9d0a7fba71b2f14b4efc3248bb4fb944860e85851e4a8add475ff12c6466e864be75b8cc38bb
+DIST spyder-5.2.0.tar.gz 23901277 BLAKE2B ce4846ce054ff484a30d38d836a2da23908e0793cb5ecaeaefe1b4171dcb038facfc19e8d80ca840b538b4effd97c9b8541c9e0af86e74f75acb5237b049c154 SHA512 9298c845a17f348bccbe93451f03aef0d4ee2bde2d3025ac7ed695b3e3c3941cb9852f7c56d676ca022a37020a647c93977e0845fe6f5686dd2598236a9c7d9c
 DIST spyder-docs-5eb83118155a3765de4a0f863b936bcbe73bb7aa.tar.gz 85362596 BLAKE2B 7294dcd0f169958da132b141379b9b1cf497095981a86416fb98d98f98e30a425fe2e628a523785f932bbc06a2ba1ecddb45bae0df009887db928f879e08cdef SHA512 45f45546b83afb3036348e89ee3eded4d8ecee36ce58fe697da14677fbff8fa2dfe170be7385ecf10e1989817780c07b5676d545ee34e87a8f252929ad72882e
 DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
+DIST spyder-docs-879e8a59a522444f1866485290933ed398a30c81.tar.gz 90033271 BLAKE2B fe1f1b2d9284c7d75ed90ebe496dbacc7c5cedb7202c6fa2031f7e5a59675080f5dbbc61293b8ed3e6b676e24fd8896f60c18821f9d31b57595a0f36076b4b8a SHA512 61d099c38efd588689ce1acb9d559fa9d0ca76a6e12cb6ed70b626aa445b9efacb9358393fbf9096987862ee57fb4b52a7b72461b46baea52b8447903fac587c
 DIST spyder-docs-a3a579ce6e7e42c9d9bbd88ac4e76650b7093e5c.tar.gz 88791917 BLAKE2B bdcf52965b592f4a88ee988afcca71ed73b0499397c8c0b7ff36c38d4408f4b76ff285b3d9739d1c126322fdd8c1c6b93f3017edcaf30563da02d8f509d09fe4 SHA512 2717dad17db836330820578c9082505b7f1126fef2a76284d03a443f3317e3a9a294f69e50f075a29580c4ad1bfbd23dcd02fcef93f32645ae5d52ecfb0b8f10
 EBUILD spyder-4.2.5-r3.ebuild 10242 BLAKE2B 4f1be987a2a565cc1816754ad2cbde22c091345cb6fb4295f9299eb99d0b77242f13eddd05b1b6ef728494c953572693ce1055d751d38bc32559b7afbabec12c SHA512 efc782d8cab53f3f70a97bfccf6e5a2f54efaba9618df1221ad3e2c7bc6ce73edcdfa4318001cd018c6965859945f89dc55cd84265d7c42156a28a57818f92e7
 EBUILD spyder-5.0.5-r2.ebuild 8219 BLAKE2B e95d6cd019398c19e7548b5008f63dab1f29a1c5c25b26fde059a7caf217709cf4c92e952b423385bccb2a27ab16d79fe2ca4a07fbdd19537b8fb731dda813a9 SHA512 3bf7b4947724e15125fdd0a6e655d55d274b3d6a787848da92f0be4050e556fca158228d8e40e212537d7144a720c0e513821b943cdc4d821e6efb0f5c490430
 EBUILD spyder-5.1.5-r2.ebuild 7424 BLAKE2B fbab5dac940bd1c6c0e2cd0f3f0cf1e4cc1d0b59b1f686b172ca5076a282b8c68dbc97294cfdd978b4de40ef2c89270a9adf18f6f5a6a9448d698589573d3e87 SHA512 b71a0868b35122e1dc513f96677eaaff36983a08b1eeeb009b5e7bb0fb2928582c2766832588628fe366787e2382e8d9b7b889146d28d7274d02012e829f6860
+EBUILD spyder-5.2.0.ebuild 7508 BLAKE2B 83a1684b77ed1de647a76644aabce9188b3d6412b56457d7c63fe0b745c50c2bc3ba32199d72f02caf8b280a9ce8db225932796f5bea1cc65ffba5fa08cdaeae SHA512 a01cf9448244cd1f33cf408837f9d22d3431581421ca1c58341d71e14821b231ca3ddd5d1567afbe9799b2b86affae88da3c142548d24483a729b65457dac28d
 MISC metadata.xml 1316 BLAKE2B 996e794aec3c0a7f3b192fb9a66ebe7afaddc3f1ef2057d36a007770becf3d11ec0d05cf30a520cfb8537c1ae34bc9d89e8bc54224def1f4f2f4b30c657ead53 SHA512 b3cd21a16e51414d22b0f102f88da30ca1c3e596eb032ee7bde3c0d7b396659485c2565f0ed79c437eaca07b535fa3305796386e6023606ad1896edf7d347493
diff --git a/dev-python/spyder/files/spyder-5.2.0-doc-theme-renamed.patch b/dev-python/spyder/files/spyder-5.2.0-doc-theme-renamed.patch
new file mode 100644
index 000000000000..08403d90fd9d
--- /dev/null
+++ b/dev-python/spyder/files/spyder-5.2.0-doc-theme-renamed.patch
@@ -0,0 +1,13 @@
+diff --git a/docs/doc/conf.py b/docs/doc/conf.py
+index 92a4b65..412fd39 100644
+--- a/docs/doc/conf.py
++++ b/docs/doc/conf.py
+@@ -145,7 +145,7 @@
+ #
+ # CI = True
+ # TRAVIS_BRANCH = 'master'
+-html_theme = "pandas_sphinx_theme"
++html_theme = "pydata_sphinx_theme"
+ html_logo = "_static/images/spyder_logo.png"
+ html_theme_options = {
+     "external_links": [
diff --git a/dev-python/spyder/spyder-5.2.0.ebuild b/dev-python/spyder/spyder-5.2.0.ebuild
new file mode 100644
index 000000000000..c760c5c3c69d
--- /dev/null
+++ b/dev-python/spyder/spyder-5.2.0.ebuild
@@ -0,0 +1,199 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="879e8a59a522444f1866485290933ed398a30c81"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work. Technically spyder requires
+# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason
+# many of the tests fail or hang. RESTRICTing because IMO it is not worth the
+# several hours I spend every single version bump checking which tests do and
+# do not work. Spyder itself works fine with pyqt5>13.
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	~dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.2.1[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.3.0[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},svg,webengine]
+	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-2.2.0[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		<dev-python/pytest-qt-4[${PYTHON_USEDEP}]
+		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+	dev-python/sphinx-panels \
+	dev-python/pydata-sphinx-theme \
+	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.13, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.13, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e '/pyqt5/d' \
+		-e '/pyqtwebengine/d' \
+		-e '/python-lsp-server/d' \
+		-e '/parso/d' \
+		-e '/jedi/d' \
+		-e '/pylint/d' \
+			requirements/conda.txt || die
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+			setup.py || die
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+
+	# do not check deps, fails because we removed pyqt5 dependency above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# can't check for update, need network
+	rm spyder/workers/tests/test_update.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here test results
+# should be checked for success manually
+python_test() {
+	"${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-autopep8 does not have a release (yet)
+	# and are not compatible with >=spyder-4.0.0 at the moment
+	# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+}