gentoo resync : 14.07.2018

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-python/pushbullet-py/pushbullet-py-0.11.0.ebuild b/dev-python/pushbullet-py/pushbullet-py-0.11.0.ebuild
new file mode 100644
index 000000000000..4a035f018675
--- /dev/null
+++ b/dev-python/pushbullet-py/pushbullet-py-0.11.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+DESCRIPTION="A simple python client for pushbullet.com"
+HOMEPAGE="https://github.com/randomchars/pushbullet.py"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_test() {
+	# skip tests which require network access
+	PUSHBULLET_API_KEY= py.test \
+		-k "not (test_auth or test_decryption)" \
+		|| die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r example/.
+	fi
+	distutils-r1_python_install_all
+}