gentoo resync : 15.01.2020

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1.ebuild b/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1.ebuild
new file mode 100644
index 000000000000..7676128f1302
--- /dev/null
+++ b/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3 distutils-r1
+	EGIT_REPO_URI="https://github.com/python-xmp-toolkit/${PN}.git"
+else
+	inherit distutils-r1
+	SRC_URI="https://github.com/python-xmp-toolkit/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Library for working with XMP metadata"
+HOMEPAGE="https://github.com/python-xmp-toolkit/python-xmp-toolkit/ https://pypi.org/project/python-xmp-toolkit/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/unittest2[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		media-libs/exempi )"
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/.build/html/. )
+	distutils-r1_python_install_all
+}