gentoo resync : 17.01.2010

1 files changed, 36 insertions, 0 deletions

diff --git a/dev-libs/libvterm/libvterm-0.1.3.ebuild b/dev-libs/libvterm/libvterm-0.1.3.ebuild
new file mode 100644
index 000000000000..dacba680fa78
--- /dev/null
+++ b/dev-libs/libvterm/libvterm-0.1.3.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic
+
+DESCRIPTION="An abstract library implementation of a VT220/xterm/ECMA-48 terminal emulator"
+HOMEPAGE="http://www.leonerd.org.uk/code/libvterm/"
+SRC_URI="http://www.leonerd.org.uk/code/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+BDEPEND="
+	dev-lang/perl
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+DEPEND=""
+RDEPEND="!dev-libs/libvterm-neovim"
+
+src_compile() {
+	append-cflags -fPIC
+	emake VERBOSE=1 PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+	emake \
+		VERBOSE=1 \
+		PREFIX="${EPREFIX}/usr" \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die "Failed to prune libtool files"
+}