gentoo resync : 28.04.2021

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/argcomplete/argcomplete-1.12.3.ebuild b/dev-python/argcomplete/argcomplete-1.12.3.ebuild
new file mode 100644
index 000000000000..8e10b106c08c
--- /dev/null
+++ b/dev-python/argcomplete/argcomplete-1.12.3.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Bash tab completion for argparse"
+HOMEPAGE="https://pypi.org/project/argcomplete/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		<dev-python/importlib_metadata-5[${PYTHON_USEDEP}]
+	' python3_7 pypy3)"
+# pip is called as an external tool
+BDEPEND="
+	test? (
+		app-shells/fish
+		app-shells/tcsh
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pip-19
+	)"
+
+src_test() {
+	# workaround new readline defaults
+	echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+	local -x INPUTRC="${T}"/inputrc
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" test/test.py -v || die
+}