reinit the tree, so we can have metadata

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/pyserial/pyserial-3.2.1.ebuild b/dev-python/pyserial/pyserial-3.2.1.ebuild
new file mode 100644
index 000000000000..59ef3d4e7035
--- /dev/null
+++ b/dev-python/pyserial/pyserial-3.2.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Serial Port extension"
+HOMEPAGE="https://github.com/pyserial/pyserial https://pypi.python.org/pypi/pyserial"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="doc examples"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+# Usual avoid d'loading un-needed objects.inv file
+PATCHES=( "${FILESDIR}"/mapping.patch )
+
+DOCS=( CHANGES.rst README.rst )
+
+python_compile_all() {
+	use doc && emake -C documentation html
+}
+
+python_test() {
+	${EPYTHON} test/run_all_tests.py || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( documentation/_build/html/. )
+	distutils-r1_python_install_all
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}