Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-libs/libf2c/libf2c-20110801-r4.ebuild b/dev-libs/libf2c/libf2c-20110801-r4.ebuild
new file mode 100644
index 000000000000..50e2c97344ee
--- /dev/null
+++ b/dev-libs/libf2c/libf2c-20110801-r4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Library that converts FORTRAN to C source"
+HOMEPAGE="http://www.netlib.org/f2c/"
+SRC_URI="${HOMEPAGE}/${PN}.zip -> ${P}.zip"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/20051004-add-ofiles-dep.patch \
+		"${FILESDIR}"/20090407-link-shared-libf2c-correctly.patch \
+		"${FILESDIR}"/${P}-main.patch\
+		"${FILESDIR}"/${P}-64bit-long.patch \
+		"${FILESDIR}"/${P}-format-security.patch
+	sed -i -e "s/ld /$(tc-getLD) /" makefile.u || die
+}
+
+src_compile() {
+	emake \
+		-f makefile.u \
+		libf2c.so \
+		CFLAGS="${CFLAGS} -fPIC" \
+		CC="$(tc-getCC)"
+
+	# Clean up files so we can recompile without PIC for the static lib
+	if use static-libs; then
+		rm *.o || die "clean failed"
+		emake \
+			-f makefile.u \
+			all \
+			CFLAGS="${CFLAGS}" \
+			CC="$(tc-getCC)"
+	fi
+}
+
+src_install () {
+	dolib libf2c.so.2
+	dosym libf2c.so.2 /usr/$(get_libdir)/libf2c.so
+	use static-libs && dolib.a libf2c.a
+	doheader f2c.h
+	dodoc README Notice
+}