gentoo resync : 08.01.2021

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-libs/volume_key/volume_key-0.3.12-r3.ebuild b/dev-libs/volume_key/volume_key-0.3.12-r3.ebuild
new file mode 100644
index 000000000000..b2c7c39f30b4
--- /dev/null
+++ b/dev-libs/volume_key/volume_key-0.3.12-r3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Library for manipulating and storing storage volume encryption keys"
+HOMEPAGE="https://pagure.io/volume_key"
+SRC_URI="http://releases.pagure.org/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~mips ppc ppc64 ~sparc x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-crypt/gpgme
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	sys-apps/util-linux
+	sys-fs/cryptsetup:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	test? ( dev-libs/nss[utils] )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-support_higher_LUKS_versions.patch"
+	"${FILESDIR}/${PN}-0.3.12-find_python3.patch" #764230
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf #764230
+}
+
+src_configure() {
+	# --without-python disables python2
+	econf --without-python --with-python3
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	python_optimize
+}