gentoo resync : 02.08.2019

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/qrcode/qrcode-6.1.ebuild b/dev-python/qrcode/qrcode-6.1.ebuild
new file mode 100644
index 000000000000..b59ee7e4b562
--- /dev/null
+++ b/dev-python/qrcode/qrcode-6.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="QR Code generator on top of PIL"
+HOMEPAGE="https://pypi.org/project/qrcode/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# optional deps:
+# - pillow and lxml for svg backend, set as hard deps
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2) )"
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Testing failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman doc/qr.1
+}