gentoo auto-resync : 03:01:2025 - 06:31:16

3 files changed, 113 insertions, 0 deletions

diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index a733ff65edb0..ea038eb6d6b7 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1,3 +1,5 @@
+AUX python-lsp-server-1.12.0-jedi19-compat.patch 584 BLAKE2B 58aeb1c9370f3c028c2c8abf1c2ac85bd3bb4ad3af549d4e75bbf119973a0503c8822871c5614d6269e321674a04a6994ce6a49a300738304ce3d0e860f4cc9b SHA512 6b929110e1c9f27a87e7641bd4e5656b45d76db09a8b9c4a9319162a64a00ca3b604c164c71aedf83fd4eb2bdd4df1a1f128fde38279d904c562141e566fa257
 DIST python_lsp_server-1.12.0.tar.gz 114328 BLAKE2B 3c94642be615822058debda5cb9de07529e7d269938029d66ade7eb7db801e7db90ae724f449e1133a813967e94bcfc71247f0392db1c495af5fff89ae66bd03 SHA512 74cbd8012f5e027fb117105302ba92e142900e88565d7f95d2dad72f2624048fff3c2c85085b648bd1ff86f6f6eb679aa34d5f6d9ae54b80e96b6ed472785b32
+EBUILD python-lsp-server-1.12.0-r1.ebuild 2797 BLAKE2B 0e573f07c0aac1c6342219d65826655bd6bdb06b5ce75eda976434994411a2b2b4c44009e9f6162884e3b831b261c69326419c89caae2e0055e2bfa6bfd46d62 SHA512 8703a7e96c664553b1e107c12fcb6e82aa77524366db75a5803d1c4c1ba188870312956168eaed1a89ce7132ee43fbd2488fb7aaa719a660cf2b8fc090bc82d0
 EBUILD python-lsp-server-1.12.0.ebuild 2596 BLAKE2B e5e5862da9f32867c2e63e7aff7d8299fbae07f7ffffecbcf596324eaf96910a5fcfd14573fe9dcc28a4230a02da59c38376f95e616467efe251345e00c17890 SHA512 1cd964284b18e3632b0c2e049767f3eb284de8a71236c15b871bd56fe35ea445ad156f8dc38819d9a5050a5c3294d6e717039b6e2ca683f47dcbc63ed5299cb7
 MISC metadata.xml 597 BLAKE2B 2b7babd22792b973dd6eb9c7f127e4e91b4e534a36662c9f773c5a27aaedfd676fb31eaab4e5b337bb203ae8729e0e2ac8f31a8e7edc6695a7b7967b51fec1da SHA512 1d6a89489d5f701d259b9d1e200fbdf51b368258556c9b66efb313690f3551c089bd03935ff95e73845b79e5ec5031b2f34eea7a853f1f8de8b88abcb2f09663
diff --git a/dev-python/python-lsp-server/files/python-lsp-server-1.12.0-jedi19-compat.patch b/dev-python/python-lsp-server/files/python-lsp-server-1.12.0-jedi19-compat.patch
new file mode 100644
index 000000000000..b5dd4c352dbb
--- /dev/null
+++ b/dev-python/python-lsp-server/files/python-lsp-server-1.12.0-jedi19-compat.patch
@@ -0,0 +1,16 @@
+https://github.com/python-lsp/python-lsp-server/pull/609
+diff --git a/test/plugins/test_completion.py b/test/plugins/test_completion.py
+index d1ca5ef8..3e768f06 100644
+--- a/test/plugins/test_completion.py
++++ b/test/plugins/test_completion.py
+@@ -179,9 +179,7 @@ def test_jedi_completion_with_fuzzy_enabled(config, workspace) -> None:
+ 
+     assert items
+ 
+-    expected = "commonprefix(m)"
+-    if JEDI_VERSION == "0.18.0":
+-        expected = "commonprefix(list)"
++    expected = "isabs(s)"
+     assert items[0]["label"] == expected
+ 
+     # Test we don't throw with big character
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.12.0-r1.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.12.0-r1.ebuild
new file mode 100644
index 000000000000..8a673c456491
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.12.0-r1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-server/
+	https://pypi.org/project/python-lsp-server/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="all-plugins"
+
+PLUGIN_DEP="
+	>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
+	>=dev-python/flake8-7.1[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyflakes-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-3.1[${PYTHON_USEDEP}]
+	>=dev-python/rope-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		${PLUGIN_DEP}
+	)
+"
+BDEPEND="
+	test? (
+		${PLUGIN_DEP}
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/qtpy[gui,testlib,${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	# https://github.com/python-lsp/python-lsp-server/pull/609
+	"${FILESDIR}/${PN}-1.12.0-jedi19-compat.patch"
+)
+
+# Note: xdist breaks some tests
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by presence of pathlib2
+		'test/plugins/test_autoimport.py'
+		# Requires pyqt5
+		'test/plugins/test_completion.py::test_pyqt_completion'
+	)
+	local EPYTEST_IGNORE=(
+		# pydocstyle is archived upstream and broken with py3.12
+		test/plugins/test_pydocstyle_lint.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}