reinit the tree, so we can have metadata

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/rootpy/rootpy-0.8.3.ebuild b/dev-python/rootpy/rootpy-0.8.3.ebuild
new file mode 100644
index 000000000000..9823bde1b34e
--- /dev/null
+++ b/dev-python/rootpy/rootpy-0.8.3.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="readline"
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="Pythonic layer on top of the ROOT framework's PyROOT bindings"
+HOMEPAGE="http://rootpy.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples test"
+
+RDEPEND="
+	sci-physics/root[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pytables[${PYTHON_USEDEP}]
+	dev-python/root_numpy[${PYTHON_USEDEP}]
+	dev-python/termcolor[${PYTHON_USEDEP}]"
+
+DEPEND="
+	sci-physics/root[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+# TOFIX: tests go in an infinite loop error
+RESTRICT=test
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	nosetests -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}