gentoo resync : 28.07.2021

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-ml/bos/bos-0.2.0.ebuild b/dev-ml/bos/bos-0.2.0.ebuild
new file mode 100644
index 000000000000..f1bcc15aeb1a
--- /dev/null
+++ b/dev-ml/bos/bos-0.2.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Basic OS interaction for OCaml"
+HOMEPAGE="https://erratique.ch/software/bos https://github.com/dbuenzli/bos"
+SRC_URI="https://erratique.ch/software/bos/releases/${P}.tbz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-lang/ocaml:=
+	dev-ml/rresult:=
+	dev-ml/astring:=
+	dev-ml/fpath:=
+	dev-ml/fmt:=
+	dev-ml/logs:="
+DEPEND="${RDEPEND}"
+BDEPEND="dev-ml/findlib
+	dev-ml/ocamlbuild
+	dev-ml/topkg
+	test? ( dev-ml/mtime )"
+
+src_compile() {
+	ocaml pkg/pkg.ml build --tests $(usex test true false) || die
+}
+
+src_test() {
+	ocaml pkg/pkg.ml test || die
+}
+
+src_install() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		${PN}.install || die
+}