gentoo resync : 25.09.2021

2 files changed, 155 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index ba4da05b549b..96d8a2e126e0 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,4 +1,6 @@
 AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc6a0b6bbdb524dfc66e0f4a7c69b0eeb2d35efb9d1845d567a11d1afa7881068b4757e42b9baf24dc01ba3026608a38 SHA512 fc4c9e12267ac5f04a2e16ad27334a093638538b8149ff380099fcbeb674a276ab9eb624a508010e37f82c05d5f7ab527a80e386b3e7b61c123ecb8effd9d542
 DIST ipython-7.26.0.tar.gz 5147847 BLAKE2B c0cb45550387e47bba6ea67656bbb4561a2250bf9c39b4560b26a8a9e380061f79c5fa663f90df166af1fa49811cb59953fb367b2fea5f07d44ba3f9dae3de44 SHA512 142ff8ebddd61640e6ebff01d16b1310b6370643aa8cf4c7fd076872ad342949a1778c5ad74eccbafdc6b4d31a1849e096d75a28eafc555d629948db523b4776
+DIST ipython-7.28.0.tar.gz 5150515 BLAKE2B e69b2ca9b788d8bcc12fb1b82c2e3f198ba4cf1918c8d8d30aea9a1ee3c7cea99ba3ade8ac7171466f1ffc8771dafcf5980766ecca7b985e07890e229cd1575d SHA512 227645ab2cc698f6f7141bb3712b254d75beaf3f227065530f25f988ac76b5a741752ddfa6bb2816b625eaa4972d434f9e73dbe465654e4efc5420b5d80650cb
 EBUILD ipython-7.26.0.ebuild 4215 BLAKE2B ebb124ad9c69acc70e1359d435b867dfce9987833a97e34026c449ac2d384e425ace3e326e2caa9cac66044cb0a3d6346feb8a07a4ec190315754aec493a3c93 SHA512 59abde0994606ed611145d415b4f3474f571f47bc969d35eec3d88c6e27efe4df1babfccbf1ea3f7a7f95facf6e5de0876a6198972a37032180ef43c84a2f06f
+EBUILD ipython-7.28.0.ebuild 4465 BLAKE2B 7d3389f0febcdc41f95b299ee8f8879a60a5388bbbaa4616d6e5a562cff671e3118220f46508e9872e005b7f465fbdd7ae82c468008db9ccc4cd093bc3ddc2d7 SHA512 58a51548a7d45ceca17581bbde4586af37c3f851ccaafe2ea90b862ee225cfffadb9714b34f35a88447614528e11f26c1c4e86599aeb03be49aa2ee225673599
 MISC metadata.xml 2883 BLAKE2B f61d1c66cdc9a956f3fdc9fcbc93fbc2051e9d0872beb9229e87a8fdabbce656efee9702e66bf30bec68009702f42e4036202e02208a428a8ed87b448f625536 SHA512 617f19e859544079d2680e9796e3ff0b7af41577776847d4c4dccfffc460dfc887631169289e5271120f375bea7c7836395abb9bf8a7628b3b55a7c1beefda9b
diff --git a/dev-python/ipython/ipython-7.28.0.ebuild b/dev-python/ipython/ipython-7.28.0.ebuild
new file mode 100644
index 000000000000..c9a468dda532
--- /dev/null
+++ b/dev-python/ipython/ipython-7.28.0.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=()
+	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
+		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
+		IPython/core/tests/test_oinspect.py::test_pinfo_docstring_if_detail_and_no_source
+		# fails due to changed argparse output
+		IPython/core/tests/test_magic_arguments.py::test_magic_arguments
+		# py3.10 API incompat, doesn't look important
+		IPython/lib/tests/test_pretty.py::test_pprint_heap_allocated_type
+	)
+	virtx epytest
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}