gentoo auto-resync : 17:03:2025 - 00:29:37

2 files changed, 96 insertions, 0 deletions

diff --git a/dev-python/pythran/Manifest b/dev-python/pythran/Manifest
index 7d0f72a5945b..08bb00e3ea81 100644
--- a/dev-python/pythran/Manifest
+++ b/dev-python/pythran/Manifest
@@ -2,4 +2,5 @@ DIST pythran-0.16.1.gh.tar.gz 3680817 BLAKE2B 2a4b928e9d0ce68248eb543c97da5afca9
 DIST pythran-0.17.0.gh.tar.gz 3697173 BLAKE2B 90f765283e4346392eb69d8e6fadf4b00469779bd7fb8dc99084ed0d2d940a1ca949c9dd0eb0fc484c2938de79b1e3650c417dc1cd30786b25b6781c519a629d SHA512 af14cd497bcbef7ac97b42b80e297e641bd520f51938b04a68ebf01de86d6900926653c01ff99b1af7f699674094241099101f1501acfae2be5dc9d1724af777
 EBUILD pythran-0.16.1-r3.ebuild 3032 BLAKE2B dfba64db09dd747b0381cbe855b3cda5c6978ade221f2a5bb263b9f7840e910b34d5cf2bc66859d608200e72fc5567f27c4a72f61163da5c1dd552fe818cbb1c SHA512 fc2f4627af186fb0755aa9aaa5448bfb53310601cc5912799ad565efb03c6c56f4298d0ee2c435621a55031f70010bed19149dadc2859426c526c3bea9f306c9
 EBUILD pythran-0.17.0-r1.ebuild 2989 BLAKE2B 92876adc09c450a53f830b94a00430eed888feaa51a5aa73e774ec63a4922117212df189080e896eb468dd7c5523afa64791f4364f9f75ec4fd4d3cdf3aaee18 SHA512 1b3beebd501e5a65f32ed033de95c653678ee5f6eb8c8f12374a275b63aea7e29b849cd2b3747f5a5833d710038436dd82c41abd55724491bc2b4bc3856f5e9d
+EBUILD pythran-0.17.0-r2.ebuild 2116 BLAKE2B 2809debcd7a2507f58d90ca768c215a4e763650971638fab9583ae86d1367d09dcd98728ca786403952d92f3b0689724376004d495f11e01b51264fec4b24501 SHA512 3ec55e8ef0afb277bf0ef6a381d3334c7849958aba59a6e1aa55e3c74e1a0aeac3da8c917784c58d30b00f24ce06651eb14972384db5609b1d5bc72ccbe39ed0
 MISC metadata.xml 354 BLAKE2B e7ec71fae294f6f697b0fd99b0ccef24049af7999866344e8da2ebc40bc2988a21f2cb0374b52b781a5f8b55f26ebca364dc93f4e69d957a3ff6bd3c32cd988d SHA512 9008d270ea6757557482edb55c5848aea9a29abfbbad65d93000660a1e51ad2456a2b7ccfcacb80da23b3dd38cee2c4da9645aed48a35edb4a497bbe3a80dd7f
diff --git a/dev-python/pythran/pythran-0.17.0-r2.ebuild b/dev-python/pythran/pythran-0.17.0-r2.ebuild
new file mode 100644
index 000000000000..92794c1be77e
--- /dev/null
+++ b/dev-python/pythran/pythran-0.17.0-r2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 pypy3_11 python3_{10..13} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+	https://pypi.org/project/pythran/
+	https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+	https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-libs/boost
+	dev-cpp/xsimd
+	=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+	=dev-python/gast-0.6*[${PYTHON_USEDEP}]
+	dev-python/numpy:=[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.4[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-73.0.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-libs/boost
+		dev-cpp/xsimd
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		virtual/cblas
+		!!dev-python/setuptools-declarative-requirements
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_configure() {
+	# vendored C++ headers -- use system copies
+	rm -r pythran/{boost,xsimd} || die
+
+	# https://bugs.gentoo.org/916461
+	sed -i \
+		-e 's|blas=blas|blas=cblas|' \
+		-e 's|libs=|libs=cblas|' \
+		pythran/pythran-*.cfg || die
+	# boost.math 1.82.0+ requires -std=c++14
+	sed -i \
+		-e 's|-std=c++11|-std=c++14|' \
+		pythran/pythran-*.cfg || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	if has_version ">=dev-python/numpy-2[${PYTHON_USEDEP}]"; then
+		case ${EPYTHON} in
+			pypy3*)
+				EPYTEST_DESELECT+=(
+					# tries to link to libpypy*.so
+					pythran/tests/test_distutils.py::TestMeson::test_meson_build
+				)
+				;;
+			python3.13)
+				EPYTEST_DESELECT+=(
+					# repr() differences?
+					pythran/tests/test_xdoc.py::TestDoctest::test_tutorial
+				)
+				;;
+		esac
+	fi
+
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}