gentoo auto-resync : 24:11:2024 - 03:02:54

3 files changed, 88 insertions, 0 deletions

diff --git a/dev-python/pysdl2/Manifest b/dev-python/pysdl2/Manifest
new file mode 100644
index 000000000000..10abeb41264a
--- /dev/null
+++ b/dev-python/pysdl2/Manifest
@@ -0,0 +1,3 @@
+DIST PySDL2-0.9.16.tar.gz 773537 BLAKE2B 5cfe4ab3981a665fc7f7606c07a3252e58c2706e45ab41d0d6444b4d3fb1c8805b5fd67e770a8a64538d305be0013a4d599ee81f5de0c5370146edc9d4d858df SHA512 ffe7abe8e828926934677c81a42c9af794c4817144eba50c40430c150d476dea40f0b36e639b2c270cbd8e00ab5bf5b032a4c0e514255cceef8161c8d76f8cb2
+EBUILD pysdl2-0.9.16.ebuild 1799 BLAKE2B f74ad68a04b3c4fc20186f535c0d90c9d83587710826e68802a435fadc25a43282ae0446c996a551f4a1172b20c5eb86847b1f53b54840bf26d8adeff39b26dd SHA512 a1cefe5dded69ba39b37a54af961ce1d4c687666922896e448c1b88ffa78799702aee8f09512097cb3b75977c6ca9a0db3d6beb2dcb74f8a1360fb5c17277679
+MISC metadata.xml 450 BLAKE2B f92f2f7529e3a09d18c88a51f78ed520d7b4756a99776d70bb7ad4e452ae6cd9a67560ebfaafcacbd73e945282fc28ecdb48d54b2c2eb5b18d3f944401650349 SHA512 de7f757b195170ee865e34dcc214d0a57912e50631291045c485f58ba05fa87b7fc57878333021c7b9d3f8609e9afa4190f4c4062fb7a8136498875aecee615c
diff --git a/dev-python/pysdl2/metadata.xml b/dev-python/pysdl2/metadata.xml
new file mode 100644
index 000000000000..4f40190355c3
--- /dev/null
+++ b/dev-python/pysdl2/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>mgorny@gentoo.org</email>
+		<name>Michał Górny</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">py-sdl/py-sdl2</remote-id>
+		<remote-id type="pypi">PySDL2</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/pysdl2/pysdl2-0.9.16.ebuild b/dev-python/pysdl2/pysdl2-0.9.16.ebuild
new file mode 100644
index 000000000000..94ff2c96b9cd
--- /dev/null
+++ b/dev-python/pysdl2/pysdl2-0.9.16.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=PySDL2
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
+HOMEPAGE="
+	https://github.com/py-sdl/py-sdl2/
+	https://pypi.org/project/PySDL2/
+"
+
+LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Optional deps:
+# - dev-python/numpy,
+# - dev-python/pillow,
+# - media-libs/sdl2-* (loaded dynamically via ctypes).
+#
+# If a reverse dependency needs the specific module, it should
+# explicitly depend on the optional module in question. You also
+# probably need to explicitly require some media-libs/libsdl2 flags.
+RDEPEND="media-libs/libsdl2"
+
+# Require all of SDL2 libraries and at least the most common subsystems
+# for better test coverage.
+DEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/libsdl2[joystick,sound,video]
+		media-libs/sdl2-gfx
+		media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+		|| (
+			media-libs/sdl2-mixer[flac]
+			media-libs/sdl2-mixer[midi]
+			media-libs/sdl2-mixer[mod]
+			media-libs/sdl2-mixer[mp3]
+			media-libs/sdl2-mixer[opus]
+		)
+		media-libs/sdl2-ttf
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# pysdl2 was misusing libsdl2's error API. Fixed upstream already
+		# but it didn't land in 0.9.16.
+		# https://bugs.gentoo.org/916120
+		# https://bugs.gentoo.org/916118
+		sdl2/test/gamecontroller_test.py
+		sdl2/test/hidapi_test.py::test_SDL_hid_enumerate
+	)
+
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=dummy
+	local -x SDL_RENDER_DRIVER=software
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -x
+}