gentoo auto-resync : 05:05:2023 - 11:30:40

2 files changed, 161 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index 5d8afbef12d0..b275be351c29 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,7 +2,9 @@ AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc
 DIST ipython-8.12.0.tar.gz 5465154 BLAKE2B 946d3e649dcf8eea3518ed68499cfcaa6caa7eac99aa21c05fcbb81338037151253ba84d8d942746600dad3883f6d0e8ba1e82e9932cdddc8e1e77a270573ebf SHA512 3e9a42a6fb34a46d32d1236eac99182a756db2ec7b57c77dbedff1e4b25bcf2ef37effe4e5575cda450a1cde77e3c0d24172dcf19d102110a1ac75b9cfe9272c
 DIST ipython-8.13.0.tar.gz 5467133 BLAKE2B 038b4af8c5f9b32c9a2a1152e9a48131ae46f2903435f50fe67aeabfed7d34daf3f3439af372e561812c88bd6b90d7c729d4d876fe8b6e093582004def5058b7 SHA512 df71a2d30c3e88be89126b7f7178b45377b32c54ed78af0f3dda2612ccdbf7a55f23ccfe8293e50b063f47ecdcab6ff4454855bdabd5c1a45c4e573fd7a7b6d4
 DIST ipython-8.13.1.tar.gz 5467211 BLAKE2B 6d09ba56acbb20b367a1e3be163a63343f56fad7d62c2ec76c9ae2012d5884f534ae9e9eaac501cbc94c3d4ffb6eb599eb568d5fa57ab3af56efeec8d094343b SHA512 370512abc8fbe2c512b33167b8feded2b1177d9c194e60c912ee20e6286f90b20abb3982945f691c19cf0391dd556396d3df8755d5cd72fbbb5babe5f034a3d5
+DIST ipython-8.13.2.tar.gz 5467542 BLAKE2B dd924954c93eadc844e75cbfe95627f84120a120a7f69a2bd767c8506fe95ddac912ec9e55cad9ed1149369aec699e0e159f02b7a69ea4ec041e4af6677355ee SHA512 43bbc1669dffad690ee34c0455ca8ea66d30d6249d5c743c7cc100c0a218408761bce9cb798333bf7e7b0c03507009bcb8e1550bcd5be71680f30f822f9376bd
 EBUILD ipython-8.12.0.ebuild 4415 BLAKE2B d9b57f42d1dbc5432677372f458f113417e6a172db18a1a84385a1c359eb8c68f8beeecd4ab8b2591d34e5b9d6dfc173a3c385f44f57d222e5edd21af894d881 SHA512 a6dc7b2f0615577027cf4def0ea1332a249894a572cc3b3d953b1201827f98c77d237fada122cb3eb42d96befca0615114a0789c70c4ec39539a43460f7fff75
 EBUILD ipython-8.13.0.ebuild 4423 BLAKE2B 82ea5dabe4579dec38cddc9e54e9ea3b403f60f5f803e2cb84c6ecd35775201a109f79481cf1863aef8bf49e3c93eb03481bacb3f15154c6d03e035467114bdf SHA512 31240e79ed752a85efec0341ebcb83f3eff0442a9b995592d6e5dd327c51861d24025bf5a990923e5f9edd2be64f8e38d3643b9dfaebf596e4bc60fc443b6da3
 EBUILD ipython-8.13.1.ebuild 4423 BLAKE2B 82ea5dabe4579dec38cddc9e54e9ea3b403f60f5f803e2cb84c6ecd35775201a109f79481cf1863aef8bf49e3c93eb03481bacb3f15154c6d03e035467114bdf SHA512 31240e79ed752a85efec0341ebcb83f3eff0442a9b995592d6e5dd327c51861d24025bf5a990923e5f9edd2be64f8e38d3643b9dfaebf596e4bc60fc443b6da3
+EBUILD ipython-8.13.2.ebuild 4423 BLAKE2B 82ea5dabe4579dec38cddc9e54e9ea3b403f60f5f803e2cb84c6ecd35775201a109f79481cf1863aef8bf49e3c93eb03481bacb3f15154c6d03e035467114bdf SHA512 31240e79ed752a85efec0341ebcb83f3eff0442a9b995592d6e5dd327c51861d24025bf5a990923e5f9edd2be64f8e38d3643b9dfaebf596e4bc60fc443b6da3
 MISC metadata.xml 2886 BLAKE2B 88c80f5eef5c89c8939e60c1944be4c63a5a318e55a3490b38bf864e7919debf8e3c3a32f1fa0a43766ceec6462fb20fd4d943194fe2c08208f0839783c20916 SHA512 f4ed7c1898930ade11983fb0666dc25dce7907f017145e1ad903651dcd95ead2734893d55b4548c4ae23425388485a86bffc9d885eae17d12ae1ac2c0058aac2
diff --git a/dev-python/ipython/ipython-8.13.2.ebuild b/dev-python/ipython/ipython-8.13.2.ebuild
new file mode 100644
index 000000000000..1a16373c26a0
--- /dev/null
+++ b/dev-python/ipython/ipython-8.13.2.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.38[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/stack_data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.9)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+	)
+	# nonfatal implied by virtx
+	nonfatal epytest || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}