gentoo auto-resync : 29:08:2024 - 12:00:47

2 files changed, 129 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 14871b118bac..e7a98bac2df4 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -2,7 +2,9 @@ AUX setuptools-62.4.0-py-compile.patch 3704 BLAKE2B 9a5e70d2556b059be0ef060abd1d
 DIST setuptools-72.1.0.tar.gz 2419487 BLAKE2B df05affc48f8909b6b3b9dc30ef33e31c4b3781e747fea7d23b855d0294976f563e25b268666bfd2c758be66eca00e3e850463ff3d6f26b891185a2a15c8d31c SHA512 d0a34f16dfa6bb9a6df39076cd43528cf854d343f6f801c448ea0ebab2a259aec3d03571e2a26709df6082ed2fcb6c43b86448be556fd559b6af41831b4f38e0
 DIST setuptools-72.2.0.tar.gz 2419230 BLAKE2B f04c196d13f62302e7c6f30a1021598fe22955cc8c980ddf22efa65f4d398c25273552b1a19b8719e2fee722dc44e9f1a2e339c5b6da8f4ca4ae8399cd27b2e1 SHA512 029c711be2953cc7fd88b6a0a00715e05ac04414e085e0b2387d58757c970a3316afb6e13426fa10dcc53785b98c8543ba48d49acf223a6332399a39a4924732
 DIST setuptools-73.0.1.tar.gz 2526506 BLAKE2B 766453a7f6f3e34bdc63628b8c0321730c66381cc6048d01fbf9dbf76eb9900cd5cfa6dbd7c55c95ada3e01065d43bf7cd9029793e0735cae989b3cb1b95287c SHA512 5def2d817329524e610c7981fc3a84687ea4d2e0a72799341a706a16ec61df3efc16c4622f8b88746ad4cb52f92f2493c23a99a21cf3607ed48da480dedd200b
+DIST setuptools-74.0.0.tar.gz 1389536 BLAKE2B 11a9c4a6e175cc1d48b4bfed4f57f38e0e2f1e9c1de08706afc8199860c61325c85eb1f0772f30a47d7dec1923ea866eeeeb3cf51e74d7396bd291769cae42cf SHA512 c8116bb2cd6b39c74a03bf267eb44289ab54a8b6acb91882e0159f9bd57f369d686e44dda8bb6b2466baa50abad684f939df914bfb5c2564cc9596bc602c7388
 EBUILD setuptools-72.1.0.ebuild 4261 BLAKE2B 5211e0e5aa791afcc0d700964638ba793e5c5fe507a036dbad025dda8f3905575b92d472ba0db77ae43ddd5c6cb86cba877275a7b7ca8322ad095294053cc125 SHA512 2989175c52bd37682d09c333883ca57dd92b1b40ccaf755fc820c6f31cf8d503f2846a965ec8cc94e420facee4930b9395083a34e5536b146a5d86534d6d2ad9
 EBUILD setuptools-72.2.0.ebuild 4428 BLAKE2B b584ccf973ab6784e0d5187499b5f140d1cb3e6b88bebd5439a1af5439ec5eabd2cfd6082ad02b007fe9ab38d3b4f1331bd4a49400231e79e6061462ea2c80f3 SHA512 a1cf38c6eff9313656f907de31eae6504ad66bea90b7a257e324400917c80a93490d50656c3251daa16565455cf2d24d5af94aa7665603bd4b9312ece90b9312
 EBUILD setuptools-73.0.1.ebuild 4372 BLAKE2B d1adf6c88761065855de60e4e3e2636b02372b96813650b1e5f60541faf179ab9a67a9fb145e79b65be8ae2579c73e979df63e2f97cfc70c243a755fbd649169 SHA512 2e7974293b764156a0fbd0254203ad39b9736b8b0ee077c154337fbcae2345d9034bff62707087aba8e2ed58eb143020539f560131905a1c0feb1fa7c37e1b7a
+EBUILD setuptools-74.0.0.ebuild 4454 BLAKE2B aa82ac6ee45f26cfc486a86000f0690703883b8ad5080997f3a48a9073a7ce5a2860291306bc35def00b5c738f798fb3649243f050cde9a65abf9a65f453b6df SHA512 019405dfd516dfcd66f3af10ffc09ab9f27e87aeb5be8a117e72605287b6ba336c505d8c4d8da07f5d3c4b8293278065061462dab2d5a4e6194dcd3217490f22
 MISC metadata.xml 469 BLAKE2B 4a26769b09a3785586b22db850b7fc5c4818f31c3ace9cc94476d35df05e50edf6721f3c95ec615c3b2efe071ef284a54ea2d53566316ba653f7830bb48f80bf SHA512 dd682c4ad2e59a97094ebdabe4d1063e2319ed05e1fe9d8c2fafe069badb3b4cf8bb6d9f50e09d2128e2a081c1c69827407ac8aed644ebf70eb4ca1bc9a57319
diff --git a/dev-python/setuptools/setuptools-74.0.0.ebuild b/dev-python/setuptools/setuptools-74.0.0.ebuild
new file mode 100644
index 000000000000..9cb620d24ab3
--- /dev/null
+++ b/dev-python/setuptools/setuptools-74.0.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!!<dev-python/setuptools-rust-1.8.0
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.44.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/jaraco-test[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-subprocess[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+#
+# trove-classifiers are optionally used in validation, if they are
+# installed.  Since we really oughtn't block them, let's always enforce
+# the newest version for the time being to avoid errors.
+# https://github.com/pypa/setuptools/issues/4459
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2024.7.2[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}/setuptools-62.4.0-py-compile.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# breaks tests
+	sed -i -e '/--import-mode/d' pytest.ini || die
+
+	# remove bundled dependencies
+	rm -r */_vendor setuptools/_distutils/_vendor || die
+
+	find -name '*.py' -exec sed \
+		-e 's:from [.]_vendor[.]:from :' \
+		-i {} + || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# broken by unbundling
+		setuptools/tests/test_setuptools.py::test_wheel_includes_vendored_metadata
+		# fails on normalized metadata, perhaps different dep version?
+		setuptools/tests/test_build_meta.py::TestBuildMetaBackend::test_build_with_pyproject_config
+		# TODO
+		setuptools/tests/test_sdist.py::test_sanity_check_setuptools_own_sdist
+	)
+
+	local EPYTEST_XDIST=1
+	local -x PRE_BUILT_SETUPTOOLS_WHEEL=${DISTUTILS_WHEEL_PATH}
+	epytest -o tmp_path_retention_policy=all \
+		-m "not uses_network" setuptools
+}