gentoo resync : 14.07.2018

4 files changed, 119 insertions, 0 deletions

diff --git a/dev-python/MechanicalSoup/Manifest b/dev-python/MechanicalSoup/Manifest
new file mode 100644
index 000000000000..a136712edc28
--- /dev/null
+++ b/dev-python/MechanicalSoup/Manifest
@@ -0,0 +1,5 @@
+DIST MechanicalSoup-0.10.0.tar.gz 40111 BLAKE2B cbb09253666850d3ce433f60ed6405585588e6dc7198c58de1cab8ecfad1e1c814433787aefe33dbb490edab5367ffca285d14cf8fbcb2c16e309b957a3a311b SHA512 5fa493abac39c5084dacb67b9dfaa2f8f5af773d3e3aaff48e6240596e863ada30a2fd1e345188c3249fd6e570977aa45b9fd553fe5a549f8430f170613bb866
+DIST MechanicalSoup-0.6.0.zip 5286 BLAKE2B 93a1d124cd45820e425fcb50b2aec04026f7a6f42c7c3f5c93103fbd216c98e36f366a1f7f343dd5561688ac4adb6feacab08ae444f91156348c07a80710a306 SHA512 cc413723514f3beee1267c57c16f6de2c19eb1f64535a60b546d289c7c18d8c4ba752ea61ab0b4a2aead2b56b12639cd226cb32662622515cb40262b7e619c24
+EBUILD MechanicalSoup-0.10.0.ebuild 1620 BLAKE2B 743cc14d3701f2b9527e11d6f96142db8942c03e9f39beeaa65b344d783cbb797eb2bacd8f03e331790b66c6a48e425d785ad3e0c9971ca6b2704a9b3638d7da SHA512 e11d40a10c3cacb940a4e710664e675b298382a4ecb1b1f774efcb38a51dc8bb42a2358138fce168f692012d84e6af15c4b8ef6a7b16b0bd966a7189f729fd43
+EBUILD MechanicalSoup-0.6.0.ebuild 750 BLAKE2B 7b299f207b52c84ad1476ca67bbbe9bacc68a9019870e3f34b1ec5a08e63a21ac73a74b5ad1c480a77c91933996bdb6aa7e7bbc8f978e12cef0d6f68b261ba38 SHA512 fc3ad2fb6a26118902bec92d90bc74827d05752f65414d485a9a8c5100151fe8e57d5d39872f1b940a65be187bf77cca8afbb6a0753ca31d2b9a029d312dc697
+MISC metadata.xml 550 BLAKE2B e580cc1c3eea5cd7a96ff564c5bb7606498911f997c326cd962ea54e7c73e6521b08d22a7de40f5a7784f3a6386aaaa6d8146ce64d8bcdc4d5f3f42a1855f821 SHA512 cf6d0689bb22256e261d2b964ec9ad05508467f68a115ded56b73fe27dad9f15f53a202f6c71e36b6219a5e79d99e01befa04bf239637f16ced3658d41d06314
diff --git a/dev-python/MechanicalSoup/MechanicalSoup-0.10.0.ebuild b/dev-python/MechanicalSoup/MechanicalSoup-0.10.0.ebuild
new file mode 100644
index 000000000000..808ae3326860
--- /dev/null
+++ b/dev-python/MechanicalSoup/MechanicalSoup-0.10.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="A python library for automating interaction with websites"
+HOMEPAGE="https://pypi.org/project/MechanicalSoup/"
+# https://github.com/MechanicalSoup/MechanicalSoup/pull/217
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+# https://github.com/MechanicalSoup/MechanicalSoup/issues/215
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/beautifulsoup-4.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		>=dev-python/requests-mock-1.3.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	sed -i "s/'pytest-runner'//" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip coverage and flake8
+	py.test --override-ini="addopts=" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/MechanicalSoup/MechanicalSoup-0.6.0.ebuild b/dev-python/MechanicalSoup/MechanicalSoup-0.6.0.ebuild
new file mode 100644
index 000000000000..97cbb3efb4cb
--- /dev/null
+++ b/dev-python/MechanicalSoup/MechanicalSoup-0.6.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+inherit distutils-r1
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/hickford/MechanicalSoup"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A python library for automating interaction with websites"
+HOMEPAGE="https://pypi.org/project/MechanicalSoup/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/beautifulsoup-4.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/MechanicalSoup/metadata.xml b/dev-python/MechanicalSoup/metadata.xml
new file mode 100644
index 000000000000..1565f268e779
--- /dev/null
+++ b/dev-python/MechanicalSoup/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>williamh@gentoo.org</email>
+		<name>William Hubbs</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">MechanicalSoup</remote-id>
+		<remote-id type="github">MechanicalSoup/MechanicalSoup</remote-id>
+		<bugs-to>https://github.com/MechanicalSoup/MechanicalSoup/issues</bugs-to>
+	</upstream>
+</pkgmetadata>