gentoo resync : 04.08.2018

3 files changed, 152 insertions, 0 deletions

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
index 891831a9bc7c..85daf985dd43 100644
--- a/dev-python/dbus-python/Manifest
+++ b/dev-python/dbus-python/Manifest
@@ -1,7 +1,10 @@
 DIST dbus-python-1.2.0.tar.gz 602426 BLAKE2B 86f5ba9283256b83d268ff7c27368e587896d58f87b15aefe9d29a90530ced591a2c6814dd37b91274910ed131fe031846071311bc6cc07c11d1f9cdda9e4602 SHA512 013b23e08fa1ed43f53a756587fefbc9770f7c51e93510e555acbd77230b7200693419bba9a69680d790bbaf123f4a195afa38b3eee1143da950fee0b5130bce
 DIST dbus-python-1.2.4.tar.gz 612112 BLAKE2B cccd3e2f5d700c0d228e7d21fd85e2307357778371742a7fe26a0e419af41886efebb27a73f642d2ecd4603c79f4afe6e7002af95c831180e0e7844c079b2c8c SHA512 efdd9d96a8b56e813c93208d34777f1ca2db96c076d31f13afbcaec3c7770a16a623d5531fe23443130c555240949802503f171f2064d45eee97546d6251304b
 DIST dbus-python-1.2.6.tar.gz 778893 BLAKE2B 1587bc9b1795e5c416397468b2061c869d923aea0983e604862342b27d37b946b1fcdd3bf07a612dba30087bdc6a5fa734906188c55756edf38d50eb67b7eef6 SHA512 6f2aec81defd2528d9876ec9a83843f8767275a5d6cf1b2b7b7a094f892f552f9a7b3d7b5006465254d410e503108e10138d7dd4cb3f1a4035d7f8d58c4d0684
+DIST dbus-python-1.2.8.tar.gz 787426 BLAKE2B 186cb8b1b25b2d2d12ab24ed304819ef18f953232d321bd425e7fda632c79a5a94f7b4118cc09f1bb13a0621980af67b4b55599fbbbcaf0e95f7912f4afd0a2e SHA512 6e486fd560944fc1461a27e6798e2c348c7fdf351602c082a0614c0a6822ff147875212bdcb1f818c0ab12470cffc613c0ffbd292cd9d445d3429bee65765905
 EBUILD dbus-python-1.2.0-r1.ebuild 2210 BLAKE2B 0f475f5ebe65b9880a5a9807f01914f3dc366597b21d528c1642d251400710a9dcd45f0bac1cd7e1faafa4506b358bc4d723d5c87d1db05dddec74eede59fa3a SHA512 a7bd731d00b142fdd0dcc90c8c2b3e87ad4766ca4725cf10d2418b13de82e87df1931cb76fa40e1808fe0a8d1be3012e855e126f0b398f5aaa308118a67a9c0a
 EBUILD dbus-python-1.2.4.ebuild 2228 BLAKE2B 16447af268331e0666b0cb10bf0f9137e466f5bcc53cdeebbcc5cf3ac2f7e80996f124ca724cc775482a98ade16e5b85177233402897cbb4f21116e31faeb702 SHA512 ff39e5618cc8a6704c7e393949370a6fef2d6aacc22172410db6976ab76071220a5b16ebeb901be66f604cdc0440bc9ea1982126ae66730853464b46d8bb1f85
 EBUILD dbus-python-1.2.6-r1.ebuild 2354 BLAKE2B a84ae880849eacd33ac774d3aa9f0b99a1a4a827304e806da5d0508f0850abf0eb79e61a8dff2d36a561a3bf09061d660d24ec45aa8e6a3196482a7019bcb765 SHA512 ca739a3a0a63ef25a260eb62adc4efec39181dadaac3a5feb1cb4887f3620ef45bc7175ac3677f3502e7b2ca695bcf2861694acba94784205e2521a751f6d477
+EBUILD dbus-python-1.2.6-r2.ebuild 1895 BLAKE2B b868d0892812a869f10461bc4317af6d32fe910b304b6cb04e1162f167570819224b6fe70de33b238f9c6780f0048016c06a16de8b27602078981f8bb545068c SHA512 fd4e509aeee20ad804bedc0db431acd8db7402ee57afe53d532a55362113258c57f000710478be9aa3205c30c7e53b6fd1596b7c9dffd092a90f3888b0988baa
+EBUILD dbus-python-1.2.8.ebuild 1638 BLAKE2B 39eda40eddf1f7100de143031d2f272db9375633657fcd89bd7de9997bad3329f8c838d0cb54cdbdf6663f086735ac591dbe1bedb5f3d9a95cc51329440881ef SHA512 5d3377cc756460686412bb40e54794f50b12042e3f51cc6c94795144873bdc1a81f8b00dca3cdd74568a72d6a3ef69aa7155346a7358151d8a101e9b3b1f4e8d
 MISC metadata.xml 337 BLAKE2B 96d3f5d7c37edb1a63791e013c39cf5b10c94d621ad851f9975d9d5e36519da135bf963f2a0e38c2c098fa48c2056bf210bdfcebc12bb10a88c9e9f85c55eb2a SHA512 633761250e946af99fcbcbf813b70fa0b1e03a0d89102faa3f324c418f0e749371aa931d253dc5a6f69369c25acc2d50a0f5e2155bd727766bc70f4bc3933d65
diff --git a/dev-python/dbus-python/dbus-python-1.2.6-r2.ebuild b/dev-python/dbus-python/dbus-python-1.2.6-r2.ebuild
new file mode 100644
index 000000000000..b2f40c7851c9
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.6-r2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+# API docs generated with epydoc, which is python2-only
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	doc? ( python_targets_python2_7 )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sys-apps/dbus-1.8:=
+	>=dev-libs/glib-2.40
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		dev-python/docutils[python_targets_python2_7?]
+		=dev-python/epydoc-3*[python_targets_python2_7?] )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/tappy[${PYTHON_USEDEP}] )"
+# TODO: Half the tests require tap.py from PyPI now, which we didn't have packaged; those tests just get skipped then though
+
+src_prepare() {
+	default
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	configuring() {
+		# epydoc is python2-only, bug #447642
+		local apidocs=--disable-api-docs
+		[[ ${EPYTHON/.*} = "python2" ]] && apidocs=$(use_enable doc api-docs)
+
+		econf \
+			--disable-html-docs \
+			${apidocs}
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installing() {
+		default
+		[[ ${EPYTHON/.*} = "python2" ]] && use doc && dodoc -r api
+	}
+	python_foreach_impl run_in_build_dir installing
+	find "${D}" -name "*.la" -delete || die
+
+	use examples && dodoc -r examples
+}
diff --git a/dev-python/dbus-python/dbus-python-1.2.8.ebuild b/dev-python/dbus-python/dbus-python-1.2.8.ebuild
new file mode 100644
index 000000000000..f976f4eb972b
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.8.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sys-apps/dbus-1.8:=
+	>=dev-libs/glib-2.40
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/tappy[${PYTHON_USEDEP}] )"
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	use doc && python_setup
+	local SPHINX_IMPL=${EPYTHON}
+
+	configuring() {
+		local myconf=(
+			--disable-documentation
+		)
+		[[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+			myconf+=( --enable-documentation )
+
+		econf "${myconf[@]}"
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name "*.la" -delete || die
+
+	use examples && dodoc -r examples
+}