reinit the tree, so we can have metadata

4 files changed, 147 insertions, 0 deletions

diff --git a/dev-python/doit/Manifest b/dev-python/doit/Manifest
new file mode 100644
index 000000000000..7acc794ca15e
--- /dev/null
+++ b/dev-python/doit/Manifest
@@ -0,0 +1,7 @@
+DIST doit-0.23.0.tar.gz 316588 SHA256 5d0421be6e5528e3be11bd0ede5c232e0c91f2b98b55688d7db1ce0638e1efbb SHA512 f2298d76d9ce3e7ed5f356bfdeeef8d5d99ebae74571666a3d2b3843fc63f5a8f76cd6cdedcfe8fc81bc653ecf04951c11f50abd16e9aa8fc7539e3c224b0e4c WHIRLPOOL cfb09484e25cfbc9618ef5b4a750010d16281a13772a37a8da59f2f6e1ebed77bbc40c06f263062c0464e6689415aeac695c0ef9e5cfe561349efea61f8be8e3
+DIST doit-0.29.0.tar.gz 222341 SHA256 fcb479482644de3e83d6faed9b29373f1f38942b79b991a7432943a84416d5cd SHA512 a686457df31b414d0c3797789e0ae1ae5cdfa3674025236419cb59b254f342cd2db07911ef18b2cb576d8d817b44035b9372265b34b786b2779fb7074b394de1 WHIRLPOOL 64e5cedb8d3ce0b99287713c05041da477182d63f745c7abc10cb72fd3d856fee62514cfa97c4ae6a433e12dd43d70bf4dea751eff99b91430b538dbf0ab7012
+EBUILD doit-0.23.0-r1.ebuild 1943 SHA256 6828d90eb24fffaa547209d487b525f85f799e3fd6d74988b7fa228a57a7bd5d SHA512 458b643e432806e13a88e119c3a0621b7296ee3e1babca1031085f6a0d884c17fa3ccb0f3ab7bf912f7de2c649170389830f3b4332dc8b17b7b4906caf4dd538 WHIRLPOOL 6dd8f3dbb8e81df9d31570d946e4d500c07a0b829ef54c5a2b244f7aa8f4608f67b7417cd97cd702976386bc93f09222ce3b2555d2938ac5ae1055e059e36119
+EBUILD doit-0.29.0.ebuild 1969 SHA256 c34cc20f3292bafe5e5b5eef797c659e758e5bcddce4446cc42a52f4f194803c SHA512 eddc795927da520eb12fa5ad1a360951c281897d874a48ba54fb52f498216ef5f750eac5425b95cb70d9bfbe704f40681d735332ac5aa07742606a1e1fbc5c12 WHIRLPOOL 163ceac00bca1845c4df791eba613e416a23d49e6bbf8a8f18aa86c11a9506e79ea6545318380c69f0efb2214d2224cc02e29bab93586640401f8f9658104b8f
+MISC ChangeLog 3765 SHA256 867075f972cd8fb039e44af830faedef03d7628de9e70210932b4b96731308a9 SHA512 7665c5e4bafb3a3acb21754e907d556bfba77bec48371f37b939eb3cd9b30d77389b2226f1160e34f9e80c8581bfdb3896b3837804a9327498fdede03a1b9ec9 WHIRLPOOL 26dbafce650fa7af634541d8d8745aa6a3f94d7442ee191325e4cfb85f27e32e87cce5e2417df0101c03220a3132338f41b36f27106a80cd6e2cc70c18d0664d
+MISC ChangeLog-2015 2516 SHA256 7fa4f94214c75eb6bf0b487046ba8a3cfd1bcb7ee53441c4db75c1718ffffbb8 SHA512 fa230cd29866b2353ab9bdb0d19d5f3387e2fb07bfa9b061c94852e3fd9314d83c4ad2de9878a067b8a73e4653d6060713847177ad77a3f3e32d42866fdf700b WHIRLPOOL 1bf54dcf77eaa4a4f576be34f024445b37913dbdfa1f1fe8db93c4a9724745f52e78bd5026f5f89940c4ea2da01206a1944b3e9637c2e4c2b63b4afbe345e7e8
+MISC metadata.xml 268 SHA256 71383dc4357a8683e8d73cbf6d0e5cab662bba98b0d61d58c0a1854dca07730c SHA512 7318c022300ab1ccfddb09bbf4789f64185dba13c3e4befa77f0e7aaaea4fa650508f66cf39d00c760ceea31872022d40523af05ecaac1c6b59005bc23f5bc42 WHIRLPOOL ada7be43e06656ee767f07b5e0fe702c20efd0f4fc0680fab81fcc71d884459af1468baf4d376541fc9a15ad2238d9aa5ba5457d0672603df86ec74ad0dbc206
diff --git a/dev-python/doit/doit-0.23.0-r1.ebuild b/dev-python/doit/doit-0.23.0-r1.ebuild
new file mode 100644
index 000000000000..1987991014c9
--- /dev/null
+++ b/dev-python/doit/doit-0.23.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4} pypy )
+inherit eutils distutils-r1
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="http://python-doit.sourceforge.net/ https://pypi.python.org/pypi/doit"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="test"
+
+RDEPEND="dev-python/pyinotify[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="test? ( ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}] )"
+# Required for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+DOCS=( AUTHORS CHANGES README TODO.txt dev_requirements.txt )
+
+python_prepare_all() {
+	use test && DISTUTILS_IN_SOURCE_BUILD=1
+	# Tests of this file fail due to setting of a tmp dir which can be fixed.
+	# This known spurious cause does not warrant halting a testsuite
+	rm -f tests/test_cmd_strace.py || die
+
+	# These 2 tests succeed on running the suite a second time, so they are NOT broken
+	# A gentoo test phase is run only once, so these unbroken tests can be safely skipped.
+	sed -e s':testInit:_&:' -e s':testLoop:_&:' \
+		-i tests/test_filewatch.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Testsuite is designed to be run by py.test, called by runtests.py
+	# https://bitbucket.org/schettino72/doit/issue/78/tests-that-fail-under-pypy
+	if [[ "${EPYTHON}" == pypy-c2.0 ]]; then
+		sed -e 's:test_corrupted_file:_&:' \
+			-e 's:test_corrupted_file_unrecognized_excep_pdep:_&:' \
+			-i tests/test_dependency.py || die
+	elif [[ "${EPYTHON}" == python2.6 ]]; then
+		rm -f tests/test___main__.py || die
+		sed -e 's:test_invalid_param_stdout:_&:' \
+			-i tests/test_action.py || die
+		sed -e 's:test_run_wait:_&:' \
+			-i tests/test_cmd_auto.py || die
+	fi
+	"${PYTHON}" runtests.py
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	dodoc -r doc
+	docompress -x /usr/share/doc/${PF}/doc
+}
diff --git a/dev-python/doit/doit-0.29.0.ebuild b/dev-python/doit/doit-0.29.0.ebuild
new file mode 100644
index 000000000000..2bef51932ca1
--- /dev/null
+++ b/dev-python/doit/doit-0.29.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy )
+inherit eutils distutils-r1
+
+RESTRICT="test" # can't work as it imports nonexistant modules from coverage
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="http://python-doit.sourceforge.net/ https://pypi.python.org/pypi/doit"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/configparser[${PYTHON_USEDEP}]' python2_7 pypy)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+DEPEND="test? ( ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}] )
+"
+PDEPEND=">=dev-python/doit-py-0.3.0[${PYTHON_USEDEP}]"
+
+# Required for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Disable test failing due to impact on PATH run in a sandbox
+	sed -e s':test_target:_&:' -i tests/test_cmd_strace.py || die
+
+	# Test requires connection to an absent database
+	sed -e s':testIgnoreAll:_&:' -i tests/test_cmd_ignore.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	local -x TMPDIR="${T}"
+	# disable tests where pypy's treatment of some tests' use of a db is incompatible
+
+	if [[ "${EPYTHON}" == pypy ]]; then
+		sed -e 's:test_remove_all:_&:' -i tests/test_dependency.py || die
+		sed -e 's:testForgetAll:_&:' -i tests/test_cmd_forget.py || die
+		sed -e 's:test_not_picklable:_&:' \
+			-e 's:test_task_not_picklabe_multiprocess:_&:' \
+			-i tests/test_runner.py || die
+	fi
+
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_src_install
+}
diff --git a/dev-python/doit/metadata.xml b/dev-python/doit/metadata.xml
new file mode 100644
index 000000000000..aa35e52686ed
--- /dev/null
+++ b/dev-python/doit/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <upstream>
+    <remote-id type="pypi">doit</remote-id>
+    <remote-id type="sourceforge">python-doit</remote-id>
+  </upstream>
+</pkgmetadata>