gentoo auto-resync : 19:10:2022 - 13:58:24

2 files changed, 212 insertions, 0 deletions

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 4e8bf7c11ad8..cb72e3366737 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -1,6 +1,8 @@
 DIST pandas-1.4.4.tar.gz 4949620 BLAKE2B 7ce236ae28ed6c6857a3acf6936aad2b1dc53a048986809d8dedbb9595dd2234bacbe114b74d8a171a6b31254372ea262566b134e7b5b24d5d4666938c7e6154 SHA512 a12e92dd751ed2342d9291724833732cdadbc9791e59533b9efded570b9893bacbe2f10e6bc70d673adb9356dcb0ae3d64d8a1dfe6ae8a3c70e474556ded4d91
 DIST pandas-1.5.0.tar.gz 5191537 BLAKE2B c7dec1d0197e6ac860667177f0f255bb327dbd48fe4501280d578b93f4496e61c0847dc478effeb8c5729d7a9d3e8a643c01db095a9843d6d211a9420f94d42c SHA512 8d340da1e0dff9b64c8993359b35ddcfc796fa15fee1bf1a27ea5a12e33f8b20d45bfac0ff9275b16ff0d4f7855a73962629e06c62bc08ca5e21b4ef1ea29ec2
+DIST pandas-1.5.1.tar.gz 5199286 BLAKE2B 17d98870f3397d7a9289a18708021a614b1d456e2ea99dae8927727aabb8aab73bd31f25c3035947f8f4c38404e7d971bf999500b300307b19a2cf6029763d0e SHA512 e5f25f21f17f36c6488f14fbfa391beb9f1989652de01cb8346d2826dead9331fea27295ee1e6f42d0875f2f1a91fcd23d606edd339432589bca5ba8d89e5ecd
 EBUILD pandas-1.4.4.ebuild 6486 BLAKE2B 65421968a776be789bd034222242ec3ed5a43b25e0fbe7f136b20ed46d16f8bf99af85673a1544aceef25997fc761f7a558c10f9358b06061a654772529861b3 SHA512 78f9a087894510b87e777e6ed0c64d3c75b640858f8be52332767985dd111dca46d4338d40bfd662d0785d06e8f5609657108eae740442ae6edd0e8cdac9f5e7
 EBUILD pandas-1.5.0-r1.ebuild 6752 BLAKE2B cdf46e171d595990224a00261be8a70cf03c7bf4860d55ac04edf2a8fce8c92d77cc542814023ef9f1f775ed1689f98cbc3fa07dc09e4416a5ecf605e3be844f SHA512 3cb71918734101adf9c27ec6e3f72e41edb086b0a14fc48876bdb0c132f6aee8adc6914c86344319d4888050ad431f18481409198d5bcf7c15e546dac3204101
 EBUILD pandas-1.5.0.ebuild 6579 BLAKE2B 215cbfefa2456ab577cb13e687a034325afc4fdc184d3810dc8495e38588257c8f90f5a4de116f43072b808a1c6716b40759134ac6394cdb526fab5c041a45e4 SHA512 58a27b293a7da2ecf84631789357c22c32e108ee9d12b8385d3d0c4101d887f2d413db17e4013860589c0ccd4700a8d2232a659e16d5c278b8e71ae3ce2726dd
+EBUILD pandas-1.5.1.ebuild 6837 BLAKE2B d1e6ba85ce3fecfa09420bdab447bc213e7cddb16a34e10135f1d04c734c3fde91caa298fdfdf4c7b9935af623f9a6a4e6cc85cb73498c9f68a54f04bd40e652 SHA512 186326daf4876ca1762fef866b08694c834a41ee18132f14e9e8ec7f7dee40bdb932e833192ba1a3c9888e894feb91652bbb4676d96c4e2dd2981b3bbeebc942
 MISC metadata.xml 918 BLAKE2B 09b6ef472cbceaade61bfec8780ba3659838cd73f0a19b277d731db75655ac7e65d396f9fa74c19a2d5e03269c541dfe2af59296c048e77744f00bdb55295d4d SHA512 0b1fd089b0ce35a4e3408cd7224a249d427571a638961a8d63dee73b386d03b5a22e4ff085e2e548749f9fc03e9beb18317010d0b67f608dafe305bb4a87ddb2
diff --git a/dev-python/pandas/pandas-1.5.1.ebuild b/dev-python/pandas/pandas-1.5.1.ebuild
new file mode 100644
index 000000000000..abf2b42cbc63
--- /dev/null
+++ b/dev-python/pandas/pandas-1.5.1.ebuild
@@ -0,0 +1,210 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="
+	https://pandas.pydata.org/
+	https://github.com/pandas-dev/pandas/
+	https://pypi.org/project/pandas/
+"
+SRC_URI="
+	https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.7.0[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+# TODO: Re-add dev-python/statsmodel[python3_11] dep once it supports python3_11
+# https://github.com/statsmodels/statsmodels/issues/8287
+OPTIONAL_DEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	|| (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	|| (
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+	)
+	>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.12.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+	!hppa? (
+		$(python_gen_cond_dep '
+			dev-python/statsmodels[${PYTHON_USEDEP}]
+		' python3_{8..10} )
+		>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
+	)
+	X? (
+		|| (
+			dev-python/PyQt5[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+COMMON_DEPEND="
+	>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1-r3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		app-text/pandoc
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/xlrd[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5.5.3[${PYTHON_USEDEP}]
+		dev-python/openpyxl[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.31[${PYTHON_USEDEP}]
+		dev-python/psycopg:2[${PYTHON_USEDEP}]
+		dev-python/xlsxwriter[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="
+	${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# requires package installed
+	sed -e '/extra_compile_args =/s:"-Werror"::' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# test for rounding errors, fails if we have better precision
+		# e.g. on amd64 with FMA or on arm64
+		# https://github.com/pandas-dev/pandas/issues/38921
+		pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+		# TODO
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+		pandas/tests/io/test_clipboard.py::TestClipboard::test_raw_roundtrip
+
+		# TODO: xdist?
+		pandas/tests/test_expressions.py::TestExpressions::test_run_binary
+
+		# TODO: these require a running db server
+		pandas/tests/io/test_sql.py::TestMySQLAlchemy
+		pandas/tests/io/test_sql.py::TestMySQLAlchemyConn
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemy
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemyConn
+
+		# OOMs
+		pandas/tests/io/parser/test_c_parser_only.py::test_bytes_exceed_2gb
+	)
+
+	local -x LC_ALL=C.UTF-8
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	epytest pandas --skip-slow --skip-network -m "not single" \
+		-n "$(makeopts_jobs)" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.0" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-1.3.0"
+	optfeature "miscellaneous statistical functions" dev-python/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}