gentoo auto-resync : 27:09:2022 - 21:10:48

1 files changed, 37 insertions, 0 deletions

diff --git a/dev-python/fitsio/fitsio-1.1.8.ebuild b/dev-python/fitsio/fitsio-1.1.8.ebuild
new file mode 100644
index 000000000000..b4730fcfeca7
--- /dev/null
+++ b/dev-python/fitsio/fitsio-1.1.8.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1
+
+DESCRIPTION="Python library to read from and write to FITS files"
+HOMEPAGE="https://github.com/esheldon/fitsio"
+SRC_URI="
+	https://github.com/esheldon/fitsio/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/numpy-1.11[${PYTHON_USEDEP}]
+	sci-libs/cfitsio:0=
+"
+BDEPEND="${RDEPEND}"
+
+src_configure() {
+	cat >> setup.cfg <<-EOF || die
+		[build_ext]
+		use_system_fitsio = True
+	EOF
+}
+
+python_test() {
+	cd "${T}" || die
+	"${EPYTHON}" -c "import fitsio; exit(fitsio.test.test())" ||
+		die "Tests failed with ${EPYTHON}"
+}