gentoo auto-resync : 02:07:2024 - 08:01:06

2 files changed, 142 insertions, 0 deletions

diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 611c89fae619..d6e640c86268 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -4,8 +4,10 @@ DIST setuptools-69.0.3.tar.gz 2219609 BLAKE2B 1a5e7896c7ea82d51b0aa4794435b9899c
 DIST setuptools-69.5.1.tar.gz 2291314 BLAKE2B 3756dd587136c7e688bdfecf4c0434c0e799f50f9a9a95750d41cb75e26b613b3dc178f43a9e0d21f17c42a7c4ad7461e7986966aefb814e3d0ff05178c82542 SHA512 81f4a5184976a0d4aa070261bb56458c54ec6a479786fa469e98cb336e9a1691b281ae771abe41bc5398fac15b2dd039c07cf014ee00572f46908ce6830fcb6a
 DIST setuptools-70.0.0.tar.gz 2265182 BLAKE2B 436189fbd614473c42a08da75837c5bb2f6fb6bc03bfc9b99db22810fa043fb071c2344659125439d507d10354d42ea5b703e91c0572caad90f5d805eca9ee8d SHA512 13a5ac09401165dc36d2a365c0ea236c01153374c002b062c4b403a537157ce86593848e93e3c26f5c81f5783e43e6aa96d813f9a39a55732ea3911ddc5c337a
 DIST setuptools-70.1.1.tar.gz 2292324 BLAKE2B 9d489117a80ef9cefab6b730680a614d990f338aa54579928bafbe3c87dbb5e4db8527b8a0b6c1090bcd3504be97cc69a9ce979e593d0634d9b66b66bccb25e5 SHA512 63452aa1e1d1dea6ad622a21fcc9334bc3603e45de9a1485f79776e02a0fb3b0a0a8b3e886af73845c3c373348c7021f2e06a5665676e9015ee9855441512136
+DIST setuptools-70.2.0.tar.gz 2332711 BLAKE2B d552e3c7fb8bad3829b6c210827af2a3993afa7c534502d08cb7f87df846f9939b75ce181217c673be7a0c71e81ede437b5f44cf9a42ff13133a9f922e426c1d SHA512 a2b0aaf57d012326475ee7637e65ebbc3b1a09b338850e8b0c6a0f169c49651f934c813d6d347ba1ff04894a4d8341bb5fedbea35d45dbc19f317587bbb35094
 EBUILD setuptools-69.0.3-r1.ebuild 3979 BLAKE2B 58d78a82ac5a3fb98a2844dc3b95cb7880c1b9acfa56f9125ce5aeb5ab334a21596a3a7b43ad4e776fb58ab7f91ac706a82dce176b6c971ebb7200374e69a8e6 SHA512 883c1919f2ba8ae92f1f2c78d99fdc786824765ffe6eac3e09f5c4105c22e2b1299a457f729c629d1bb5a9303b25499f9eccd177707b5a88fbe56ccb6ffe1d6e
 EBUILD setuptools-69.5.1-r1.ebuild 4636 BLAKE2B 9aebfc1c5861b64058a9f5ef14ad0cef531c39f6d85e90c25cfc4553fd3d60a29842cd3b26e33cd1c3dcef4d6b3cfa8873ae423beb01a0448fc7b1450081142d SHA512 f80f437a0501918010ea99fd130860ecd82de2c95b49a7a7db83c07eba82e2a36c0b3808fddfcaf16b659f435e8db394caf8663a3a7bc14c16d43ce03f6466f1
 EBUILD setuptools-70.0.0.ebuild 4649 BLAKE2B 17e47a7fb15219ed058b259330db282c8ee803805f8c6f447060676384aae4311cbd8a537ae89caefa5725c6d1c88bcee51864fab82c068ab6df21cc26df3e16 SHA512 11dcfed4ea59444c2fc32b3e99bea725da481a84cf4bead50749acc0c2531b9ae7a402b20b8f900f4e28708f7643e4c74fb72c73e0f310f17f5826f898b0ab06
 EBUILD setuptools-70.1.1.ebuild 4892 BLAKE2B be2911d8b357ed15ac8d66c6a57ada1037581bdecdcc4222357b725076a435757627ac2e4b7e0e06023726d4c864fae50c191b32a1aeeb4670500bd8e5905109 SHA512 f9db6803121eebcd71a8833d1e34c89df4a83a504f3d493443162c23c11057269fc06ab81e64ff0346546137a636b738087d9215495208d2988e3e1bff0d44c8
+EBUILD setuptools-70.2.0.ebuild 4959 BLAKE2B 1ca70f7b0fa744ad8f04ef2dc26744d6300cbadb0c03f7e644943323c742f141f0f423dc6ef4592ce9a8b5a798ecab6b7d26039233cfcbc03739059fdf76af93 SHA512 193b412ff570bce5440a7d0ea824d27ac4895eec20058fc5bacbba0ae49258f4ee3486bf3d5f450ba68708db9213c2c52f02c6c79ad1bf344617fa207ebd843c
 MISC metadata.xml 469 BLAKE2B 4a26769b09a3785586b22db850b7fc5c4818f31c3ace9cc94476d35df05e50edf6721f3c95ec615c3b2efe071ef284a54ea2d53566316ba653f7830bb48f80bf SHA512 dd682c4ad2e59a97094ebdabe4d1063e2319ed05e1fe9d8c2fafe069badb3b4cf8bb6d9f50e09d2128e2a081c1c69827407ac8aed644ebf70eb4ca1bc9a57319
diff --git a/dev-python/setuptools/setuptools-70.2.0.ebuild b/dev-python/setuptools/setuptools-70.2.0.ebuild
new file mode 100644
index 000000000000..be44dd4c247d
--- /dev/null
+++ b/dev-python/setuptools/setuptools-70.2.0.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{10..13} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# check */_vendor/vendored.txt
+RDEPEND="
+	!!<dev-python/setuptools-rust-1.8.0
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.14[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-subprocess[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/tomli[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+		$(python_gen_cond_dep '
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+		' 3.10)
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}/setuptools-62.4.0-py-compile.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	# breaks tests
+	sed -i -e '/--import-mode/d' pytest.ini || die
+
+	# remove bundled dependencies
+	rm -r */_vendor setuptools/_distutils/_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-e 's:from [.]_vendor[.]:from :' \
+		-i {} + || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# Internet, sigh
+		setuptools/tests/test_integration.py
+		# flaky
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_transitive_extra_dependency
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_distutils_command_dep
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# TODO
+				setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_distutils_command_dep
+				setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_transitive_extra_dependency
+			)
+	esac
+
+	local EPYTEST_XDIST=1
+	epytest -o tmp_path_retention_policy=all setuptools
+}