gentoo resync : 20.03.2022

5 files changed, 214 insertions, 6 deletions

diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 4946b56ac27a..dfa51d99b060 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,4 +1,7 @@
 DIST pillow-9.0.0.tar.gz 49510604 BLAKE2B c3b0d07e8fe280e3a253067c4da18ac2dee40d216280632d58ddaa7848e13a165587b9aca61c98f8b5380e53d6d59a4097320bacf6e016e236239af518ec7780 SHA512 d2fd74dd1b8824d994e3767ef9794175dd2f4adc8173612432a3e171705723ee8757d299a87fb1c010b40919792c1ca76578f41977ee3303ccb6f75165deb791
-EBUILD pillow-9.0.0-r1.ebuild 2892 BLAKE2B 133ef433e8cb05632dc4162ee68b390f86d7cf2451fb34541ab4f2002bea720725344f7b9808833ac3029612257a081af63d0a89cf9335d51a82a1389267952d SHA512 95ced5f48b3a628aa751cab412f80e6a1f002b01b4e2fda12b88d2813ba01ed25c2e5b2a2393b7cda117884686d3112aef8c1cc6fb1edf480cdd5f132a83b852
-EBUILD pillow-9.0.0.ebuild 2640 BLAKE2B 6c6d029aacbcd7d9038f4fbb854f42570b6de2e9f7c579b299357cb9bbb28ae461ac245b516743e5567e8599e8e76aac5b593d67ff92d2077d3a254884ea2ca0 SHA512 dba3365b0f73900ecf375895d85dab361c3502a6f7645cf438f66d19d54a20ff9a5ad37db6f54508c80934a37ad9136b9c32937883610c3892cb587315825a97
+DIST pillow-9.0.1.tar.gz 49512045 BLAKE2B 14f0969c87c57bad8fc38d873bba7a118d666e8b2e62e777ea17197e5ca973b3994bafb56b4464cde4059f2fc4040d73e7ddeec2a1053aeb1f201bf2ec2b38e2 SHA512 73893fe079bb2405c87b73b13b6eff198fb8970a891a7c9586bd2620ea0310d54cb35b1d594c6c6d3859e47d8d467700f987ae32aa6d3dc4a2e9286e8749869e
+EBUILD pillow-9.0.0-r1.ebuild 2889 BLAKE2B 5aa19477632d17ae9ce031f5dbcab51e1b315fd7b8a82cd3e3cf4c1ef200180d8bbdd607dedcbf390e319bdcfe8960d966d4f5ae1544de413b408aaa74549546 SHA512 d902760494cd2d8dcfc32da0808678ab5198d8eaf4c1e8534ec586f380de317b15944627d07ae0984b11e9a06afc98fe0b115e981a5844b73af0370572f41ebb
+EBUILD pillow-9.0.0.ebuild 2637 BLAKE2B 393b8e2fa5dbb13ef28acfbaf87709496617eaa904ada6f5503745e933a960aef982f5e11df5e4204b8cd754eb505508b79db01bce3d15089d9f56621753eb7e SHA512 af0aed73003e291f08aba7ae98bf803daadb1fceac2ca058a994c62865773648e04aa310fdf445ce2c8d5d7d965bfc113d40df52447e11ce340f6997f2da91fc
+EBUILD pillow-9.0.1-r1.ebuild 2888 BLAKE2B 86e987d7dbe47bf8a571e24c3da622f9c2c37cd2704eaee2f5bbc4e022da88e61dc9096ba28b1637b3e40109d815a98e20576cc80a55a3132710f37f78074cc6 SHA512 fc67f88e28ad74f4150debb7f302b86d689ac7f4642a1696f64523d07c921fe0d9c77f8ff210809a12223b6d767da42791784e75b0fc246f1df0b4bdc3877c40
+EBUILD pillow-9.0.1.ebuild 2639 BLAKE2B a77660a7c500f3df1f1e0af026ce44610a9f63476bd52e48c215ddd32d692f0da1b565f37752014409f711626dabac600e18c66b032e38feeff8f48b5f2dc1dd SHA512 7200c180661b56943c1df9a6161e06a9afa041cdeb78965fcde758d5dd1cf5d5ade8acfdc954f4bc8fbd741f3511b32b3509c79690bbbc7f50f54c5a5312fb4b
 MISC metadata.xml 480 BLAKE2B b42e6b01b1572a0688ef93025a0baaa95b9fd0c3a5eabcddcea7145dd880a95f11859b255ae24a376ca792559ffcf940c67da1b19f2f579dbc6ef6de68903749 SHA512 b98a33136aef4498051370bce3295b000687ddb80b4d909b26b32af61b4e4638d07269f7924ae039420af63236aa74b51e23d2feae1c83349683073c69714582
diff --git a/dev-python/pillow/pillow-9.0.0-r1.ebuild b/dev-python/pillow/pillow-9.0.0-r1.ebuild
index 82a914de8bf7..0dd406cd6c5f 100644
--- a/dev-python/pillow/pillow-9.0.0-r1.ebuild
+++ b/dev-python/pillow/pillow-9.0.0-r1.ebuild
@@ -70,10 +70,10 @@ python_configure_all() {
 		$(usepil zlib)_zlib = True
 	EOF
 
-	# setup.py sucks at adding the right toolchain paths but it does
+	# setup.py won't let us add the right toolchain paths but it does
 	# accept additional ones from INCLUDE and LIB so set these. You
 	# wouldn't normally need these at all as the toolchain should look
-	# here anyway but this setup.py does stupid things.
+	# here anyway but it doesn't for this setup.py.
 	export \
 		INCLUDE="${ESYSROOT}"/usr/include \
 		LIB="${ESYSROOT}"/usr/$(get_libdir)
diff --git a/dev-python/pillow/pillow-9.0.0.ebuild b/dev-python/pillow/pillow-9.0.0.ebuild
index 4d188aa9d485..c1fb9e79bab2 100644
--- a/dev-python/pillow/pillow-9.0.0.ebuild
+++ b/dev-python/pillow/pillow-9.0.0.ebuild
@@ -65,10 +65,10 @@ python_configure_all() {
 		$(use_enable zlib)
 	)
 
-	# setup.py sucks at adding the right toolchain paths but it does
+	# setup.py won't let us add the right toolchain paths but it does
 	# accept additional ones from INCLUDE and LIB so set these. You
 	# wouldn't normally need these at all as the toolchain should look
-	# here anyway but this setup.py does stupid things.
+	# here anyway but it doesn't for this setup.py.
 	export \
 		INCLUDE="${ESYSROOT}"/usr/include \
 		LIB="${ESYSROOT}"/usr/$(get_libdir)
diff --git a/dev-python/pillow/pillow-9.0.1-r1.ebuild b/dev-python/pillow/pillow-9.0.1-r1.ebuild
new file mode 100644
index 000000000000..e8726d4477e8
--- /dev/null
+++ b/dev-python/pillow/pillow-9.0.1-r1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://python-pillow.org/"
+SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	imagequant? ( media-gfx/libimagequant:0 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:0= )
+	xcb? ( x11-libs/libxcb )
+	zlib? ( sys-libs/zlib:0= )"
+RDEPEND="${DEPEND}
+	dev-python/olefile[${PYTHON_USEDEP}]"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		|| (
+			media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[png]
+		)
+	)
+"
+
+usepil() {
+	usex "${1}" enable disable
+}
+
+python_configure_all() {
+	# It's important that these flags are also passed during the install phase
+	# as well. Make sure of that if you change the lines below. See bug 661308.
+	cat >> setup.cfg <<-EOF || die
+		[build_ext]
+		disable_platform_guessing = True
+		$(usepil truetype)_freetype = True
+		$(usepil jpeg)_jpeg = True
+		$(usepil jpeg2k)_jpeg2000 = True
+		$(usepil lcms)_lcms = True
+		$(usepil tiff)_tiff = True
+		$(usepil imagequant)_imagequant = True
+		$(usepil webp)_webp = True
+		$(usepil webp)_webpmux = True
+		$(usepil xcb)_xcb = True
+		$(usepil zlib)_zlib = True
+	EOF
+
+	# setup.py won't let us add the right toolchain paths but it does
+	# accept additional ones from INCLUDE and LIB so set these. You
+	# wouldn't normally need these at all as the toolchain should look
+	# here anyway but it doesn't for this setup.py.
+	export \
+		INCLUDE="${ESYSROOT}"/usr/include \
+		LIB="${ESYSROOT}"/usr/$(get_libdir)
+
+	# We have patched in this env var.
+	tc-export PKG_CONFIG
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
+	epytest -p no:relaxed || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pillow/pillow-9.0.1.ebuild b/dev-python/pillow/pillow-9.0.1.ebuild
new file mode 100644
index 000000000000..81f5cf5eef02
--- /dev/null
+++ b/dev-python/pillow/pillow-9.0.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://python-pillow.org/"
+SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 hppa ~ia64 ~m68k ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
+IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	imagequant? ( media-gfx/libimagequant:0 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:0= )
+	xcb? ( x11-libs/libxcb )
+	zlib? ( sys-libs/zlib:0= )"
+RDEPEND="${DEPEND}
+	dev-python/olefile[${PYTHON_USEDEP}]"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		|| (
+			media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[png]
+		)
+	)
+"
+
+python_configure_all() {
+	# It's important that these flags are also passed during the install phase
+	# as well. Make sure of that if you change the lines below. See bug 661308.
+	DISTUTILS_ARGS=(
+		build_ext
+		--disable-platform-guessing
+		$(use_enable truetype freetype)
+		$(use_enable jpeg)
+		$(use_enable jpeg2k jpeg2000)
+		$(use_enable lcms)
+		$(use_enable tiff)
+		$(use_enable imagequant)
+		$(use_enable webp)
+		$(use_enable webp webpmux)
+		$(use_enable xcb)
+		$(use_enable zlib)
+	)
+
+	# setup.py won't let us add the right toolchain paths but it does
+	# accept additional ones from INCLUDE and LIB so set these. You
+	# wouldn't normally need these at all as the toolchain should look
+	# here anyway but it doesn't for this setup.py.
+	export \
+		INCLUDE="${ESYSROOT}"/usr/include \
+		LIB="${ESYSROOT}"/usr/$(get_libdir)
+
+	# We have patched in this env var.
+	tc-export PKG_CONFIG
+}
+
+python_test() {
+	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
+	virtx epytest -p no:relaxed
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}