gentoo auto-resync : 01:11:2024 - 03:04:33

2 files changed, 109 insertions, 0 deletions

diff --git a/dev-python/pythran/Manifest b/dev-python/pythran/Manifest
index b9c7049cd633..ee7bf3d98308 100644
--- a/dev-python/pythran/Manifest
+++ b/dev-python/pythran/Manifest
@@ -1,3 +1,5 @@
 DIST pythran-0.16.1.gh.tar.gz 3680817 BLAKE2B 2a4b928e9d0ce68248eb543c97da5afca900d81bc660377313617149c5aae7529a371bfd3604dd9feb6e38f834360fef881c8324ae72b585d8ab86e867c2f6b3 SHA512 7a89546b52bdae9bdaeba42768ac822c584a3714b8f4e32417d793454dc0b5492342dfd393d92f8ecee12c854bc39e418f5860aadd00d328afef7b17ebddec99
+DIST pythran-0.17.0.gh.tar.gz 3697173 BLAKE2B 90f765283e4346392eb69d8e6fadf4b00469779bd7fb8dc99084ed0d2d940a1ca949c9dd0eb0fc484c2938de79b1e3650c417dc1cd30786b25b6781c519a629d SHA512 af14cd497bcbef7ac97b42b80e297e641bd520f51938b04a68ebf01de86d6900926653c01ff99b1af7f699674094241099101f1501acfae2be5dc9d1724af777
 EBUILD pythran-0.16.1-r2.ebuild 3030 BLAKE2B c4d5497948b0d70f465678a147ae4846b0d45dbd181ff44ea1bf356065bd3ac2f4e6986478e5e622baf16ed9d0edf50d9024b3747238d97da36c170ca1b725e6 SHA512 8a2e5c89fb8af631a3cd2a51c5fc595c97f7635575dbe10ee43b365a4e8a416436393ef3598b8f5b233651a7b2c97271df1344409078a7fa9aad60d7ef4945ad
+EBUILD pythran-0.17.0.ebuild 2988 BLAKE2B 16972b461955f9c8257d53e110e8d369f49b51da7622d36c4ed33061052c392626619c62b16ec53941a5993f14169e6846929cc776271887a3bee91314736410 SHA512 03c72b52f2abf8e81bb333665bd59ca9f8250d704c942354150508495722687a4bdd0777854895f6183212173ffe917c096458f2f1037118e7d25325b5aec469
 MISC metadata.xml 354 BLAKE2B e7ec71fae294f6f697b0fd99b0ccef24049af7999866344e8da2ebc40bc2988a21f2cb0374b52b781a5f8b55f26ebca364dc93f4e69d957a3ff6bd3c32cd988d SHA512 9008d270ea6757557482edb55c5848aea9a29abfbbad65d93000660a1e51ad2456a2b7ccfcacb80da23b3dd38cee2c4da9645aed48a35edb4a497bbe3a80dd7f
diff --git a/dev-python/pythran/pythran-0.17.0.ebuild b/dev-python/pythran/pythran-0.17.0.ebuild
new file mode 100644
index 000000000000..03a72413f83d
--- /dev/null
+++ b/dev-python/pythran/pythran-0.17.0.ebuild
@@ -0,0 +1,107 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+	https://pypi.org/project/pythran/
+	https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+	https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-libs/boost
+	dev-cpp/xsimd
+	=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+	=dev-python/gast-0.6*[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.4[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-73.0.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-libs/boost
+		dev-cpp/xsimd
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		virtual/cblas
+		!!dev-python/setuptools-declarative-requirements
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_configure() {
+	# vendored C++ headers -- use system copies
+	rm -r pythran/{boost,xsimd} || die
+
+	if use test ; then
+		# https://bugs.gentoo.org/916461
+		sed -i \
+			-e 's|blas=blas|blas=cblas|' \
+			-e 's|libs=|libs=cblas|' \
+			pythran/pythran-*.cfg || die
+	fi
+}
+
+python_test() {
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	local EPYTEST_DESELECT=(
+		# TODO
+		pythran/tests/test_numpy_ufunc_unary.py::TestNumpyUFuncUnary::test_signbit0
+	)
+
+	if has_version ">=dev-python/numpy-2[${PYTHON_USEDEP}]"; then
+		case ${EPYTHON} in
+			pypy3)
+				EPYTEST_DESELECT+=(
+					pythran/tests/test_distutils.py::TestDistutils::test_setup_bdist_install3
+					pythran/tests/test_distutils.py::TestDistutils::test_setup_build3
+					pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install
+					pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install2
+					pythran/tests/test_distutils.py::TestDistutils::test_setup_sdist_install3
+					pythran/tests/test_distutils.py::TestMeson::test_meson_build
+					pythran/tests/test_exception.py::TestException::test_multiple_tuple_exception_register
+					pythran/tests/test_ndarray.py::TestNdarray::test_ndarray_fancy_indexing1
+					pythran/tests/test_numpy_fft.py::TestNumpyFFTN::test_fftn_1
+					pythran/tests/test_numpy_func0.py::TestNumpyFunc0::test_ravel0
+					pythran/tests/test_numpy_func3.py::TestNumpyFunc3::test_list_imag0
+					pythran/tests/test_numpy_random.py::TestNumpyRandom::test_numpy_uniform_size_int
+					pythran/tests/test_set.py::TestSet::test_fct_symmetric_difference_update
+				)
+				;;
+			python3.13)
+				EPYTEST_DESELECT+=(
+					# repr() differences?
+					pythran/tests/test_xdoc.py::TestDoctest::test_tutorial
+				)
+		esac
+	fi
+
+	epytest
+}