gentoo auto-resync : 31:10:2023 - 21:49:19

2 files changed, 160 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 128db4904629..afdfb3bdf676 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -3,6 +3,7 @@ DIST ipython-8.14.0.tar.gz 5470735 BLAKE2B 9789b49b771e69439f957ff85d81f40e6511f
 DIST ipython-8.15.0.tar.gz 5482758 BLAKE2B 596e87a1952995c1581e377f8306c02d1a37f29e04e7baa040a2ed78da1deea7f4de45b7af84919c47005c70f3e5fe2155a891cb3b5923e0ee76d2ff027036a5 SHA512 881b8d2caf051ee6a44af3c73f342e55eaf588ad096d0d2da08a10ee4699cb31b3550825091833848df9ed75657c9a2a1daf0b9b65ac7a3927c04a8d6e7cb1a9
 DIST ipython-8.16.1.tar.gz 5485037 BLAKE2B c5429b1df9906681f9792d7bc3005a3a41f7d89f7d6c104f9826902134179f7149de0747a50f31c53d277a135d0fedd0952aa23fce3650f026ac3c1733287ecb SHA512 0feb4c14e8e7f34829cd8b6c43c91c9bb5b6c85ae60173951db4354296474945268fb8d3caedcfae8457783e6d27a6dc33b6291bf2d9a691526fc44199724887
 DIST ipython-8.17.1.tar.gz 5486234 BLAKE2B 33d817713ca635f0c06a6e97f37d33ca9f139cede35bb67bb79491703ab0e71000aa5205d98898ad7e570763cbba84a1b8562bb35d2612f205bc8ed240a4f6a5 SHA512 c5fc3c23d616396861a0f1a7f96fc974d98e33f3dc166e1f714b088c1b617e984e53d654bcb5efb7762d8a2628c0f808a5c0129800e0b441283e8f783943bc69
+DIST ipython-8.17.2.tar.gz 5486488 BLAKE2B 7af4b4964527de8e74247ce05e9b1c8ab9a16e8784e0e07129859d01ffef0a976c8de7661821b131c125a8d1c2ac29d09d8e81a741f7180219a0c429530391cd SHA512 87039da43cb942c78238c4c69a2e2e7d6d1757a9ce8aac5f1bcd30a112a38f1b4f51672749ed469945844070eec661c6bb2f137405336f71d6adc1f5d26a11e2
 EBUILD ipython-8.14.0-r1.ebuild 4456 BLAKE2B df3bfdf147a315bc6e818300d3a8690f3689c01bfa45378f420610ab472499478b24f44c48462ccf21064dae65d98e8b6862b05ee8f52e2140f275ce0af92e5c SHA512 3475ded842fe047422236f778ae4a85a29a1bbe3ce47a789fc19e12c6c4680bac3da88a1c792c51fb3313602e8d3aab4859b2bc7249a9f6ff81ac37f37394d1b
 EBUILD ipython-8.14.0.ebuild 4346 BLAKE2B d7b58575f13354a2c19e2a70a225c6291f395fa6f96da6ab4b0f5f186234b2168700793f874e41b1eb7ccca3b227a7ee7119ad2ee4ae68af96d45218cecd0ddf SHA512 f52226b32eab2d7e43396187007873151b0bc9dd9884717d49ac0254954a8149a8dae616d333613dcd7281590ca73d08cf8bdfd379980c0db87a5ed5ab5473f5
 EBUILD ipython-8.15.0-r1.ebuild 4456 BLAKE2B df3bfdf147a315bc6e818300d3a8690f3689c01bfa45378f420610ab472499478b24f44c48462ccf21064dae65d98e8b6862b05ee8f52e2140f275ce0af92e5c SHA512 3475ded842fe047422236f778ae4a85a29a1bbe3ce47a789fc19e12c6c4680bac3da88a1c792c51fb3313602e8d3aab4859b2bc7249a9f6ff81ac37f37394d1b
@@ -11,4 +12,5 @@ EBUILD ipython-8.16.1-r1.ebuild 4456 BLAKE2B df3bfdf147a315bc6e818300d3a8690f368
 EBUILD ipython-8.16.1.ebuild 4434 BLAKE2B e048668572fa2719c9b2fc45c75967e58afee182d68cd2dd9557df0e52fb10bda387228476d6500e071a1af7d690a7f9aab46b5703bf400d366010e870c058c7 SHA512 231184fc5979ccbcecc1878ad2c2e4bed577195d4e110fde3bbc45877c62f6dc3487a02d7227449774ccbf167285d01d4b3c5236e6a212dee97f8395e01a5e87
 EBUILD ipython-8.17.1-r1.ebuild 4425 BLAKE2B 3d67300aee2a1c02293214d0b376dcade128cfb5adfe0188adc520034fc7fb008f2dca12ff4e62ab6f7f5053f4eba9215214ebe7e3b31c0062a72d70f5ce1c83 SHA512 e6e6dc340fb1f81313aec9ce16672b23f36552206b1241d19bff2d7ab2bb827e019b204ab652c06bda5258f50dd9a21ab4cb0053b35cbcd203c42cad8f9b53ab
 EBUILD ipython-8.17.1.ebuild 4396 BLAKE2B f8954cfb6b3ef3a55227d011fd9c87926f7c759fcdf9aa2b96c7d429ad0196c081e40ac5f21879460cd145018bbc625ed50d618ed4ea4a85294eaa697a03938d SHA512 f63aa1f8b5f74553dc33506744518cbddb4aa2adb223f3c4042d425137cd114baa03b5263e080cdf5d902fa6da39d68a2adcd92936752080c6c5406b2a648825
+EBUILD ipython-8.17.2.ebuild 4425 BLAKE2B 3d67300aee2a1c02293214d0b376dcade128cfb5adfe0188adc520034fc7fb008f2dca12ff4e62ab6f7f5053f4eba9215214ebe7e3b31c0062a72d70f5ce1c83 SHA512 e6e6dc340fb1f81313aec9ce16672b23f36552206b1241d19bff2d7ab2bb827e019b204ab652c06bda5258f50dd9a21ab4cb0053b35cbcd203c42cad8f9b53ab
 MISC metadata.xml 2802 BLAKE2B 2fb6773ad4ef10d531f978e3ed40f6d99cf1586ec6d7cf2bf7e60fd5d640d082a0946651e0a066993320ffeaace3426066ca24c325926b62125ae91816707128 SHA512 965c3e36e05475d9454af8219b84e080d4c83d775f8a7e20a4951a82246d672c46fd3cb1fff5f8664d0ce8e8fcb846de6f15abc4575db3a6b7d87209194bcecc
diff --git a/dev-python/ipython/ipython-8.17.2.ebuild b/dev-python/ipython/ipython-8.17.2.ebuild
new file mode 100644
index 000000000000..29bca8f56469
--- /dev/null
+++ b/dev-python/ipython/ipython-8.17.2.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="doc examples notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.38[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/stack-data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.22[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+	)
+	# nonfatal implied by virtx
+	nonfatal epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+	optfeature "%mprun magic command" dev-python/memory-profiler
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}