gentoo resync : 03.11.2021

1 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/mypy/mypy-0.910-r1.ebuild b/dev-python/mypy/mypy-0.910-r1.ebuild
new file mode 100644
index 000000000000..99219a9f53b0
--- /dev/null
+++ b/dev-python/mypy/mypy-0.910-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="http://www.mypy-lang.org/"
+SRC_URI="https://github.com/python/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+# Note: replace toml with tomli on next version bump
+# https://github.com/python/mypy/pull/10824
+RDEPEND="
+	!dev-util/stubgen
+	>=dev-python/psutil-4[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/typed-ast-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	<dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/python/mypy/pull/11017
+	"${FILESDIR}/${P}-py3.10-tests.patch"
+)
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with pytest-xdist 2.3.0
+		# https://github.com/python/mypy/issues/11019
+		mypy/test/teststubtest.py
+	)
+
+	[[ "${EPYTHON}" == "python3.10" ]] && EPYTEST_DESELECT+=(
+		# https://github.com/python/mypy/issues/11018
+		mypyc/test/test_commandline.py::TestCommandLine::testErrorOutput
+	)
+
+	# Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+	# fail with high COLUMNS values
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}