gentoo (valentine's day) resync : 14.02.2021

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/jupyter_core/jupyter_core-4.7.1.ebuild b/dev-python/jupyter_core/jupyter_core-4.7.1.ebuild
new file mode 100644
index 000000000000..3ee1504526a9
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.7.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="dev-python/traitlets[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		>=dev-python/ipython-4.0.1[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinxcontrib-github-alt
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# fails if jupyter is not in system sitedir
+		# (PYTHONPATH is insufficient)
+		jupyter_core/tests/test_command.py::test_not_on_path
+		jupyter_core/tests/test_command.py::test_path_priority
+		# TODO
+		jupyter_core/tests/test_paths.py::test_jupyter_path_prefer_env
+	)
+
+	pytest -vv ${deselect[@]/#/--deselect } ||
+		die "Tests failed with ${EPYTHON}"
+}