gentoo resync : 29.12.2022

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/requests-mock/requests-mock-1.9.3-r1.ebuild b/dev-python/requests-mock/requests-mock-1.9.3-r1.ebuild
new file mode 100644
index 000000000000..f6ab5d2b33d0
--- /dev/null
+++ b/dev-python/requests-mock/requests-mock-1.9.3-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Mock out responses from the requests package"
+HOMEPAGE="https://github.com/jamielennox/requests-mock"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
+
+RDEPEND="
+	>=dev-python/requests-2.3[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-0.8[${PYTHON_USEDEP}]
+	test? (
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-obj-has-no-attr-url.patch"
+)
+
+distutils_enable_sphinx doc/source
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Disable reno which only works inside a git repository
+	sed -i "s/'reno.sphinxext',//" doc/source/conf.py || die
+	# Remove the release notes section which requires reno
+	rm doc/source/release-notes.rst || die
+	sed -i '/^=============$/,/release-notes/d' doc/source/index.rst || die
+	# Disable a test which requires purl (not in the tree)
+	sed -i -e "/^import purl$/d" -e "s/test_with_purl/_&/" \
+		tests/test_adapter.py || die
+	distutils-r1_python_prepare_all
+}