Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-libs/libcdio-paranoia/libcdio-paranoia-0.90_p1-r1.ebuild b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.90_p1-r1.ebuild
new file mode 100644
index 000000000000..ed391732a871
--- /dev/null
+++ b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.90_p1-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P=${PN}-10.2+${PV/_p/+}
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="an advanced CDDA reader with error correction"
+HOMEPAGE="https://www.gnu.org/software/libcdio/"
+SRC_URI="mirror://gnu/${PN%-*}/${MY_P}.tar.gz"
+
+# COPYING-GPL from cdparanoia says "2 or later"
+# COPYING-LGPL from cdparanoia says "2.1 or later" but 2 files are without the
+# clause "or later" so we use LGPL-2.1 without +
+LICENSE="GPL-3+ GPL-2+ LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="+cxx static-libs test"
+
+RDEPEND="app-eselect/eselect-cdparanoia
+	>=dev-libs/libcdio-0.90-r1[${MULTILIB_USEDEP}]
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.90-mkdir_p.patch
+)
+
+src_prepare() {
+	default
+	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466410
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-maintainer-mode
+		--disable-example-progs
+		$(use_enable cxx)
+		--disable-cpp-progs
+		--with-cd-paranoia-name=libcdio-paranoia
+	)
+	ECONF_SOURCE="${S}" \
+		econf "${myeconfargs[@]}"
+}
+
+pkg_postinst() {
+	eselect cdparanoia update ifunset
+}
+
+pkg_postrm() {
+	eselect cdparanoia update ifunset
+}