gentoo resync : 25.08.2018

3 files changed, 286 insertions, 2 deletions

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index bc7172315470..b0d2f5ce7b4f 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -2,7 +2,9 @@ AUX efl-1.17.0-gnutls-3.4.patch 1303 BLAKE2B 74368829bd2cc3ebf1878384dfa6fc5a429
 DIST efl-1.17.0.tar.xz 43485360 BLAKE2B 97a79bda40658eac6e50886a01821bb8c98d6f56d18fcd51dc3827154506064bec3bf665c8f471919aedb03ae83ce4045293afa9a0bf8d3eaf947221ef7cba9e SHA512 e4f28f938daf4ec1cb3d761407a443e401b59c6bb0f9fa6cd771dbd256b95f4a32a5f9e6bd8ad8328708a382f732e67abd1a23c7be2ff222f08bc8135a2435da
 DIST efl-1.18.4.tar.xz 64609944 BLAKE2B b36e5ee7c64a57772c5826e990a85110fffc3488e605d72515d4db7a6ec56eee25eb68c7136840f24cb8cdcdc8d7050e2825c17f0e4c5566db7d9ec2c96fd557 SHA512 2cfdcde8b5adb93310e75e4923e3845392bed97563ca1a68f4537e346b51f59acefaa85a425bdbb5619e5bfd6c9ff92b4bd1888b5d4ddd8db94c8a555e3934c9
 DIST efl-1.20.7.tar.xz 65509444 BLAKE2B f58f7daf850ef9983fe4b3a10a3ceb137be7f7ae32c71f476498f677de690bfcc7c16aea5032168a42aa6b5f97d1fb5ca51dafc69d80e2a9262f4d78220a8562 SHA512 c1bf18b74316cf9bd0bc16635c216ca0d8005b2ded1c014b22590388e37368343e5e5318f526dcb042cfce8ab2c7a82655e4718cbcac5dd1ed0d2522a7a2d7de
+DIST efl-1.21.0.tar.xz 71030532 BLAKE2B 3480e261aef05b169a850d27f3d9fa6da0ad9bc9ac04548137829e662546cd7d85c87596576e561bba33f9f1be657d81f261595e34c711ff9e35d551ae5f09a8 SHA512 497735f518976d70b96023b013a6d821f6695fe56def2abf5bd1e1c7ad89d324428017d7909c7b73bfb332b811b5596592b105bb4c3d2f6a40929f1cefc2b789
 EBUILD efl-1.17.0-r1.ebuild 7068 BLAKE2B e0ce5cf1e86f41918799a7ceebfa341726ea9a700c7e2e4d89acedaf595171b12bef11261fed2bea14c4099fa63fcf063d0eddb49c1dcf490449f936ec4dd1c8 SHA512 a5293c2f97a4976fe3681ad8da97918f37a0bd47bf37cf38d4f025ad7512782e967deaef1d2f80c624ccf57c8b68b74f8288a9b223f710dcee3bde515d454be2
 EBUILD efl-1.18.4-r1.ebuild 7298 BLAKE2B d88740f4081b53d274f36e1f8200dd917030b6246cc88d8f9f2b24569ff79a69f2b7e68e76d61e2123297315850d03c3273894ffc0a508d425724fb25395ddd3 SHA512 2e2992916f6af3acec5af00c3d5c3e781414fb2c35c13000a18786dfd0e46ba27506130010900cbe75da80f33fa62410ccfb597be4b77d2770773bdf87be7faa
 EBUILD efl-1.20.7-r1.ebuild 7785 BLAKE2B 6f9cff3f6fbf9a8169251b5e89b447cf20a9d9a187efe24681dc6d6e5e6fa912018df393444fd7720d0605116c68f0ad0c7173192ca720ccb3472da57d11e6b0 SHA512 3433be6e2fe8913671f8028fbd2566ea98fb4f14c9184086f4bd13760aaa153769b024dd57faa7e0c5327b6de961f55175c5d35ecc515b7e76a11c595f6e0d0d
-MISC metadata.xml 2242 BLAKE2B 5bcbcb78454bc3640d839857c026114a69f485bbbe934cc2db098168368c34e0840e37389628e8c0425e9045833735c58c8c1a36132a76d36c3eeef4d8c557f7 SHA512 65a10606f3e77f82a26b4cf9fdba2a4ef1358fcd041ee5bbffe2a932477597479cdc604dd5df1a4cb0384709116b1d9430f1815f5020b1ff7cf4eeea7d8cd0f3
+EBUILD efl-1.21.0.ebuild 6780 BLAKE2B b172687994d6794457cbfc4f282b12646e2865ae909b7348f4776570c4a95020457c59aded59a9abc7d133804293ce5d7755221be5aede6f58cffef04792b7de SHA512 58c326f5cb419931a15c4745c0fef5b4fb3b5034611fc5d3acbcd9e8df9deee2bd14f3d67b98d9d6d49805600699ddbadfe6da0c0c9f2b79c6d1bd5af32324e4
+MISC metadata.xml 2316 BLAKE2B d7401c2e633366d6c74a9bb5633160b868ee0ec2c8a04c3cc4da43898c50192238ac19eb7fc9aad88593d974c5fcf0cd2cf0413e66ecb4134d19581ff002fd10 SHA512 5e0a520c7854a1837dbf4c1e7f6e5e64695f62892118ca99e41f389efd4145066348f5023a0e4bf2d5b061d36dfa66ae9ce979f3b614fcb6498dafd9609c0530
diff --git a/dev-libs/efl/efl-1.21.0.ebuild b/dev-libs/efl/efl-1.21.0.ebuild
new file mode 100644
index 000000000000..77750924fd50
--- /dev/null
+++ b/dev-libs/efl/efl-1.21.0.ebuild
@@ -0,0 +1,281 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils pax-utils xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org/"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="avahi +bmp dds connman debug drm +eet egl examples fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpresent xpm"
+
+REQUIRED_USE="
+	?? ( opengl egl )
+	?? ( opengl gles )
+	fbcon? ( !tslib )
+	gles? (
+		|| ( X wayland )
+		!sdl
+		egl
+	)
+	ibus? ( glib )
+	opengl? ( X )
+	pulseaudio? ( sound )
+	sdl? ( opengl )
+	vnc? ( X fbcon )
+	wayland? ( egl gles !opengl )
+	xim? ( X )
+"
+
+COMMON_DEPEND="
+	net-misc/curl
+	media-libs/libpng:0=
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/zlib:=
+	virtual/jpeg:0=
+	avahi? ( net-dns/avahi )
+	connman? ( net-misc/connman )
+	drm? (
+		dev-libs/libinput
+		media-libs/mesa[gbm]
+		x11-libs/libdrm
+		x11-libs/libxkbcommon
+	)
+	egl? ( media-libs/mesa[egl] )
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib:= )
+	glib? ( dev-libs/glib:2 )
+	gles? ( media-libs/mesa[gles2] )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	harfbuzz? ( media-libs/harfbuzz )
+	hyphen? ( dev-libs/hyphen )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:0= )
+	libuv? ( dev-libs/libuv )
+	luajit? ( dev-lang/luajit:= )
+	!luajit? ( dev-lang/lua:* )
+	nls? ( sys-devel/gettext )
+	pdf? ( app-text/poppler:=[cxx] )
+	physics? ( sci-physics/bullet:= )
+	postscript? ( app-text/libspectre )
+	pulseaudio? ( media-sound/pulseaudio )
+	raw? ( media-libs/libraw:= )
+	scim? ( app-i18n/scim )
+	sdl? (
+		media-libs/libsdl2
+		virtual/opengl
+	)
+	sound? ( media-libs/libsndfile )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:= )
+			libressl? ( dev-libs/libressl:= )
+		)
+	)
+	svg? (
+		gnome-base/librsvg
+		x11-libs/cairo
+	)
+	system-lz4? ( app-arch/lz4 )
+	systemd? ( sys-apps/systemd )
+	tiff? ( media-libs/tiff:0= )
+	tslib? ( x11-libs/tslib:= )
+	unwind? ( sys-libs/libunwind )
+	valgrind? ( dev-util/valgrind )
+	vlc? ( media-video/vlc )
+	vnc? ( net-libs/libvncserver )
+	wayland? (
+		dev-libs/wayland
+		media-libs/mesa[gles2,wayland]
+		x11-libs/libxkbcommon
+	)
+	webp? ( media-libs/libwebp:= )
+	X? (
+		media-libs/freetype
+		x11-libs/libXcursor
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+		opengl? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+		gles? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+			xpresent? ( x11-libs/libXpresent )
+		)
+	)
+	xine? ( media-libs/xine-lib )
+	xpm? ( x11-libs/libXpm )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	!media-libs/elementary
+	!media-plugins/emotion_generic_players
+	!media-plugins/evas_generic_loaders
+"
+
+src_prepare() {
+	default
+
+	# Upstream still doesnt offer a configure flag. #611108
+	if ! use unwind ; then
+		sed -i -e 's:libunwind libunwind-generic:xxxxxxxxxxxxxxxx:' \
+		configure || die "Sedding configure file with unwind fix failed."
+	fi
+
+	xdg_environment_reset
+}
+
+src_configure() {
+	local myconf=(
+		--enable-cserve
+		--enable-image-loader-generic
+		--enable-image-loader-jpeg
+		--enable-image-loader-png
+		--enable-libeeze
+		--enable-libmount
+		--enable-xinput22
+
+		--disable-doc
+		--disable-gesture
+		--disable-gstreamer
+		--disable-image-loader-tgv
+		--disable-tizen
+		--disable-wayland-ivi-shell
+
+		$(use_enable avahi)
+		$(use_enable bmp image-loader-bmp)
+		$(use_enable bmp image-loader-wbmp)
+		$(use_enable dds image-loader-dds)
+		$(use_enable drm)
+		$(use_enable drm elput)
+		$(use_enable eet image-loader-eet)
+		$(use_enable egl)
+		$(use_enable examples always-build-examples)
+		$(use_enable fbcon fb)
+		$(use_enable fontconfig)
+		$(use_enable fribidi)
+		$(use_enable gif image-loader-gif)
+		$(use_enable gstreamer gstreamer1)
+		$(use_enable harfbuzz)
+		$(use_enable hyphen)
+		$(use_enable ico image-loader-ico)
+		$(use_enable ibus)
+		$(use_enable jpeg2k image-loader-jp2k)
+		$(use_enable libuv)
+		$(use_enable !luajit lua-old)
+		$(use_enable neon)
+		$(use_enable nls)
+		$(use_enable pdf poppler)
+		$(use_enable physics)
+		$(use_enable postscript spectre)
+		$(use_enable ppm image-loader-pmaps)
+		$(use_enable psd image-loader-psd)
+		$(use_enable pulseaudio)
+		$(use_enable raw libraw)
+		$(use_enable scim)
+		$(use_enable sdl)
+		$(use_enable sound audio)
+		$(use_enable static-libs static)
+		$(use_enable svg librsvg)
+		$(use_enable system-lz4 liblz4)
+		$(use_enable systemd)
+		$(use_enable tga image-loader-tga)
+		$(use_enable tiff image-loader-tiff)
+		$(use_enable tslib)
+		$(use_enable v4l v4l2)
+		$(use_enable valgrind)
+		$(use_enable vlc libvlc)
+		$(use_enable vnc vnc-server)
+		$(use_enable wayland)
+		$(use_enable webp image-loader-webp)
+		$(use_enable xcf)
+		$(use_enable xim)
+		$(use_enable xine)
+		$(use_enable xpm image-loader-xpm)
+
+		--with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+		--with-glib=$(usex glib)
+		--with-js=none
+		--with-net-control=$(usex connman connman none)
+		--with-profile=$(usex debug debug release)
+		--with-x11=$(usex X xlib none)
+
+		$(use_with X x)
+	)
+
+	use fbcon && use egl &&	myconf+=( --enable-eglfs )
+	use drm && use wayland && myconf+=( --enable-gl-drm )
+	use X && use xpresent && myconf+=( --enable-xpresent )
+
+	if use opengl ; then
+		myconf+=( --with-opengl=full )
+	elif use egl ; then
+		myconf+=( --with-opengl=es )
+	elif use drm && use wayland ; then
+		myconf+=( --with-opengl=es )
+	else
+		myconf+=( --with-opengl=none )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	if host-is-pax && use luajit ; then
+		# We need to build the lua code first so we can pax-mark it. #547076
+		local target='_e_built_sources_target_gogogo_'
+		printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+		emake -C src "${target}"
+		emake -C src bin/elua/elua
+		pax-mark m src/bin/elua/.libs/elua
+	fi
+
+	V=1 emake || die "Compiling EFL failed."
+}
+
+src_install() {
+	einstalldocs
+
+	V=1 emake install DESTDIR="${D}" || die "Installing EFL files failed."
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+}
diff --git a/dev-libs/efl/metadata.xml b/dev-libs/efl/metadata.xml
index 591fc67fc6f0..221e9e373197 100644
--- a/dev-libs/efl/metadata.xml
+++ b/dev-libs/efl/metadata.xml
@@ -23,13 +23,14 @@
 		<flag name="ico">Enable Ico image loader</flag>
 		<flag name="ivi">Enable ivi-shell support</flag>
 		<flag name="libuv">Enable <pkg>dev-libs/libuv</pkg> support</flag>
-		<flag name="luajit">USE <pkg>dev-lang/lua</pkg> instead of <pkg>dev-lang/luajit</pkg></flag>
+		<flag name="luajit">USE <pkg>dev-lang/luajit</pkg> instead of <pkg>dev-lang/lua</pkg></flag>
 		<flag name="oldlua">USE <pkg>dev-lang/lua</pkg> instead of <pkg>dev-lang/luajit</pkg></flag>
 		<flag name="physics">Enable Bullet physics effects and support</flag>
 		<flag name="pixman">Enable PixMan for software rendering</flag>
 		<flag name="ppm">Enable PMAPS image loader</flag>
 		<flag name="psd">Enable PSD image loader</flag>
 		<flag name="scim">Enable Smart Common Input Method</flag>
+		<flag name="system-lz4">Use system liblz4 instead of bundled one</flag>
 		<flag name="tga">Enable Tga image loader</flag>
 		<flag name="tslib">Enable <pkg>x11-libs/tslib</pkg> for touchscreen events</flag>
 		<flag name="unwind">Enable debug support via <pkg>sys-libs/libunwind</pkg></flag>