gentoo auto-resync : 13:04:2023 - 11:43:14

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/html5-parser/html5-parser-0.4.11.ebuild b/dev-python/html5-parser/html5-parser-0.4.11.ebuild
new file mode 100644
index 000000000000..6f0b31d3ef50
--- /dev/null
+++ b/dev-python/html5-parser/html5-parser-0.4.11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Fast C based HTML 5 parsing for python"
+HOMEPAGE="
+	https://github.com/kovidgoyal/html5-parser/
+	https://pypi.org/project/html5-parser/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/libxml2:=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.8.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+	)
+"
+
+src_prepare() {
+	# Soup is not used when lxml is available.
+	rm test/soup.py || die
+	sed -i -e 's:-O3::' setup.py unix_build.py || die
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	export PKGCONFIG_EXE=$(tc-getPKG_CONFIG)
+}
+
+python_test() {
+	"${EPYTHON}" run_tests.py || die
+}