gentoo resync : 16.01.2021

2 files changed, 156 insertions, 0 deletions

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index cbf33c79e74b..dc6d6ea3d274 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -2,7 +2,9 @@ AUX 2.1.0-substitute-files.patch 1017 BLAKE2B 70577eb950a18345804a2a4b750bd233dc
 DIST ipython-7.29.0.tar.gz 5151803 BLAKE2B 685bb7df39513fe262c07dbb10de4d795860bf2958c626d030bfa3e18052a98d7c9d5f0f96c0c9a5d4b9fdcfab09c492457d409f05ce522f607456ff3a4b35fd SHA512 b8e9cc07a0f77bbfaa88183546ed9d7e4a4c37e7c1704b1a3716d605a04339f986c7767f3c0920a94039eda99e75afb62a7bb43fa0cde6699a902f3b8f83a398
 DIST ipython-7.30.1.tar.gz 5154336 BLAKE2B 0753433eea2ee6a5a6451db6aa537c9c9469c749b970ecdd040123787064e7be78363060a785c7ea4175b8e0f4f2bfefa15485f6f5412ec34690fe505a1cfb97 SHA512 839f709e019dd5efe32730f2e4c457e6dae0db5490844805d30f12a1fd17bfb2f991f1374a84542b2392d3ce332096d3922471c6b14149331075be8719b14734
 DIST ipython-7.31.0.tar.gz 5154974 BLAKE2B 5debac9a1011cc6541a2ce97df5d8793465ce4c289d1293c33c29eacc23cbd2271f0a8d7362c3445a88d080edefd85046aebc8782cd930c3dd8b6837ec682bf6 SHA512 705122ca63df17812ab360da06d58431b51d3a1f3bba47df7131e882de64de54c6986e7ba3d55f4b77c4b1049981b0100ba64825e952b25712c843ef7e975e2f
+DIST ipython-8.0.0.tar.gz 5395839 BLAKE2B 8844372c423c4b33a2a77b376c033aa00a4d44d1735cad42c4c85b05950370fcafea109025f4f02d124643656673ebf45ef27f78a93d31083b94e13d9364b32c SHA512 cb372080fac212f0d3872747820d06829f6b008ba142650c1af6fbc2ff287a0a82e9ec27777fe1c94f86d7dd9b57a9ebab467eeabd100344d053becd8ec1f70b
 EBUILD ipython-7.29.0.ebuild 4469 BLAKE2B 953d54ebb8837bdc34c55a1cf15e0f7bca2b367608e6082523e7a7dafa9df86025ccf127de6b9dcdad767108f992f14cdc662416ad8d5beddfb1ec9216a24921 SHA512 952c6093b489d5b7e95f842630fe4dbbf05ecc5acc2750953a9cddd9184032468f72b6c44f86621b13227b41896f021625f1bbe55cd608b03851458817ad9dd6
 EBUILD ipython-7.30.1.ebuild 4469 BLAKE2B a4fe701945791cc17bc043316eea80a3c350f56c8f621e1eda6d05182c6d1a656c2ac874826777690ede2f36483b98c3632c88c64501bc76fd0ecf63b109e9d7 SHA512 2b157b63f61fbaed1a2dd5dc6c76f3d27a8303a738cac99ed7b27b9829dfaf1929e7690b41e8b84c24cf0af268aebf80e45709f3a1f15d69ad82ac1999501fb9
 EBUILD ipython-7.31.0.ebuild 4477 BLAKE2B 6c74574a989cc388ca07628230ad56d8a75cf0cd304a1d11f9313df5b7316ee9a37a7c6050c696a6499a4484f80df14eabea78e241d989c604ba0bfb66021989 SHA512 145c220398ff972009aedb123db8d8c276d44adb4bf984cdb6183baafcb854b1cd68a39a0710775af62ca72238323c458a2c80e0ee67cfd9920122b6a95aa9ac
+EBUILD ipython-8.0.0-r1.ebuild 4352 BLAKE2B 6972f647ad4ee2a6fcee147d892fa0db63b3e35a447d994f0eca4c7b5acb7a028ad791d59914374c21b6bf03554fe32d9e7e6cf14a167f673b0edebb98888a8a SHA512 3d1194d7687dcca7925032ba4a1ed61acdbbdd94b885a92e2664c2e3da7050b675b68d20adb3fcd86fdeddd237f7fadb2a5624db62c4e3988b7363e5001256fd
 MISC metadata.xml 2883 BLAKE2B f61d1c66cdc9a956f3fdc9fcbc93fbc2051e9d0872beb9229e87a8fdabbce656efee9702e66bf30bec68009702f42e4036202e02208a428a8ed87b448f625536 SHA512 617f19e859544079d2680e9796e3ff0b7af41577776847d4c4dccfffc460dfc887631169289e5271120f375bea7c7836395abb9bf8a7628b3b55a7c1beefda9b
diff --git a/dev-python/ipython/ipython-8.0.0-r1.ebuild b/dev-python/ipython/ipython-8.0.0-r1.ebuild
new file mode 100644
index 000000000000..28e1e1885dc1
--- /dev/null
+++ b/dev-python/ipython/ipython-8.0.0-r1.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ia64 ~riscv"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/black[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/stack_data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.0[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# Internet
+		IPython/core/display.py::IPython.core.display.Image.__init__
+		# TODO
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+	)
+	[[ ${EPYTHON} == python3.10 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		IPython/core/tests/test_completer.py::TestCompleter::test_all_completions_dups
+		IPython/core/tests/test_completer.py::TestCompleter::test_deduplicate_completions
+	)
+	virtx epytest
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}