gentoo auto-resync : 03:03:2024 - 17:42:46

3 files changed, 274 insertions, 0 deletions

diff --git a/dev-lisp/Manifest.gz b/dev-lisp/Manifest.gz
index 7f8bf8a977b0..eed1f6503bcb 100644
--- a/dev-lisp/Manifest.gz
+++ b/dev-lisp/Manifest.gz
diff --git a/dev-lisp/sbcl/Manifest b/dev-lisp/sbcl/Manifest
index 3f39b7257152..ebb40bc9abd9 100644
--- a/dev-lisp/sbcl/Manifest
+++ b/dev-lisp/sbcl/Manifest
@@ -21,7 +21,10 @@ DIST sbcl-2.4.0-source.tar.bz2 7695124 BLAKE2B 7f282282af0f2900cfc07795c659cc508
 DIST sbcl-2.4.0-x86-64-linux-binary.tar.bz2 12122206 BLAKE2B 8f0ba1bb4a3ba52f4b54cf16d347b7014d28bb635154f7f6811a30d08a19d4e1b9b448ed8fc5ae84d3aaa9edca89692cbcc5c9496e8f914cf3c9950890f164b4 SHA512 99b4760a5cc52c7807610aae7ae71810df013824a49fe956c4920d009648aa2a0c3a96c0745d00a7f09ba90b97e353999f19f98acd788b431defe6acd24edbc8
 DIST sbcl-2.4.1-source.tar.bz2 7800453 BLAKE2B 4ac07e5d3d18d9cfa5df266207d259f6b6b778b458e1e3be749ad7b145347e7aeada3623c1c423b20a15ba757dd2a2de4bd16163001aabc965ced8554f397825 SHA512 ae78f4d64063c05f82748239f661fb88792652496fced0a7bedcd00fda6b17cf9e01b866a5a11ca953746bc8b208116b73a93288ad08c9ffe578cc3266870780
 DIST sbcl-2.4.1-x86-64-linux-binary.tar.bz2 12113408 BLAKE2B 608f2455590d7118986015d48d02894b07350e418c3a893eb29bf423f6b78435ebde64e91cb9ca542cf2629ad9148f0c8576ddd3e7fb4569852ae6a374c2f38e SHA512 03fdefb9f51c8ebe32878328954d574dad31bce32e2b73c41c891188ce4f2d36039820639fea65b3280d257015cd5c7074989093ba71106e8f36d8e2df545db9
+DIST sbcl-2.4.2-source.tar.bz2 8148605 BLAKE2B be59c4332a25202dd5e2fabe78a51e039ae1efbdeb41ecec5392eb1e53a4e49c406a4d3dd5a3bd5e545702f924349a326f786e67db47b31bcf5ec9a9ec3766aa SHA512 9e4abb58b87e24937b883967e36da92ff3658e3eedbce245511f20f97455212436629f885815e91481d07b10e7af89b124c787e0dc7d4e5ce2790e9ea90fdbf3
+DIST sbcl-2.4.2-x86-64-linux-binary.tar.bz2 12072658 BLAKE2B b579b847d23f569b7cef01265781457ebfb07bac6604c18d1886c471e79af672cb2ec7c7b145b65b2d3ea7796bb288725bbb066c59e972ce56e153e76577cb65 SHA512 680908f21b8697c71f5a7ce5e68846fabcd4474fe4cd99f087576e0a9f336ba2f4cba83baf987af77869dab2d29974e46edbb52abe9b336be37dd9c8acecd81b
 EBUILD sbcl-2.3.5.ebuild 9048 BLAKE2B 5ed640bc380cab66baa817a4dbb9fd15a1d8bd4843b1e0459d636afe1d816ccddb01ca9a0297b1acafc1fe1ef8eb01e4646e8b9adca87ea36daac6cac7d31628 SHA512 1ad0c2443836a9b15c1f6a746833f91201adfa2182b6b82786c592f04c35abf10192e0a28b59228be81ad7d22859dc2096f277994004b05356615d4e4e6e7c49
 EBUILD sbcl-2.4.0.ebuild 9142 BLAKE2B 3f2b70c0324a1af7a5dfecb870d994cfba77cf0e98cfd752118b04406e5587c8b30a3de5f78962228dc5e71f80eeaa9174e9d1b4fbe7a6d9f093f3018fc47aa0 SHA512 191828f180d7e0eb0f80a56e302e3c9dfe5a25d3c7a6b9d0fff09e60373cda85ec8739d9f6691c0dd12f2a693d3eb5fbf30c026cb9c25be7b23feed26809bc28
 EBUILD sbcl-2.4.1.ebuild 9142 BLAKE2B 2d2fde85e0635d9bb89f771c2fa5a147b7b503efc8c44f652f383545ebc6c2c3b380137fa5066c1bd946b4f026dece5dd9e603e60912c22b25f946aad2bb0c5e SHA512 c378fb7f5562a6625013e1e34897c5218707aa5740ea05feb3eb6ac18f0eee7573a2d02158bf32589623d285946bb06cdb8bca24c09b2fee660876e758763125
+EBUILD sbcl-2.4.2.ebuild 9142 BLAKE2B 5c29f8d91504d76d9752362f2168af5a2c29b3c548209f2e624603106e3257e9055bd82e033df94cccd1610aa6f7957d9d742d73dbe7477486d21b0e7d18e2c4 SHA512 067adeb3ef5e70aecdec5cb53d600bf76fa67ca3abd4cf36ddc066095f72f1d52c5b7634b5d267d48583a8d4a1808b8c40b23bdee36eef0bd34c919ee3b98098
 MISC metadata.xml 1498 BLAKE2B 26fd9f6375ae06e3158d09608aeb5ea4a50e6ce7dd002c7c8f7827cf05798aebd7cba2b630238495ab0a27152ef6e485af2101446dd31e9592e9ffb14fb012b2 SHA512 c56fbecceb20c9550b4f5a07662276af099e7a600ad4f93139e25618aefd57bc45489fd85049da35b1f19937f2293640c1f953cb76780b849435b26f1f27285f
diff --git a/dev-lisp/sbcl/sbcl-2.4.2.ebuild b/dev-lisp/sbcl/sbcl-2.4.2.ebuild
new file mode 100644
index 000000000000..5f950057e5b8
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-2.4.2.ebuild
@@ -0,0 +1,271 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic pax-utils toolchain-funcs
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.4.3
+BV_AMD64=2.4.2
+BV_PPC=1.2.7
+BV_PPC64LE=1.5.8
+BV_SPARC=1.0.28
+BV_ALPHA=1.0.28
+BV_ARM=2.3.3
+BV_ARM64=1.4.2
+BV_X64_MACOS=1.2.11
+BV_PPC_MACOS=1.0.47
+BV_X86_SOLARIS=1.2.7
+BV_X64_SOLARIS=1.2.7
+BV_SPARC_SOLARIS=1.0.23
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp"
+HOMEPAGE="https://www.sbcl.org/ http://sbcl.sourceforge.net/"
+BSD_SOCKETS_TEST_PATCH=bsd-sockets-test-2.3.6.patch
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	https://dev.gentoo.org/~grozin/${BSD_SOCKETS_TEST_PATCH}.gz
+	!system-bootstrap? (
+		x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+		amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+		ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+		ppc64? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC64LE}-ppc64le-linux-binary.tar.bz2 )
+		sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+		alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+		arm? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM}-armhf-linux-binary.tar.bz2 )
+		arm64? ( mirror://sourceforge/sbcl/${PN}-${BV_ARM64}-arm64-linux-binary.tar.bz2 )
+		x64-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_MACOS}-x86-64-darwin-binary.tar.bz2 )
+		ppc-macos? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC_MACOS}-powerpc-darwin-binary.tar.bz2 )
+		x64-solaris? ( mirror://sourceforge/sbcl/${PN}-${BV_X64_SOLARIS}-x86-64-solaris-binary.tar.bz2 )
+	)"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="system-bootstrap debug doc source +threads +unicode +zstd"
+
+CDEPEND=">=dev-lisp/asdf-3.3:= \
+	prefix? ( dev-util/patchelf )"
+# bug #843851
+BDEPEND="${CDEPEND}
+		dev-debug/strace
+		doc? ( sys-apps/texinfo >=media-gfx/graphviz-2.26.0 )
+		system-bootstrap? ( || ( dev-lisp/clisp dev-lisp/sbcl ) )"
+RDEPEND="${CDEPEND}
+		zstd? ( app-arch/zstd )
+		!prefix? ( elibc_glibc? ( >=sys-libs/glibc-2.6 ) )"
+
+# Disable warnings about executable stacks, as this won't be fixed soon by upstream
+QA_EXECSTACK="usr/bin/sbcl"
+
+CONFIG="${S}/customize-target-features.lisp"
+ENVD="${T}/50sbcl"
+
+# Prevent ASDF from using the system libraries
+CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)"
+ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)"
+
+usep() {
+	use ${1} && echo "true" || echo "false"
+}
+
+sbcl_feature() {
+	echo "$( [[ ${1} == "true" ]] && echo "(enable ${2})" || echo "(disable ${2})")" >> "${CONFIG}"
+}
+
+sbcl_apply_features() {
+	sed 's/^X//' > "${CONFIG}" <<-'EOF'
+	(lambda (list)
+	X  (flet ((enable  (x) (pushnew x list))
+	X         (disable (x) (setf list (remove x list))))
+	EOF
+	if use x86 || use amd64; then
+		sbcl_feature "$(usep threads)" ":sb-thread"
+	fi
+	sbcl_feature "true" ":sb-ldb"
+	sbcl_feature "false" ":sb-test"
+	sbcl_feature "$(usep unicode)" ":sb-unicode"
+	sbcl_feature "$(usep zstd)" ":sb-core-compression"
+	sbcl_feature "$(usep debug)" ":sb-xref-for-internals"
+	sed 's/^X//' >> "${CONFIG}" <<-'EOF'
+	X    )
+	X  list)
+	EOF
+	cat "${CONFIG}"
+}
+
+src_unpack() {
+	unpack ${A}
+	if ! use system-bootstrap ; then
+		mv sbcl-*-* sbcl-binary || die
+	fi
+	cd "${S}"
+}
+
+src_prepare() {
+	# bug #468482
+	eapply "${FILESDIR}"/concurrency-test-2.0.1.patch
+	# bugs #486552, #527666, #517004
+	eapply "${WORKDIR}"/${BSD_SOCKETS_TEST_PATCH}
+	# bugs #560276, #561018
+	eapply "${FILESDIR}"/sb-posix-test-2.2.9.patch
+	# bug #767742
+	eapply "${FILESDIR}"/etags-2.1.0.patch
+	# Use ${PV} as build-id, bug #797574
+	eapply "${FILESDIR}"/build-id-2.3.6.patch
+
+	eapply "${FILESDIR}"/verbose-build-2.0.3.patch
+
+	eapply_user
+
+	# Make sure the *FLAGS variables are sane.
+	# sbcl needs symbols in resulting binaries, so building with the -s linker flag will fail.
+	strip-unsupported-flags
+	filter-flags -fomit-frame-pointer -Wl,-s
+	filter-ldflags -s
+
+	# original bugs #526194, #620532
+	# this broke no-pie default builds, c.f. bug #632670
+	# Pass CFLAGS down by appending our value, to let users override
+	# the default values.
+	# Keep passing LDFLAGS down via the LINKFLAGS variable.
+	sed -e "s@\(CFLAGS += -g .*\)\$@\1 ${CFLAGS}@" \
+		-e "s@LINKFLAGS += -g\$@LINKFLAGS += ${LDFLAGS}@" \
+		-i src/runtime/GNUmakefile || die
+
+	sed -e "s@SBCL_PREFIX=\"/usr/local\"@SBCL_PREFIX=\"${EPREFIX}/usr\"@" \
+		-i make-config.sh || die
+
+	# Use installed ASDF version
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+	# Avoid installation of ASDF info page. See bug #605752
+	sed '/INFOFILES/s/asdf.info//' -i doc/manual/Makefile || die
+
+	use source && sed 's%"$(BUILD_ROOT)%$(MODULE).lisp "$(BUILD_ROOT)%' -i contrib/vanilla-module.mk
+
+	# Some shells(such as dash) don't have "time" as builtin
+	# and we don't want to DEPEND on sys-process/time
+	sed "s,^time ,," -i make.sh || die
+	sed "s,/lib,/$(get_libdir),g" -i install.sh || die
+	# #define SBCL_HOME ...
+	sed "s,/usr/local/lib,${EPREFIX}/usr/$(get_libdir),g" -i src/runtime/runtime.c || die
+	# change location of /etc/sbclrc ...
+	sed  "s,/etc/sbclrc,${EPREFIX}/etc/sbclrc,g" -i src/code/toplevel.lisp || die
+
+	find . -type f -name .cvsignore -delete
+}
+
+src_configure() {
+	# customizing SBCL version as per
+	# http://sbcl.cvs.sourceforge.net/sbcl/sbcl/doc/PACKAGING-SBCL.txt?view=markup
+	echo -e ";;; Auto-generated by Gentoo\n\"gentoo-${PR}\"" > branch-version.lisp-expr
+
+	# set interpreter for Prefix
+	if use prefix ; then
+		patchelf --set-interpreter \
+			"${EPREFIX}/$(get_libdir)"/ld-linux-x86-64.so.2 \
+			"${WORKDIR}"/sbcl-binary/src/runtime/sbcl
+	fi
+
+	# applying customizations
+	sbcl_apply_features
+}
+
+src_compile() {
+	local bindir="${WORKDIR}"/sbcl-binary
+	local bootstrap_lisp="sh ${bindir}/run-sbcl.sh --no-sysinit --no-userinit --disable-debugger"
+
+	if use system-bootstrap ; then
+		if has_version "dev-lisp/sbcl" ; then
+			bootstrap_lisp="sbcl --no-sysinit --no-userinit --disable-debugger"
+		else
+			bootstrap_lisp="clisp"
+		fi
+	fi
+
+	# Bug #869434
+	append-cppflags -D_GNU_SOURCE
+
+	# clear the environment to get rid of non-ASCII strings, see bug #174702
+	# set HOME for paludis
+	env - HOME="${T}" PATH="${PATH}" \
+		CC="$(tc-getCC)" AS="$(tc-getAS)" LD="$(tc-getLD)" \
+		CPPFLAGS="${CPPFLAGS}" CFLAGS="${CFLAGS}" ASFLAGS="${ASFLAGS}" LDFLAGS="${LDFLAGS}" \
+		SBCL_HOME="/usr/$(get_libdir)/sbcl" SBCL_SOURCE_ROOT="/usr/$(get_libdir)/sbcl/src" \
+		GNUMAKE=make PV=${PV} ./make.sh \
+		"${bootstrap_lisp}" \
+		|| die "make failed"
+
+	# need to set HOME because libpango(used by graphviz) complains about it
+	if use doc; then
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/manual info html || die "Cannot build manual"
+		env - HOME="${T}" PATH="${PATH}" \
+			CL_SOURCE_REGISTRY="(:source-registry :ignore-inherited-configuration)" \
+			ASDF_OUTPUT_TRANSLATIONS="(:output-translations :ignore-inherited-configuration)" \
+			make -C doc/internals info html || die "Cannot build internal docs"
+	fi
+}
+
+src_test() {
+	ewarn "Unfortunately, it is known that some tests fail eg."
+	ewarn "run-program.impure.lisp. This is an issue of the upstream's"
+	ewarn "development and not of Gentoo's side. Please, before filing"
+	ewarn "any bug(s) search for older submissions. Thank you."
+	time ( cd tests && sh run-tests.sh )
+}
+
+src_install() {
+	# install system-wide initfile
+	dodir /etc/
+	sed 's/^X//' > "${ED}"/etc/sbclrc <<-EOF
+	;;; The following is required if you want source location functions to
+	;;; work in SLIME, for example.
+	X
+	(setf (logical-pathname-translations "SYS")
+	X      '(("SYS:SRC;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/src/**/*.*")
+	X        ("SYS:CONTRIB;**;*.*.*" #p"${EPREFIX}/usr/$(get_libdir)/sbcl/**/*.*")))
+	X
+	;;; Setup ASDF2
+	(load "${EPREFIX}/etc/common-lisp/gentoo-init.lisp")
+	EOF
+
+	# Install documentation
+	unset SBCL_HOME
+	INSTALL_ROOT="${ED}/usr" LIB_DIR="${EPREFIX}/usr/$(get_libdir)" DOC_DIR="${ED}/usr/share/doc/${PF}" \
+		sh install.sh || die "install.sh failed"
+
+	# bug #517008
+	pax-mark -mr "${D}"/usr/bin/sbcl
+
+	# rm empty directories lest paludis complain about this
+	find "${ED}" -empty -type d -exec rmdir -v {} +
+
+	if use doc; then
+		dodoc -r doc/internals/sbcl-internals
+
+		doinfo doc/manual/*.info*
+		doinfo doc/internals/sbcl-internals.info
+
+		docinto internals-notes
+		dodoc doc/internals-notes/*
+	else
+		rm -Rv "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	# install the SBCL source
+	if use source; then
+		./clean.sh
+		cp -av src "${ED}/usr/$(get_libdir)/sbcl/" || die
+		for d in contrib/*/; do
+			cp -av "$d" "${ED}/usr/$(get_libdir)/sbcl/" || die
+		done
+	fi
+
+	# necessary for running newly-saved images
+	echo "SBCL_HOME=${EPREFIX}/usr/$(get_libdir)/${PN}" > "${ENVD}"
+	echo "SBCL_SOURCE_ROOT=${EPREFIX}/usr/$(get_libdir)/${PN}/src" >> "${ENVD}"
+	doenvd "${ENVD}"
+}