gentoo auto-resync : 12:01:2025 - 06:41:42

3 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/hatch/Manifest b/dev-python/hatch/Manifest
new file mode 100644
index 000000000000..9f077dbb309a
--- /dev/null
+++ b/dev-python/hatch/Manifest
@@ -0,0 +1,3 @@
+DIST hatch-1.14.0.tar.gz 5188143 BLAKE2B e018bb96f08f8ba390b4681f376d69c8f50d16254dcababf5ca308f46aa3b2f654a0af88b883130d2f4255c440c9a3038e2640a6ffdb6e3449ca73b898eef032 SHA512 bb0b6e03cb2174f9c761b4b322c8da00949e0afab779d8506ebc24773f809e04f2c7ec7b54b450de860fdc8ebe5063011d2d085ea133f3c7ad3c40bcfe28f335
+EBUILD hatch-1.14.0-r1.ebuild 2077 BLAKE2B a9707e918753ee34ed094bdf8066b121be8863d9db01046f1093a5cb75fb95aeaccaa0457a898a4b35cb13052e9e32713293a90b626ebe49946efa9aa8118981 SHA512 bd65bc29355d41c56aba48c9748856c5823ca43e9a462b251554a4f5851e4963235241b705039363710b58bb9ca4a0e03076d1aa47084b6e8abe55f714a0755c
+MISC metadata.xml 361 BLAKE2B 4071b10f507cfd5cd3b24e30540e6a69212a82b1ffe0bf77087dc1a879720e8403329d75a6d09549cb024c4e2847998b7fa3c89146f1fde99ee557d242568881 SHA512 98ff9cd4cc4e37407755f12606b13eb4b22995e920f646934d74096722ec439693c546d65d9e7a72d0777e3141abf9434fbc3a00ee9f4dce6acce8418b7c7a28
diff --git a/dev-python/hatch/hatch-1.14.0-r1.ebuild b/dev-python/hatch/hatch-1.14.0-r1.ebuild
new file mode 100644
index 000000000000..67af1d9235a0
--- /dev/null
+++ b/dev-python/hatch/hatch-1.14.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Modern, extensible Python project management"
+HOMEPAGE="
+	https://github.com/pypa/hatch/
+	https://pypi.org/project/hatch/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/click-8.0.6[${PYTHON_USEDEP}]
+	>=dev-python/hatchling-1.24.2[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-21.0.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-23.5.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+	<dev-python/pexpect-5[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.8[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.5.0[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	>=dev-python/rich-11.2.0[${PYTHON_USEDEP}]
+	>=dev-python/shellingham-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11.1[${PYTHON_USEDEP}]
+	<dev-python/userpath-2[${PYTHON_USEDEP}]
+	>=dev-python/userpath-1.7[${PYTHON_USEDEP}]
+	>=dev-python/uv-0.1.35
+	>=dev-python/virtualenv-20.26.6[${PYTHON_USEDEP}]
+	<dev-python/zstandard-1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/editables[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/flit-core[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# we don't install .dist-info for uv
+	sed -i -e '/uv/d' pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/cli/env/test_create.py::test_uv_env
+	)
+	local EPYTEST_IGNORE=(
+		# we're running these in dev-python/hatchling
+		tests/backend
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_fakefs -p pytest_mock \
+		-m "not requires_internet and not requires_docker"
+}
diff --git a/dev-python/hatch/metadata.xml b/dev-python/hatch/metadata.xml
new file mode 100644
index 000000000000..56782bba5b9e
--- /dev/null
+++ b/dev-python/hatch/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">pypa/hatch</remote-id>
+		<remote-id type="pypi">hatch</remote-id>
+	</upstream>
+</pkgmetadata>