gentoo resync : 31.05.2021

2 files changed, 141 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 8abb9a5bd4b1..db3ac28919b4 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,6 +1,8 @@
 AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc6a0b6bbdb524dfc66e0f4a7c69b0eeb2d35efb9d1845d567a11d1afa7881068b4757e42b9baf24dc01ba3026608a38 SHA512 fc4c9e12267ac5f04a2e16ad27334a093638538b8149ff380099fcbeb674a276ab9eb624a508010e37f82c05d5f7ab527a80e386b3e7b61c123ecb8effd9d542
 DIST ipython-7.22.0.tar.gz 5143229 BLAKE2B be78fc7089d620cb9ad437ed8154b37ac8c7cd68ca18a2569cfcf7ea9af968c58eeee18c8d18a1f26459ccef73e59083ac27055c19e4df254836e484ce0a9908 SHA512 2647dcd5e0d9b6afc8d990d2c099ad7ed581b5eff6d657630929e0d0d9f8965e7c7924c51a10a797e7d7406212d7a06c941c163e6f6046aa62130049a9bbc0d0
 DIST ipython-7.23.1.tar.gz 5188898 BLAKE2B 9713b0f1f75e283e53ba19044c9919f0c4d0b1c120e63d7a79ab9c6b8783499ed115e86a24cab34fc13c46245fb43865b851e6f98a2ee729ee35c3db242fa2ba SHA512 9b35626a8a07c6bd0b93552341e5a61d3d90a60c72ad6e3fc71266d9509134366c46a7ae8aeca9c3acc7509dfeab47b5144f105cb3d1d05ef1c7acca6c2f365d
+DIST ipython-7.24.0.tar.gz 5146172 BLAKE2B 9d10eea9c329c78d7698adda999d746cdb305fad71ad521bd2f856590dd1e34010adfef045633bec07f8a6705201325815bbc254c23d74f0a17d73d2c3c060fe SHA512 67f6392b5448f1526da67577e8fa84958c99b3ac71c616c78a034e5c20cd06224134da45a8c3930a3779ce98ebc983bea2f237b5be7e8ba9d6fe97fde91a0608
 EBUILD ipython-7.22.0-r1.ebuild 3761 BLAKE2B 0fde64e41f1827ffaccc69fcb62db96e81c4c755bf7085d8890499eca01c776ed1ef500c20f277c1597c63c231587d2ddaf3ca68265629bf897d08f75a482cfe SHA512 bb27d30f8fa1fae515f1f92cca52846fe78bda310e35c84053cead7438898ec8b3d30475f36db3808d74e4ac02caf80f7bcabce4c570376a9f8661e6fecdb378
 EBUILD ipython-7.23.1.ebuild 3842 BLAKE2B c8e2900a436112ba50c3c5bf505da365359fe914dbbf132dfb901186456276472bfad6d2bc0e1290b1594ccac2d5368ec876e1dd786e58e12e37ac2b005ee3f5 SHA512 921a79ed0b75e69f1c390663e3a7a02263cdbb65cc2e580b5e6b1717d46b9eb742e0382f5aa03c220dd6fe95e8f17b7b27d4e0b87ef6b0915b834f4939a6a87e
+EBUILD ipython-7.24.0.ebuild 3842 BLAKE2B 93e66fbd1e931294001afdad43c3a46f1aa0518fe17b2ba8dd04e928333ac7010f1cf505a67d8a79756f235833a1987027c19892b5b0a212575e8c1012ccce0d SHA512 86423c9f303347a54ba84a1eeeef3d67a4e622b56f4c42c314576056fdee9bf28bd5b19d40340c975d5f72ce34249fc0ef6a3714667ef73dd5b536336825d305
 MISC metadata.xml 2882 BLAKE2B 189477b4ccde9051b61d2a4ff5134907886795f97c5201fc2bf9c012526333151931a1445b6315f286474b71af84253033cbe9bf89bffa7813bfa49a4a07ef6c SHA512 f54fef4552d09a03a8d186c45f917c091928f1de84dfbdd80f1db80912d616d509f10c588de533916d9c494f5b3ca5e6e50a6d8b8c59ea47781311ad4319442a
diff --git a/dev-python/ipython/ipython-7.24.0.ebuild b/dev-python/ipython/ipython-7.24.0.ebuild
new file mode 100644
index 000000000000..c085c76819cb
--- /dev/null
+++ b/dev-python/ipython/ipython-7.24.0.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}