gentoo auto-resync : 05:05:2023 - 17:31:39

3 files changed, 105 insertions, 0 deletions

diff --git a/dev-python/aws-xray-sdk/Manifest b/dev-python/aws-xray-sdk/Manifest
new file mode 100644
index 000000000000..898ae4334477
--- /dev/null
+++ b/dev-python/aws-xray-sdk/Manifest
@@ -0,0 +1,3 @@
+DIST aws-xray-sdk-python-2.12.0.gh.tar.gz 275773 BLAKE2B a78ac201524e70a342100c2e76e93bb02ed76e183dfca2e8737230061182d94c9a7f4eba183bc731d2ed79a8e4dda486ea09cb304f4cd58da56d712b8e6c5749 SHA512 0616369f95bf0de710ab5fb868d1a84280bcc1180cc205e6a6e0c405eae131fb861de75fea00c9c1be4e163b9d292cc27e08f624c7b6981ba4a3b8d99dbbb63c
+EBUILD aws-xray-sdk-2.12.0.ebuild 2249 BLAKE2B a8ee2a7d72c2b82a08c6190c72e15c2d1391862b9d15f9863e4909bb2cbb59e7f051f0cecefdc4c7694495af9771d4908d319755e958ae99f607c5f7ab063429 SHA512 a779a22c47503b69e0335d3318176309eaa0679d5377b738f9f896b1f32c1488375e04ef05f7f9ec5218e98d94063f6ffb63da7f583772d41538858a6fa49c98
+MISC metadata.xml 579 BLAKE2B 3f7aaed38bcceb97fb3597954ca9075ddf7a5718bcac69327be2b99d241c6d8cb0eefd369ca892c8d751703de9067c7eadf19f8c4445334ee8e4952b99fef69e SHA512 f3033cf16f60cae6727f80bd53944972f851579ffef8101cf6fda45e2575696183ec92ea8c994a77bbf3ffc8219be2ae2fae456faabe73a9896bcefddf3b5db5
diff --git a/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.0.ebuild b/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.0.ebuild
new file mode 100644
index 000000000000..5d91406d67f1
--- /dev/null
+++ b/dev-python/aws-xray-sdk/aws-xray-sdk-2.12.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_P=aws-xray-sdk-python-${PV}
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="
+	https://github.com/aws/aws-xray-sdk-python/
+	https://pypi.org/project/aws-xray-sdk/
+"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		<dev-python/flask-sqlalchemy-3[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-2[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local EPYTEST_DESELECT=(
+		# Internet access
+		tests/test_patcher.py::test_external_file
+		tests/test_patcher.py::test_external_module
+		tests/test_patcher.py::test_external_submodules_full
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		# benchmark
+		tests/test_local_sampling_benchmark.py
+		# Fails, probably because above is ignored
+		tests/test_async_local_storage.py::test_localstorage_isolation
+		tests/test_async_recorder.py::test_capture
+		tests/test_async_recorder.py::test_concurrent_calls
+		tests/test_async_recorder.py::test_async_context_managers
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged deps
+		tests/ext/aiobotocore
+		tests/ext/pg8000
+		tests/ext/psycopg2
+		tests/ext/pymysql
+		tests/ext/pynamodb
+		tests/ext/sqlalchemy_core/test_postgres.py
+		tests/ext/django/test_db.py
+		# Internet access
+		tests/ext/httplib
+		tests/ext/httpx
+		tests/ext/requests
+		# requires old package vesions
+		tests/ext/django
+		tests/ext/aiohttp
+	)
+
+	epytest -p no:django
+}
diff --git a/dev-python/aws-xray-sdk/metadata.xml b/dev-python/aws-xray-sdk/metadata.xml
new file mode 100644
index 000000000000..925c16c14d43
--- /dev/null
+++ b/dev-python/aws-xray-sdk/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>zmedico@gentoo.org</email>
+		<name>Zac Medico</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">aws/aws-xray-sdk-python</remote-id>
+		<remote-id type="pypi">aws-xray-sdk</remote-id>
+		<bugs-to>https://github.com/aws/aws-xray-sdk-python/issues</bugs-to>
+	</upstream>
+</pkgmetadata>