gentoo resync : 16.04.2018

2 files changed, 113 insertions, 0 deletions

diff --git a/dev-libs/gmp/Manifest b/dev-libs/gmp/Manifest
index d63e38afb108..7ad64da8ac54 100644
--- a/dev-libs/gmp/Manifest
+++ b/dev-libs/gmp/Manifest
@@ -19,5 +19,6 @@ EBUILD gmp-4.3.2-r1.ebuild 1697 BLAKE2B 2485e688b5d75b96c5cc97e819b8aea9297c217d
 EBUILD gmp-6.0.0a.ebuild 2886 BLAKE2B 7ec35c00eea809640936ba484b676330c812f2b9a34f5d868c84e1403db20d76d1f914af2fde7e4815fd096bc9a1a9bf75c4f8ac9af720f918ba0ec0acfb5fde SHA512 d177ddccd7e211779a30b1020f5358137314beb44e0712750e8ac1f690adef02007627cc7ae744340b79c9939bbf134f30c582bd00329106f1c6c926ba2b3127
 EBUILD gmp-6.1.0.ebuild 3012 BLAKE2B ced6929c84e0718d3f46fe434d372f0e1ef929a11fd2bc3e219378809d96d6ae4d8f9cca1e542be516c127d652a7741604f84578eee6cbfbc84104ce592dff73 SHA512 4d74dfbd2a3ec15ea87644bc142ed472ed1b9ae60c382cbec9a1a1f06de742cc5a492d775fbfcb720eb0f28301b195c631db99decb83b5f05fd1bccdb2818b97
 EBUILD gmp-6.1.1.ebuild 3025 BLAKE2B fd8b00e769787bd092e34f21a4c06c9f52c26d2acd2ceb1e7622514371337e70a088cd8578e78d0f86c70a602b52a01cff9b963b881df9461f198e6dfbbf9113 SHA512 8a042992fa08f825b9c8b715677ba1a55e1be2aaced085b3776fd82eb8a97097eb8ca389f3b184c245ed2b6c28d1df63d235bd2feee72cc36277c753fe4454e6
+EBUILD gmp-6.1.2-r1.ebuild 2955 BLAKE2B 3580f25174177ec6aa4c6ed163ea9eb6e98bef35d31d558f1b0ead96059d28a3a407042246684e12c8b64da5b394a5525b983876c04148a156668807f96d9dc4 SHA512 1dde8f10c5a1bf3b34f395cd7e2bd98eefb8f3d617eb7c6cee8c9c0b2dc3f32d91a5bbfdd9bad1a7c36f80290bdd3307a97fca63fe7a445b2393e8ae6478ae11
 EBUILD gmp-6.1.2.ebuild 3277 BLAKE2B a05108385e65f57492ee257c77db16dbd43bc53f87d7d311c8e285d1c991ef3f665b69cfba8631d90dbf56f852586f73cfa2ef6ec31c905d505c0f64957fe4e8 SHA512 8ecc349abc523fb6914160c7ffae905b14605f130942fa7092acf3bef170f7d09b38fa8c16e1cb47b27ef1bca0e16fcde413609e56a329ed70c7b415ac1b6ad1
 MISC metadata.xml 501 BLAKE2B f72cb10582beb651fddf6d5abe85920d6f8c9d7a87b82e6778a641bc75202213432105da5cfefbdcd9d343180cca7f2f56638f27c9e059d68afa92d6ee0d6665 SHA512 bde33c241d1e7026e86e7a445bcd929f8a2f6d2dc7a0e71994f2130459910a0ac51d6d3d8cad0fd45baea0d0a38c818348d2427035ef393ac6343ee993c95dd7
diff --git a/dev-libs/gmp/gmp-6.1.2-r1.ebuild b/dev-libs/gmp/gmp-6.1.2-r1.ebuild
new file mode 100644
index 000000000000..8ee5a2ba140f
--- /dev/null
+++ b/dev-libs/gmp/gmp-6.1.2-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit flag-o-matic eutils libtool multilib-minimal
+
+MY_PV=${PV/_p*}
+MY_PV=${MY_PV/_/-}
+MY_P=${PN}-${MY_PV}
+PLEVEL=${PV/*p}
+DESCRIPTION="Library for arbitrary-precision arithmetic on different type of numbers"
+HOMEPAGE="http://gmplib.org/"
+SRC_URI="ftp://ftp.gmplib.org/pub/${MY_P}/${MY_P}.tar.xz
+	mirror://gnu/${PN}/${MY_P}.tar.xz
+	doc? ( http://gmplib.org/${PN}-man-${MY_PV}.pdf )"
+
+LICENSE="|| ( LGPL-3+ GPL-2+ )"
+# The subslot reflects the C & C++ SONAMEs.
+SLOT="0/10.4"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+asm doc cxx static-libs"
+
+DEPEND="sys-devel/m4
+	app-arch/xz-utils"
+RDEPEND=""
+
+S=${WORKDIR}/${MY_P%a}
+
+DOCS=( AUTHORS ChangeLog NEWS README doc/configuration doc/isa_abi_headache )
+HTML_DOCS=( doc )
+MULTILIB_WRAPPED_HEADERS=( /usr/include/gmp.h )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.1.0-noexecstack-detect.patch
+)
+
+src_prepare() {
+	default
+
+	# note: we cannot run autotools here as gcc depends on this package
+	elibtoolize
+
+	# https://bugs.gentoo.org/536894
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		eapply "${FILESDIR}"/${PN}-6.1.2-gcc-apple-4.0.1.patch
+	fi
+
+	# GMP uses the "ABI" env var during configure as does Gentoo (econf).
+	# So, to avoid patching the source constantly, wrap things up.
+	mv configure configure.wrapped || die
+	cat <<-\EOF > configure
+	#!/usr/bin/env sh
+	exec env ABI="${GMPABI}" "$0.wrapped" "$@"
+	EOF
+	# Patches to original configure might have lost the +x bit.
+	chmod a+rx configure{,.wrapped} || die
+}
+
+multilib_src_configure() {
+	# Because of our 32-bit userland, 1.0 is the only HPPA ABI that works
+	# http://gmplib.org/manual/ABI-and-ISA.html#ABI-and-ISA (bug #344613)
+	if [[ ${CHOST} == hppa2.0-* ]] ; then
+		GMPABI="1.0"
+	fi
+
+	# ABI mappings (needs all architectures supported)
+	case ${ABI} in
+		32|x86)       GMPABI=32;;
+		64|amd64|n64) GMPABI=64;;
+		[onx]32)      GMPABI=${ABI};;
+	esac
+	export GMPABI
+
+	#367719
+	if [[ ${CHOST} == *-mint* ]]; then
+		filter-flags -O?
+	fi
+
+	tc-export CC
+	ECONF_SOURCE="${S}" econf \
+		--localstatedir="${EPREFIX}"/var/state/gmp \
+		--enable-shared \
+		$(use_enable asm assembly) \
+		$(use_enable cxx) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_compile() {
+	emake
+}
+
+multilib_src_test() {
+	emake check
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	# should be a standalone lib
+	rm -f "${ED}"/usr/$(get_libdir)/libgmp.la
+	# this requires libgmp
+	local la="${ED}/usr/$(get_libdir)/libgmpxx.la"
+	use static-libs \
+		&& sed -i 's:/[^ ]*/libgmp.la:-lgmp:' "${la}" \
+		|| rm -f "${la}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	use doc && cp "${DISTDIR}"/gmp-man-${MY_PV}.pdf "${ED}"/usr/share/doc/${PF}/
+}