gentoo auto-resync : 14:12:2022 - 03:28:57

11 files changed, 409 insertions, 140 deletions

diff --git a/dev-libs/Manifest.gz b/dev-libs/Manifest.gz
index 78fc262879a4..47fe0c702199 100644
--- a/dev-libs/Manifest.gz
+++ b/dev-libs/Manifest.gz
diff --git a/dev-libs/glib/Manifest b/dev-libs/glib/Manifest
index a20dab4db462..5c6132eb951d 100644
--- a/dev-libs/glib/Manifest
+++ b/dev-libs/glib/Manifest
@@ -1,7 +1,9 @@
 AUX glib-2.64.1-mark-gdbus-server-auth-test-flaky.patch 842 BLAKE2B 6b2eb57b8923c8bb54ead80d829aeb7a5c8a42c62e960e7305bc3fad69c67fd21e1c9f20b5c9002c0319cf3d77992b9cb71912c9b813b723e0a56aaea38330ad SHA512 ccd92d2f1fd495618ac788ffe6b69acec05a521a0ee8ff2bacb1dce6e283a04bbc2a10e61b37fc29f3893003fa154fa0d30bc37ed266b3f813200cd8ed17c116
 AUX glib-2.74.1-gnome-keyring-cpu.patch 3930 BLAKE2B 3da62efaa538e4685475b730626b9d76777874908340a55244e83cd70eaf6b731b5c363155b12db20c6fcf3a7692db047ca6cba65ac03f6c7f2b894af7da2ee8 SHA512 662d12afab80fb3d4af854d0ad1b477cfd27194ea86cbf5ad254a2997381d4eb327554a25d8a397b948c38011aa85d026d8ee477ce959553d292330fa01dd318
 DIST glib-2.74.1.tar.xz 5189452 BLAKE2B 58d977a5d2a100aa9125f2009ae66c6f27232dff70159433076552bdb64f9a6a93d7cb705feba890ee43d6f16d4766f6f1d5502c2e01eeb7e88d5ed0dd205d5c SHA512 21176cb95fcab49a781d02789bf21191a96a34a6391f066699b3c20b414b3169c958bd86623deb34ca55912083862885f7a7d12b67cc041467da2ba94d9e83c3
+DIST glib-2.74.3-patches.tar.xz 20644 BLAKE2B 1ffc465c4a3efd0ddd413bf40677bab903dad44580e66527c4ca115563228caf4450a94925522f12be69be88353e89b21d303d757903515fb1898a88768de18c SHA512 3eba57a4d0136bfbb7b6d7fb25957b63cc11d1e52bdcf8f5c6c346bca6db64f21237defaa320e528d00b979f73dc935ba882aa3629d14717fd109b7404766b36
 DIST glib-2.74.3.tar.xz 5181732 BLAKE2B 46c37be9519866af040b2aaf35129a9cfae6e2c74636c01755b901002fa77f4e2305025691d7a8279acfbae1298a4b5b1e095b333bed3b067e9820547b6eca97 SHA512 a9aa7e84187abb57aeeff9c7f4c4125be742a510ae5d39b6b62696ad1a715c36b353c6c14222caeb1e87bed930fb54184dba77118b991c42f1857a292c6aa77b
 EBUILD glib-2.74.1-r1.ebuild 10172 BLAKE2B 0920ab3c5ac1187ac6c31c6b9531fe7f5f0b4027a9f084f8620d4a0579b07baa10cf9f93fcc16bea2362bd7b43a25e67e77225702d1e2a35dc47b63e2bbe5b17 SHA512 1644fdff2f7031251b0f5b9e9d71f4ef522660fefcf9c963be73f911b9a283c7448657fc68f5dc679658861cb33c63ba5c0bd4785ecedee1429220e415e5fdb6
 EBUILD glib-2.74.3-r1.ebuild 10215 BLAKE2B b1ec264b5e77c633dc44348a27df0e5fcb6dc7d2fd01f2f37245f3033de46b176d7a1cc8992c17d39e91a497d7e3126d9e2231cfae1424544b64a2b26adde9fa SHA512 49b67bd553b6aecc82545a191add65276dff5aebf06915b5ad43baccd287d97ab3aa68f2cb280a0fc5f3079d70e9c2181d38ac725e4f1114c75f79048e07d637
+EBUILD glib-2.74.3-r2.ebuild 10425 BLAKE2B 153723dd40ec1c075a56e1b5441279038477809a22f3668881631af441fb7610539dd211da9aadc22f89d5a853b9bb20a25bc06a117d4f8ad119009fbb39da0c SHA512 b297c6579480340a4b86c290f95fb6309b50e9fe53d42d6840edc74fa083a84ec489d9926a13644d0777ec14e66904078b3d1c3379bd497d62b2fb80caa5aaf9
 MISC metadata.xml 1357 BLAKE2B c9236f5cdb72931175f757cd7b713d924655cbbdbba9a45479564a2fb8f73b490923d62b69e84568dcd8cd47df32f9fa1dd51481c332a85713c17ce6f6af5109 SHA512 6fc9c503e81c78e21904f74cedb9dbce10194b7acaecf3f17098749e33ca2513a96a53142bc8c1d9d196e48d62b8752956c30d4813ac34d0616cdf13de37b33b
diff --git a/dev-libs/glib/glib-2.74.3-r2.ebuild b/dev-libs/glib/glib-2.74.3-r2.ebuild
new file mode 100644
index 000000000000..5efc4fa82716
--- /dev/null
+++ b/dev-libs/glib/glib-2.74.3-r2.ebuild
@@ -0,0 +1,290 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_REQ_USE="xml(+)"
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit flag-o-matic gnome.org gnome2-utils linux-info meson-multilib multilib python-any-r1 toolchain-funcs xdg
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="https://www.gtk.org/"
+# https://discourse.gnome.org/t/multiple-fixes-for-gvariant-normalisation-issues-in-glib/12835
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-patches.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+IUSE="dbus debug +elf gtk-doc +mime selinux static-libs sysprof systemtap test utils xattr"
+RESTRICT="!test? ( test )"
+#REQUIRED_USE="gtk-doc? ( test )" # Bug #777636
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# * elfutils (via libelf) does not build on Windows. gresources are not embedded
+# within ELF binaries on that platform anyway and inspecting ELF binaries from
+# other platforms is not that useful so exclude the dependency in this case.
+# * Technically static-libs is needed on zlib, util-linux and perhaps more, but
+# these are used by GIO, which glib[static-libs] consumers don't really seem
+# to need at all, thus not imposing the deps for now and once some consumers
+# are actually found to static link libgio-2.0.a, we can revisit and either add
+# them or just put the (build) deps in that rare consumer instead of recursive
+# RDEPEND here (due to lack of recursive DEPEND).
+RDEPEND="
+	!<dev-util/gdbus-codegen-${PV}
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	>=dev-libs/libpcre2-10.32:0=[${MULTILIB_USEDEP},unicode(+),static-libs?]
+	>=dev-libs/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	>=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
+	kernel_linux? ( >=sys-apps/util-linux-2.23[${MULTILIB_USEDEP}] )
+	selinux? ( >=sys-libs/libselinux-2.2.2-r5[${MULTILIB_USEDEP}] )
+	xattr? ( !elibc_glibc? ( >=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}] ) )
+	elf? ( virtual/libelf:0= )
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+# libxml2 used for optional tests that get automatically skipped
+BDEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	gtk-doc? ( >=dev-util/gtk-doc-1.33
+		app-text/docbook-xml-dtd:4.2
+		app-text/docbook-xml-dtd:4.5 )
+	systemtap? ( >=dev-util/systemtap-1.3 )
+	${PYTHON_DEPS}
+	test? ( >=sys-apps/dbus-1.2.14 )
+	virtual/pkgconfig
+"
+# TODO: >=dev-util/gdbus-codegen-${PV} test dep once we modify gio/tests/meson.build to use external gdbus-codegen
+
+PDEPEND="
+	dbus? ( gnome-base/dconf )
+	mime? ( x11-misc/shared-mime-info )
+"
+# shared-mime-info needed for gio/xdgmime, bug #409481
+# dconf is needed to be able to save settings, bug #498436
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/gio-querymodules$(get_exeext)
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.64.1-mark-gdbus-server-auth-test-flaky.patch
+	"${WORKDIR}"/${P}-patches
+)
+
+pkg_setup() {
+	if use kernel_linux ; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		if use test ; then
+			CONFIG_CHECK="~IPV6"
+			WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
+		fi
+		linux-info_pkg_setup
+	fi
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	if use test; then
+		# TODO: Review the test exclusions, especially now with meson
+		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
+		if ! has_version dev-util/desktop-file-utils ; then
+			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
+			ewarn "think on installing it to get these tests run."
+			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
+			sed -i -e "/g_test_add_func/d" gio/tests/desktop-app-info.c || die
+		fi
+
+		# gdesktopappinfo requires existing terminal (gnome-terminal or any
+		# other), falling back to xterm if one doesn't exist
+		#if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
+		#	ewarn "Some tests will be skipped due to missing terminal program"
+		# These tests seem to sometimes fail even with a terminal; skip for now and reevulate with meson
+		# Also try https://gitlab.gnome.org/GNOME/glib/issues/1601 once ready for backport (or in a bump) and file new issue if still fails
+		sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
+		# desktop-app-info/launch* might fail similarly
+		sed -i -e "/desktop-app-info\/launch-as-manager/d" gio/tests/desktop-app-info.c || die
+		#fi
+
+		# https://bugzilla.gnome.org/show_bug.cgi?id=722604
+		sed -i -e "/timer\/stop/d" glib/tests/timer.c || die
+		sed -i -e "/timer\/basic/d" glib/tests/timer.c || die
+
+		ewarn "Tests for search-utils have been skipped"
+		sed -i -e "/search-utils/d" glib/tests/meson.build || die
+
+		# Play nice with network-sandbox, but this approach would defeat the purpose of the test
+		#sed -i -e "s/localhost/127.0.0.1/g" gio/tests/gsocketclient-slow.c || die
+	else
+		# Don't build tests, also prevents extra deps, bug #512022
+		sed -i -e '/subdir.*tests/d' {.,gio,glib}/meson.build || die
+	fi
+
+	# Don't build fuzzing binaries - not used
+	sed -i -e '/subdir.*fuzzing/d' meson.build || die
+
+	# gdbus-codegen is a separate package
+	sed -i -e '/install_dir/d' gio/gdbus-2.0/codegen/meson.build || die
+
+	# Same kind of meson-0.50 issue with some installed-tests files; will likely be fixed upstream soon
+	sed -i -e '/install_dir/d' gio/tests/meson.build || die
+
+	cat > "${T}/glib-test-ld-wrapper" <<-EOF
+		#!/usr/bin/env sh
+		exec \${LD:-ld} "\$@"
+	EOF
+	chmod a+x "${T}/glib-test-ld-wrapper" || die
+	sed -i -e "s|'ld'|'${T}/glib-test-ld-wrapper'|g" gio/tests/meson.build || die
+
+	default
+	gnome2_environment_reset
+	# TODO: python_name sedding for correct python shebang? Might be relevant mainly for glib-utils only
+}
+
+multilib_src_configure() {
+	if use debug; then
+		append-cflags -DG_ENABLE_DEBUG
+	else
+		append-cflags -DG_DISABLE_CAST_CHECKS # https://gitlab.gnome.org/GNOME/glib/issues/1833
+	fi
+
+	# TODO: figure a way to pass appropriate values for all cross properties that glib uses (search for get_cross_property)
+	#if tc-is-cross-compiler ; then
+		# https://bugzilla.gnome.org/show_bug.cgi?id=756473
+		# TODO-meson: This should be in meson cross file as 'growing_stack' property; and more, look at get_cross_property
+		#case ${CHOST} in
+		#hppa*|metag*) export glib_cv_stack_grows=yes ;;
+		#*)            export glib_cv_stack_grows=no ;;
+		#esac
+	#fi
+
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+		$(meson_feature selinux)
+		$(meson_use xattr)
+		-Dlibmount=enabled # only used if host_system == 'linux'
+		-Dman=true
+		$(meson_use systemtap dtrace)
+		$(meson_use systemtap)
+		$(meson_feature sysprof)
+		$(meson_native_use_bool gtk-doc gtk_doc)
+		$(meson_use test tests)
+		-Dinstalled_tests=false
+		-Dnls=enabled
+		-Doss_fuzz=disabled
+		$(meson_native_use_feature elf libelf)
+		-Dmultiarch=false
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	export XDG_CONFIG_DIRS=/etc/xdg
+	export XDG_DATA_DIRS=/usr/local/share:/usr/share
+	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
+	export LC_TIME=C # bug #411967
+	export TZ=UTC
+	unset GSETTINGS_BACKEND # bug #596380
+	python_setup
+
+	# https://bugs.gentoo.org/839807
+	local -x SANDBOX_PREDICT=${SANDBOX_PREDICT}
+	addpredict /usr/b
+
+	# Related test is a bit nitpicking
+	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+
+	meson_src_test --timeout-multiplier 2 --no-suite flaky
+}
+
+multilib_src_install() {
+	meson_src_install
+	keepdir /usr/$(get_libdir)/gio/modules
+}
+
+multilib_src_install_all() {
+	# These are installed by dev-util/glib-utils
+	# TODO: With patching we might be able to get rid of the python-any deps and removals, and test depend on glib-utils instead; revisit now with meson
+	rm "${ED}/usr/bin/glib-genmarshal" || die
+	rm "${ED}/usr/share/man/man1/glib-genmarshal.1" || die
+	rm "${ED}/usr/bin/glib-mkenums" || die
+	rm "${ED}/usr/share/man/man1/glib-mkenums.1" || die
+	rm "${ED}/usr/bin/gtester-report" || die
+	rm "${ED}/usr/share/man/man1/gtester-report.1" || die
+	# gdbus-codegen manpage installed by dev-util/gdbus-codegen
+	rm "${ED}/usr/share/man/man1/gdbus-codegen.1" || die
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+
+	# Make gschemas.compiled belong to glib alone
+	local cache="/usr/share/glib-2.0/schemas/gschemas.compiled"
+
+	if [[ -e ${EROOT}${cache} ]]; then
+		cp "${EROOT}"${cache} "${ED}"/${cache} || die
+	else
+		touch "${ED}"${cache} || die
+	fi
+
+	multilib_pkg_preinst() {
+		# Make giomodule.cache belong to glib alone
+		local cache="/usr/$(get_libdir)/gio/modules/giomodule.cache"
+
+		if [[ -e ${EROOT}${cache} ]]; then
+			cp "${EROOT}"${cache} "${ED}"${cache} || die
+		else
+			touch "${ED}"${cache} || die
+		fi
+	}
+
+	# Don't run the cache ownership when cross-compiling, as it would end up with an empty cache
+	# file due to inability to create it and GIO might not look at any of the modules there
+	if ! tc-is-cross-compiler ; then
+		multilib_foreach_abi multilib_pkg_preinst
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	# glib installs no schemas itself, but we force update for fresh install in case
+	# something has dropped in a schemas file without direct glib dep; and for upgrades
+	# in case the compiled schema format could have changed
+	gnome2_schemas_update
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	if ! tc-is-cross-compiler ; then
+		multilib_foreach_abi multilib_pkg_postinst
+	else
+		ewarn "Updating of GIO modules cache skipped due to cross-compilation."
+		ewarn "You might want to run gio-querymodules manually on the target for"
+		ewarn "your final image for performance reasons and re-run it when packages"
+		ewarn "installing GIO modules get upgraded or added to the image."
+	fi
+
+	for v in ${REPLACING_VERSIONS}; do
+		if ver_test "$v" "-lt" "2.63.6"; then
+			ewarn "glib no longer installs the gio-launch-desktop binary. You may need"
+			ewarn "to restart your session for \"Open With\" dialogs to work."
+		fi
+	done
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+
+	if [[ -z ${REPLACED_BY_VERSION} ]]; then
+		multilib_pkg_postrm() {
+			rm -f "${EROOT}"/usr/$(get_libdir)/gio/modules/giomodule.cache
+		}
+		multilib_foreach_abi multilib_pkg_postrm
+		rm -f "${EROOT}"/usr/share/glib-2.0/schemas/gschemas.compiled
+	fi
+}
diff --git a/dev-libs/level-zero/Manifest b/dev-libs/level-zero/Manifest
index fc9df75993eb..1d4b31b6cb85 100644
--- a/dev-libs/level-zero/Manifest
+++ b/dev-libs/level-zero/Manifest
@@ -1,3 +1,5 @@
+DIST level-zero-1.8.12.tar.gz 696435 BLAKE2B 31dfb05e947e05f7892c289071fc61f3f874009cf3b0c73c6e8c666a7ecbe1e71be6dab8bada9a56c9f993e0ba4c3bbecb975f9173e0c03672cdd31fb2a54450 SHA512 8e4025c15426e7593b45c65a09ad51282ba65156205eafbc10fa1e91aa351e2a3e2911e4b2f1bfc8fad78179f684469a3587ed164a3a702caad5aa4e5788284e
 DIST level-zero-1.8.8.tar.gz 695251 BLAKE2B cca0c35bcd9bd168187804eb3600d4ea17276be58a3a7db6da62908d9469e480dde966191e450fc80411f7caf60302bdb6c0cbaf741e7c7b59ad962a85d0d1c5 SHA512 b9b416beebbe96cd75d18d4cf888f539d908007629085f8692cd0898545e564b56671d060bc4961847df57a6c3b3beccbaa6f31539b6f4c201487961236ab83d
+EBUILD level-zero-1.8.12.ebuild 634 BLAKE2B ebb868ccae3ecc9d3782fff25bbd5bf23fe8c4f0fcf604ea721c7341111b1571ca76bb32e852ba0315854ca5ca22a9a51f95fcaac2b7a336af17feea922f3015 SHA512 0a4b7b3d5c0bef12696b6a7e08313f315835862602a4886448de7a86260d19ad12280aa7333e6e2336b1870bc2bd9398d97730f015f794abf3b94e1a3db74135
 EBUILD level-zero-1.8.8.ebuild 633 BLAKE2B feb675c296010387e70c7fb2195e467409f5fe09db1b8bcf9593b752bb6aeebae99fb9b43d94be72a6a8280eb1b950b1ee5a427660e34f6c17e5c0658e48ac5e SHA512 fd6ab8bb06ab59e7f72d3a35d39a1e9af3c509ae8a70a6852d4ce1aea758e77f79b99a5d2b331f74f92341df2b7cc19f65d3fdcc3dbc0bad1c3dfd5de9a5d86d
 MISC metadata.xml 586 BLAKE2B 44eca05640a9276ea9cbddccc0d199dc8c7297a3fbf5ad6b58693c406961efa2aabf99501faaace47ce6bb97736fe371533e89a5a700949b03db66359222b269 SHA512 da9b222b216ed217842f236eeb1991e31ec4f140d86c0a048e9e401a18018d90d6ad8d4f10edec8b71386687bc9481ebf9154a1190bf6969d4fab04bba20100e
diff --git a/dev-libs/level-zero/level-zero-1.8.12.ebuild b/dev-libs/level-zero/level-zero-1.8.12.ebuild
new file mode 100644
index 000000000000..fc6029d86bbc
--- /dev/null
+++ b/dev-libs/level-zero/level-zero-1.8.12.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="oneAPI Level Zero headers, loader and validation layer"
+HOMEPAGE="https://github.com/oneapi-src/level-zero"
+SRC_URI="https://github.com/oneapi-src/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# According to upstream, release tarballs should contain this file but at least
+	# some of them do not. Fortunately it is trivial to make one ourselves.
+	echo "$(ver_cut 3)" > "${S}"/VERSION_PATCH || die
+}
diff --git a/dev-libs/libpcre2/Manifest b/dev-libs/libpcre2/Manifest
index d56c1f0dde39..363f172d0013 100644
--- a/dev-libs/libpcre2/Manifest
+++ b/dev-libs/libpcre2/Manifest
@@ -3,12 +3,9 @@ AUX libpcre2-10.41-pcre2posix-header.patch 2719 BLAKE2B 38b47ebc780ba24ab8a5bbe8
 DIST libpcre2-10.36-patchset-01.tar.xz 1364 BLAKE2B bfef3c876a092e06972107b44794c23b758a030181f3040c8b722db166789eac794783169b468fc71334fd660bc2f1c31422a8cb8e5bdc18a69b72654b1b59b2 SHA512 04324d1efa6d155fa3ffbc328638e4674bea305fef7f57d4369ab4a6399a0f489b4c0ecfb49643feff310d91872e1673e965c48a5c60f1bf54a319f0d275c306
 DIST pcre2-10.40.tar.bz2 1765440 BLAKE2B 627a204585b92238eda81b4befc88757a81d75b0d9fa26ea6d51afcdd93f7e2d102a2245bf3c8e1f5f9ddf69a316c419c948b741a64442bb567480015543e49b SHA512 00e7b48a6554b9127cb6fe24c5cacf72783416a9754ec88f62f73c52f46ed72c86c1869e62c91a31b2ff2cbafbbedabca44b3f1eb7670bc92f49d8401c7374e8
 DIST pcre2-10.40.tar.bz2.sig 310 BLAKE2B 9609111a64b66893b12e36d1cbc77b64d6a0cc30b9288e52753785ddcab37cc3e169d0f117d94e4ad7d7ff897a6ba0a574c9a2e529c3c7e171f5a1bc6f64fe23 SHA512 faa4b47fdac1543cd323651f251b8abb94b31b5966b42d445b8cbb38c441df4742e3c3517c2bc6c0a4464e9fb5feab5d5beda1250a03d56bec2d8383be2f63ab
-DIST pcre2-10.41.tar.bz2 1799126 BLAKE2B 4335eae8e8a327c32092a1a9f8214fa86a2d016deb7450938c4ddc38214b72dfa8c6f9c85a03bb36b3686390d378d74fdd991563f92611c42a54915310604559 SHA512 328f331a56f152424f6021b37f8dcf660842c55d43ff39f1b49115f0d05ed651d0bbb66b43c0ed61d65022030615768b92ce5e6218a54e4e17152ec473cca68d
-DIST pcre2-10.41.tar.bz2.sig 310 BLAKE2B 4ee3f9327bf568e38d1c072a4be93cdab4209e7b0cc0d183b978553cd7413ba9f292318ddf815cf44bc24872f685ee4ff9bceddd7d0e915b7be67c43fd8bf8f7 SHA512 4127258f17011be7c82d9412728863a9121c5b780514ec836769ab64ccd4cd5349a84fc85b8fdc4abb2e6fe08f4610b2a3e926116e7f1451d90d9afaa888661c
 DIST pcre2-10.42.tar.bz2 1799866 BLAKE2B 40aa096745548c489a00ead87a191a4d24ecd924a5b8f00401c1273176de15ccb23510882467c8e2b5c1256b97db46fba5fcdfbd9f0d61d86a29d74bb4bca7a0 SHA512 72fbde87fecec3aa4b47225dd919ea1d55e97f2cbcf02aba26e5a0d3b1ffb58c25a80a9ef069eb99f9cf4e41ba9604ad06a7ec159870e1e875d86820e12256d3
 DIST pcre2-10.42.tar.bz2.sig 310 BLAKE2B 2125d7e23f7e75847573e3caeb8d55da5d8e0df3d166bf8b638b998aebacaefb4e88df7e813d6977af2dc7d82c93b7179ad0043c4f46fc4e06d99d214b0b7fcf SHA512 22ce3c7903835b1cf835ac6cfa725badecc982f1504382e62525c88307b2e3bd8951f2221fdd3d73920843e69f714b6df99fe741069e610f1f809087512a31f7
 EBUILD libpcre2-10.40-r1.ebuild 3011 BLAKE2B d2fe79c5ebc125e6bd08d3a24a9d27684de24323a303440bc5b545775f1504db02057ee735594564d66ad0218b37afd11420159752e7ecd83c90c39b8575fd5f SHA512 fafe9e377d2b4ccc6fc71f8b266b9a401a421ccd5bd37ad3a4134ce73e00f8fe62ac9d3e61a402acd4a42cde2f6560e69f1a5cf79c171d2311bf1a52d81c93b1
 EBUILD libpcre2-10.40.ebuild 2978 BLAKE2B 689d60aabd0b0278816571add95ddfe47b914d1bf7d55736ae8d0db8a46d7db788c3c61df5eae827f1eaec54389cb5d6dd0ff6e0bd2941f4a2405cb76b422cc4 SHA512 375fca4b0b11d8aba628e0ce86d87c3f7bb3b99faf63b63364eb9efc6a04910db2f11b216368456aaeb0143f0fbd64ea1e59f8061e12dfd53260172f9f6b169d
-EBUILD libpcre2-10.41-r1.ebuild 2563 BLAKE2B b1722855587ab47629c620afd00ebd6b694193326885f8c26000a563080976957bc4e4f201ac3cebb60025bf54333b52128afe4ab4fee4fe7d197c971d51d777 SHA512 5d150ef1a6d8b6ea74c936d89972456e191df80c5d6645548c2a11ff7ff64a0ec3a5e46ce73565249ffa611754bd64d77cd3f2287f8b5811474f59bd491a486e
 EBUILD libpcre2-10.42.ebuild 2519 BLAKE2B ac1d2b94be05e75900ada4cf0699bc337c088b0c957f73a3153d8981d07845d42c980dedd667b690ab98d8337c4d96d4242df113f2aab32040255cef59cf39ca SHA512 ba0a5b627e13952de6eb996e7b56057b48d89403c25488af841cf8aa61760ede3a3f91428fb72a2c6dde89cabfea8cc930564675121376f07c59d36edc6ae553
 MISC metadata.xml 1087 BLAKE2B 693e7f9a4d9cac7b2aa5f24804826f79135a0475770b8ef5058b09542c3b19d30ddef438029dc0358b997ebc032ab103432b1274723c81882f1b5359455c765a SHA512 74dcb822827b8cc3e86c525ab3e2ee302d39ee00d5b4515f9fd6f4a157ae1522a2edbd08b97c2950d9370878f41eb59e414a145d6beae430dab57ea10df68460
diff --git a/dev-libs/libpcre2/libpcre2-10.41-r1.ebuild b/dev-libs/libpcre2/libpcre2-10.41-r1.ebuild
deleted file mode 100644
index e4703e3a15ea..000000000000
--- a/dev-libs/libpcre2/libpcre2-10.41-r1.ebuild
+++ /dev/null
@@ -1,94 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/philiphazel.asc
-inherit libtool multilib-minimal usr-ldscript verify-sig
-
-MY_P="pcre2-${PV/_rc/-RC}"
-
-DESCRIPTION="Perl-compatible regular expression library"
-HOMEPAGE="https://www.pcre.org/"
-if [[ ${PV} != *_rc* ]] ; then
-	# Only the final releases are available here.
-	SRC_URI="https://github.com/PCRE2Project/pcre2/releases/download/${MY_P}/${MY_P}.tar.bz2
-		https://ftp.pcre.org/pub/pcre/${MY_P}.tar.bz2
-		verify-sig? ( https://github.com/PhilipHazel/pcre2/releases/download/${MY_P}/${MY_P}.tar.bz2.sig )"
-else
-	SRC_URI="https://ftp.pcre.org/pub/pcre/Testing/${MY_P}.tar.bz2"
-fi
-
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="BSD"
-SLOT="0/3" # libpcre2-posix.so version
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="bzip2 +jit libedit +pcre16 pcre32 +readline static-libs unicode zlib"
-REQUIRED_USE="?? ( libedit readline )"
-
-RDEPEND="
-	bzip2? ( app-arch/bzip2 )
-	libedit? ( dev-libs/libedit )
-	readline? ( sys-libs/readline:= )
-	zlib? ( sys-libs/zlib )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	verify-sig? ( sec-keys/openpgp-keys-philiphazel )
-"
-
-MULTILIB_CHOST_TOOLS=(
-	/usr/bin/pcre2-config
-)
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-10.10-000-Fix-multilib.patch
-	"${FILESDIR}"/${P}-pcre2posix-header.patch
-)
-
-src_prepare() {
-	default
-
-	elibtoolize
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		--enable-pcre2-8
-		--enable-shared
-		$(multilib_native_use_enable bzip2 pcre2grep-libbz2)
-		$(multilib_native_use_enable libedit pcre2test-libedit)
-		$(multilib_native_use_enable readline pcre2test-libreadline)
-		$(multilib_native_use_enable zlib pcre2grep-libz)
-		$(use_enable jit)
-		$(use_enable jit pcre2grep-jit)
-		$(use_enable pcre16 pcre2-16)
-		$(use_enable pcre32 pcre2-32)
-		$(use_enable static-libs static)
-		$(use_enable unicode)
-	)
-
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_compile() {
-	emake V=1 $(multilib_is_native_abi || echo "bin_PROGRAMS=")
-}
-
-multilib_src_test() {
-	emake check VERBOSE=yes
-}
-
-multilib_src_install() {
-	emake \
-		DESTDIR="${D}" \
-		$(multilib_is_native_abi || echo "bin_PROGRAMS= dist_html_DATA=") \
-		install
-	multilib_is_native_abi && gen_usr_ldscript -a pcre2-posix
-}
-
-multilib_src_install_all() {
-	find "${ED}" -type f -name "*.la" -delete || die
-}
diff --git a/dev-libs/mpc/Manifest b/dev-libs/mpc/Manifest
index 583551d645ae..84e78e8d0407 100644
--- a/dev-libs/mpc/Manifest
+++ b/dev-libs/mpc/Manifest
@@ -1,8 +1,6 @@
 AUX mpc-1.3.0-header.patch 1337 BLAKE2B 4a4f5b73bac8432f3f350961c6b1be53da097b45c82c8709cf4d13ba74bdac88468cc59208dc68bb0369d31434e691a546849caf7e30ed9eda92dda33a93bd2c SHA512 acefc37e97ae5bac38f71040d55a67ea352956efcd0b60ef2be1bb5e82cfecee0338b21ace185ef046280d3f1481a17ff22f665b4d7070725870036ed3773571
 DIST mpc-1.2.1.tar.gz 838731 BLAKE2B 9cd03c6a71839e4cdb3c1f18d718cc4d3097c3f8ec307a5c756bd5df27c68aa013755156b3b156efee1acabfee2269602c6a3a358092ef0d522271c9c56c133d SHA512 3279f813ab37f47fdcc800e4ac5f306417d07f539593ca715876e43e04896e1d5bceccfb288ef2908a3f24b760747d0dbd0392a24b9b341bc3e12082e5c836ee
-DIST mpc-1.3.0.tar.gz 773441 BLAKE2B b9e2f4cda2457b1e885e4099daaf55a4c226291ec60097e40835f6e311c297947fe5cfd6ce61f80eecfbc8d374923422c4050a10399b26b23c12ab0f3f53a0f5 SHA512 9c18b24f7542dc1dc5e10cf58fd242e73d79a9dc3619c3f08d52aed75ad0e7d9e2ba2c46857717c8b921b084af2efc8c0d2d7173081af764b81c24a8971ddd9a
 DIST mpc-1.3.1rc1.tar.gz 773589 BLAKE2B 27626bc2e1116e965ddaf38de45eea4d447e7f849d61180418d7685c192511c1502da0e69c612698ad404fee7c5a257024d5c35ebc00feb9f4264e8f9b164d76 SHA512 95964f8a4061d644343440c8fd8fc010b12bee226aab48063cc3d45a0d1e140d488dd10a1aeee5e0bb9fdea3bae935234a9b3b456a0d9a530339e83bc90d8945
 EBUILD mpc-1.2.1.ebuild 939 BLAKE2B 7af59b1cc4ede3496d708bf774dba385dd88ae88d1935f51b342f93f7cd02686687176f6a5723c73fbcbbc945b8ec07bf38b43ab94082c9fca41a62b01e9901c SHA512 59e817cb235cce2ada39eb88c9856e329325833e898ca6e5a779c7cebb4b1b9ba0d9ad374e39667b9056ee665768651c493db4c3c2e902ec176a59384828f211
-EBUILD mpc-1.3.0-r1.ebuild 1129 BLAKE2B 817e68734b909077924852d44632fa255e8d546ba1a1c95cf55da70b0dde0d6950d42aa87d55f3350fee42b4a53d8d7e149f05182b38e79e487e9946065ae758 SHA512 e527a06a709da2e1ca817b614646f7040e0a3684712bafec63ea45653dd5a4bc70830d5a4b21b323a604f04a6c978848505a46b3e5f94db18fe181153736d7c8
 EBUILD mpc-1.3.1_rc1.ebuild 1399 BLAKE2B b3e004490295db3ac776cf9f87d669736be417398be28bb6ae14815f46a08f743a03c8dfe6e81718de02e498ec01ce5c601b5a9f760bb6eec4625160f35fa47f SHA512 ea3a68f7bd70835f10084d55999a61e010a1fda2864e374baf3c436c8b7afe06ea6cd7d5181ca9aadc3124c650fa26c95b34ea0b5b583f3a6ce67ce76dd71dcb
 MISC metadata.xml 262 BLAKE2B fe330d67755784d14f5c5d664d7127d3cdb9edfab55b907ae3632f434d86323604f5095e1c1a9fbd169ae7a4cbb38f359e55f75047531786247c0674a4a53715 SHA512 3bcaca4e730edeed06fed73e79a5ce0a3358174672735ea4b27240c6c421ac9c33bc2b63a31e596fe1bbb6b1816c16cbc7ef4f258ca906ba04ea7db4aedc86b9
diff --git a/dev-libs/mpc/mpc-1.3.0-r1.ebuild b/dev-libs/mpc/mpc-1.3.0-r1.ebuild
deleted file mode 100644
index 58311b7a2ead..000000000000
--- a/dev-libs/mpc/mpc-1.3.0-r1.ebuild
+++ /dev/null
@@ -1,41 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit multilib-minimal
-
-DESCRIPTION="A library for multiprecision complex arithmetic with exact rounding"
-HOMEPAGE="https://www.multiprecision.org/mpc/ https://gitlab.inria.fr/mpc/mpc"
-
-if [[ ${PV} == *_rc* ]] ; then
-	SRC_URI="https://www.multiprecision.org/downloads/${P/_}.tar.gz"
-	S="${WORKDIR}"/${P/_}
-else
-	SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
-
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-fi
-
-LICENSE="LGPL-2.1"
-SLOT="0/3" # libmpc.so.3
-IUSE="static-libs"
-
-DEPEND="
-	>=dev-libs/gmp-5.0.0:=[${MULTILIB_USEDEP},static-libs?]
-	>=dev-libs/mpfr-4.1.0:=[${MULTILIB_USEDEP},static-libs?]
-"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-header.patch
-)
-
-multilib_src_configure() {
-	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${ED}" -name '*.la' -delete || die
-}
diff --git a/dev-libs/mpfr/Manifest b/dev-libs/mpfr/Manifest
index 739b0412c47c..ef27522302c2 100644
--- a/dev-libs/mpfr/Manifest
+++ b/dev-libs/mpfr/Manifest
@@ -14,6 +14,9 @@ DIST mpfr-4.1.0-patch13.patch 3344 BLAKE2B 1239cf16dfe32a71bb6fc7b156978cd451bcb
 DIST mpfr-4.1.0.tar.xz 1525476 BLAKE2B 41d1be0c4b557760f12a4525ad3a84b6e2cd6f0927c935fcfba577ac0490e582d1ae4b581dce58e21e705cf9d7c88373054d7fb7a94bb32c69b339f99a25dc68 SHA512 1bd1c349741a6529dfa53af4f0da8d49254b164ece8a46928cdb13a99460285622d57fe6f68cef19c6727b3f9daa25ddb3d7d65c201c8f387e421c7f7bee6273
 DIST mpfr-4.1.1-patch01.patch 2985 BLAKE2B d6bed1d6fca2319db457096a81aca060c1bd934fcdf9c5f98ba44920a7e97c2a5e9c539ec554feb723fb98c84096e1cb615c0d973133c67f3c2097edc1c5b803 SHA512 aa98173d59a24d0f59acff0c2143db5623746db3f6445e300a018a124b35a6b57d631c357a9a890f23c748591f621a95d3a801bed7341b6c8b6ddcc86ecfb107
 DIST mpfr-4.1.1.tar.xz 1429836 BLAKE2B ce20baee2f060acb28b877ffe6fc40c5619cf6af231bd54ca6cfb3e42ef2d74a4ffbab96cf0b5dd6a162e558099a54701d42f34f5bf2256f256fe6f5ae2505d0 SHA512 be468749bd88870dec37be35e544983a8fb7bda638eb9414c37334b9d553099ea2aa067045f51ae2c8ab86d852ef833e18161d173e414af0928e9a438c9b91f1
+DIST mpfr-4.2.0-rc1.tar.xz 1476596 BLAKE2B 0bb116d26743a5ce644d7c9ecbbec903e5556483fff0bf3a42a572e1fd56ba21e1d9e6ca45c8ee7d59c5e3bd9cf243987a75bfffbddbb6d7e7ac0509da99052a SHA512 ea5edc569fbafa01b83aa4e5022f9b2021d5768649073cf5ee3d6b5a94c0ac207dada301076e033174ffa07a24f5e42e8d82fe69bca6b696e04dc250385dd919
+DIST mpfr-4.2.0-rc1.tar.xz.asc 228 BLAKE2B 5d02eb5aef7224754ac5c4f15f4b58897f0327bc0672c70d5db664a73a0731480afcef3ac1ee6e2b1f0ed5e124a74a662adf1e8febf55b41b296402f899b9195 SHA512 29245c05f97ccc24aca38776231a73d2738077dedd488fd6148c18d93318f5b4c8abe6f6e9ba92c56a85cd1823f208828dc2f1691e941825e2d04d69c1357ff7
 EBUILD mpfr-4.1.0_p13-r1.ebuild 2700 BLAKE2B 46afea4da633c055ece8404cfabe6171abb568061a33445a58a961b55a3eb23ed28f08011efc001de2fdccc79c3ab34cc2d798be48928b74d2d1a302b8273cf2 SHA512 2e088ffc2e2343d8ce54b62ff625df579ea9236e31981f893c478f1e2b14e19d3bfa332d98fe9c486793a23acf76b231abf8ada2c1f4e7319bafa9ace3daf2fa
 EBUILD mpfr-4.1.1_p1.ebuild 2708 BLAKE2B ad21498526dd91dcc6d03b35153cbd284d85d1ee90515ab3e323a3e9c44a16ce4b8bdc59c590b5b0b7166d1a3f8fc86f42fa5b72bab7fa7e3df72e7bba3586a5 SHA512 d08c80ed13fad11c6469812d1ba9aa1074ecb27707469c1ea368e77fc9d9d5d09511c205490f97450f0c4114ac09fed53a9170259ba66f82eea949c10b0ae42f
+EBUILD mpfr-4.2.0_rc1.ebuild 3105 BLAKE2B 499f1631ce48757b6cc67b702f97130013665401ec66320167f90efbea45a4d89081c68adeb953efc190cab8ee92e49b39a773798d8fdf440fb951e49716677d SHA512 8594a1d37e2a21f416bb84aafb61bf1c44508fdbcf4cfb588f977901fbab4024295d2892a931e1e095ddaa07d88eb87710acf557804fea986e87c7070b5cc9f6
 MISC metadata.xml 344 BLAKE2B b7a0bcfbcf945ce2b6d58a9a2078c823c12de5ef8261ec009612b58a833deecb7caaf864f0b55e0c46aac004c58feb7a1f88f6d78b584c2e25c403cfb1de96a0 SHA512 8b8b5ae00a4f9ba76c193c5d84f27cce973963f4db109219394efccba3a8e8bebb7f241658a0b682331e34c66ee99332f871d826abf6ec5a4ced4f3dce381fe9
diff --git a/dev-libs/mpfr/mpfr-4.2.0_rc1.ebuild b/dev-libs/mpfr/mpfr-4.2.0_rc1.ebuild
new file mode 100644
index 000000000000..471d276fecb5
--- /dev/null
+++ b/dev-libs/mpfr/mpfr-4.2.0_rc1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/vincentlefevre.asc
+inherit multilib-minimal verify-sig
+
+# Upstream distribute patches before a new release is made
+# See https://www.mpfr.org/mpfr-current/#bugs for the latest version (and patches)
+
+# Check whether any patches touch e.g. manuals!
+# https://archives.gentoo.org/gentoo-releng-autobuilds/message/c2dd39fc4ebc849db6bb0f551739e2ed
+MY_PV=${PV%%_p*}
+MY_PATCH=$(ver_cut 5-)
+MY_PATCHES=()
+MY_P=${PN}-${MY_PV/_/-}
+
+DESCRIPTION="Library for multiple-precision floating-point computations with exact rounding"
+HOMEPAGE="https://www.mpfr.org/ https://gitlab.inria.fr/mpfr"
+SRC_URI="https://www.mpfr.org/${PN}-$(ver_cut 1-3)/${MY_P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://www.mpfr.org/${PN}-$(ver_cut 1-3)/${MY_P}.tar.xz.asc )"
+
+if [[ ${PV} == *_p* ]] ; then
+	# If this is a patch release, we have to download each of the patches:
+	# -_pN = N patches
+	# - patch file names are like: patch01, patch02, ..., patch10, patch12, ..
+	#
+	# => name the ebuild _pN where N is the number of patches on the 'bugs' page.
+	for ((my_patch_index=1; my_patch_index <= MY_PATCH; my_patch_index++)); do
+		SRC_URI+=" $(printf "https://www.mpfr.org/${PN}-$(ver_cut 1-3)/patch%02d -> ${PN}-$(ver_cut 1-3)-patch%02d.patch " ${my_patch_index}{,})"
+		MY_PATCHES+=( "${DISTDIR}"/$(printf ${PN}-$(ver_cut 1-3)-patch%02d.patch ${my_patch_index}) )
+	done
+	unset my_patch_index
+fi
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1"
+# This is a critical package; if SONAME changes, bump subslot but also add
+# preserve-libs.eclass usage to pkg_*inst! See e.g. the readline ebuild.
+SLOT="0/6" # libmpfr.so version
+if [[ ${PV} != *_rc* ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/gmp-5.0.0:=[${MULTILIB_USEDEP},static-libs?]"
+DEPEND="${RDEPEND}"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-vincentlefevre )"
+
+PATCHES=(
+	# Apply the upstream patches released out-of-band; generated above
+	"${MY_PATCHES[@]}"
+
+	# Additional patches
+)
+
+HTML_DOCS=( doc/FAQ.html )
+
+src_unpack() {
+	verify-sig_verify_detached "${DISTDIR}"/${MY_P}.tar.xz{,.asc}
+
+	# Avoid src_unpack noise from patches
+	unpack ${MY_P}.tar.xz
+}
+
+src_prepare() {
+	default
+
+	# 4.1.0_p13's patch10 patches a .texi file *and* the corresponding
+	# info file. We need to make sure the info file is newer, so the
+	# build doesn't try to run makeinfo. Won't be needed on next release.
+	#touch "${S}/doc/mpfr.info" || die
+}
+
+multilib_src_configure() {
+	# bug #476336#19
+	# Make sure mpfr doesn't go probing toolchains it shouldn't
+	ECONF_SOURCE="${S}" \
+		user_redefine_cc=yes \
+		econf $(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	rm "${ED}"/usr/share/doc/${PF}/COPYING* || die
+
+	if ! use static-libs ; then
+		find "${ED}"/usr -name '*.la' -delete || die
+	fi
+}