gentoo auto-resync : 09:01:2025 - 06:41:15

2 files changed, 135 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index ccfb4db6bdea..3af8e20d2436 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,6 +2,8 @@ AUX setuptools-62.4.0-py-compile.patch 3704 BLAKE2B 9a5e70d2556b059be0ef060abd1d
 AUX setuptools-75.6.0-disable-trove-classifiers.patch 1383 BLAKE2B fa3bc1822badca21e102ea4f360ba4975906aced16a274622f69cfbb3a720d67cbbdb8f4d7a15e4545f3b96528f2e284e85116139ba0788c80ab6eb5cd4d3414 SHA512 9011ef7551479d9512f880a91c27ee1327fca2d19eb5e97bcbadbdf243f8de2cffd6351d4a03f5ee5a6b2442953b544d70e1c30106618582758290568d3af6e7
 DIST setuptools-75.6.0.tar.gz 1337429 BLAKE2B 65ba2e3de8dd0c86ab0ad59a5dc99a860ef5b59f357272eb2568347a496d853ef8e12a2d456dee3effe6f100bfb8d29e2f9f60123b58d791003ce3cddac23e8a SHA512 bdc12309165912f8de84e6f4ceaaf8f6b05dc1506a9205201784eb740346d773a7701af9b570cb13c272d81dcc0b4928e53ea1c4bb7c179debf479701c35bb6e
 DIST setuptools-75.7.0.tar.gz 1338616 BLAKE2B df1a44a354fc48fc9bdbbea3883d0659f9865c1000b50dc8a329f6c8be9c9777b1f9cc6ce93e2e38cc53f46d08daadd470101913bf1a5992a50cd4049684c1fa SHA512 22cb119056efbfd5986eaa38ab37b24bdbbfd9903202fa031eb9a8acc4cbc1586df04bdf871eaaeeb09bfe1ad28d117e9b187f16d54afe26afc658295b5183f1
+DIST setuptools-75.8.0.tar.gz 1343222 BLAKE2B a71cba4c11ede52aae24e8a8045f2733f93001b896ea4dd46ebdfa0dd639fccfcc24b038cf4f9b6363b768e98d66cbeac2331cbcd4bb38767ea73f1811a11837 SHA512 4afa657c5259f9f405c39d82d8c264236749861ba2b104e8b26dd49da8ffb27ad3089ea894f2bb65208f480d7a4042114b93228f1cf2b224dc248774d7681a3d
 EBUILD setuptools-75.6.0-r1.ebuild 4704 BLAKE2B 197bf820ff5e42273422660693dbbb22c947bf3a32fd8e7d8c56e6ab4066fefa447523ec6c7e9f36b40e3fef18eaaea43fd7238c7d9e6edf86acaf1a42f7fa8c SHA512 603d836f81248959d69916a5a2796747fb6cf0494e5ae9c334429ea35ebb98edca05f34d193090f85fcfe24a87aa58931b2609c102d7b34e1ce5b585c69b55a0
 EBUILD setuptools-75.7.0.ebuild 4712 BLAKE2B 978a5ba3daade5b4d8c3b17a239d6e92e6447a6b1faced0aa6e00a611d8f9ea4de63f36af2d06da60d0da1149d8cf719625b637efae372f04b6ba4956e8714a8 SHA512 b4b7b6b55c2bd7bad9ea432cc9a70fdc73fb8b64ab6dbe8578d0b506751bdb25919f4c4dd3ff3b2936eaaa38d34fe9daad42efab1f4c8f1892115a1d01febf2d
+EBUILD setuptools-75.8.0.ebuild 4832 BLAKE2B e156ea1f8d05c8e4312bb61e2b7f7a09d2df09fee01da483343c490ad979e32d57a81f9bb0b605f23680f55836386870a9b7c9e0ed21bfdb9c9485f79340e252 SHA512 090a7c4d7b417a85ea284ff6843415f75ccb3fa66da58d0f0729e6362ef02e5e8804a8545a98e6bcd8e8237ec5589dbf6517dd8b7211c4036d4a31d64dd9a214
 MISC metadata.xml 469 BLAKE2B 4a26769b09a3785586b22db850b7fc5c4818f31c3ace9cc94476d35df05e50edf6721f3c95ec615c3b2efe071ef284a54ea2d53566316ba653f7830bb48f80bf SHA512 dd682c4ad2e59a97094ebdabe4d1063e2319ed05e1fe9d8c2fafe069badb3b4cf8bb6d9f50e09d2128e2a081c1c69827407ac8aed644ebf70eb4ca1bc9a57319
diff --git a/dev-python/setuptools/setuptools-75.8.0.ebuild b/dev-python/setuptools/setuptools-75.8.0.ebuild
new file mode 100644
index 000000000000..4daa92c3dd0d
--- /dev/null
+++ b/dev-python/setuptools/setuptools-75.8.0.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_13t )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!<dev-python/setuptools-rust-1.8.0
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-4[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2.2[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.44.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+	!<=dev-libs/gobject-introspection-1.76.1-r0
+	!=dev-libs/gobject-introspection-1.78.1-r0
+	!=dev-libs/gobject-introspection-1.80.1-r1
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.7.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-test-5.5[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-subprocess[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+#
+# trove-classifiers are optionally used in validation, if they are
+# installed.  Since we really oughtn't block them, let's always enforce
+# the newest version for the time being to avoid errors.
+# https://github.com/pypa/setuptools/issues/4459
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2024.10.16[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}/setuptools-62.4.0-py-compile.patch"
+		# https://github.com/abravalheri/validate-pyproject/pull/221
+		"${FILESDIR}/setuptools-75.6.0-disable-trove-classifiers.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# breaks tests
+	sed -i -e '/--import-mode/d' pytest.ini || die
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# broken by unbundling
+		setuptools/tests/test_setuptools.py::test_wheel_includes_vendored_metadata
+		# fails on normalized metadata, perhaps different dep version?
+		setuptools/tests/test_build_meta.py::TestBuildMetaBackend::test_build_with_pyproject_config
+		# TODO
+		setuptools/tests/test_sdist.py::test_sanity_check_setuptools_own_sdist
+		# relies on -Werror
+		setuptools/_static.py::setuptools._static.Dict
+		setuptools/_static.py::setuptools._static.List
+	)
+
+	local EPYTEST_XDIST=1
+	local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
+	epytest -o tmp_path_retention_policy=all \
+		-m "not uses_network" setuptools
+}