gentoo resync : 30.05.2020

3 files changed, 108 insertions, 3 deletions

diff --git a/dev-libs/cyberjack/Manifest b/dev-libs/cyberjack/Manifest
index 83fdfe741869..72aac36feb44 100644
--- a/dev-libs/cyberjack/Manifest
+++ b/dev-libs/cyberjack/Manifest
@@ -1,3 +1,5 @@
+DIST pcsc-cyberjack-3.99.5final.SP14.tar.bz2 1090014 BLAKE2B 15c9d0225f03d1fcbc636b6f8ae29f265243af35bc78c48f2e9cca27c7731ebb30069eb5bf377ce66d2c7afb31e1fb5d839001fa21e854a4bdc56237bf780327 SHA512 f39e4f13776d8c4e4bc5ea3cc64e64649d8dea334f50b9bcc9cc6f1fc9e7433ef32b8fcb00b5dad78867029dab0a099c0d7799d7e8f80d0f310b0f53dbd2a7b9
 DIST pcsc-cyberjack_3.99.5final.SP13.tar.gz 1617714 BLAKE2B 344f00217fa5dfb18e5318d2b8ccb88a3cc12b86a9c14d41a9800d701d0fc7a0a486a0b3c05188d07d1f7c51c4c514c48a55d987d8d9d2af574f427e550c8654 SHA512 74ac56a0f74a69006c87e2c22e147b65d26582d29753de03d56e4ad76413f4477a031d47f5eb074323b4ffd000b0908a1fb2b12fb7d91e9b3ee67e983e09e968
-EBUILD cyberjack-3.99.5_p13.ebuild 1909 BLAKE2B 89a8930abaf196be95b6657497a5756469ffb0d1021aea7fb383aa4cbe0a44bdf4f19eb89e91908f79afcefd42d48c9c66d89ddc645270c610c2d7fce4fcd945 SHA512 e639adafff9fbc49deafaba8c35886bc3efb260a37dfdcd18200b70a6fb43cfa8781609e5ab87fbeb844c9bf10908d5a880468130c6522e592062bda29040862
+EBUILD cyberjack-3.99.5_p13.ebuild 2053 BLAKE2B db68e22e63e6baef0a5ef2c0a1bee7a80a7230029baba274da4d4adcb48e71ad9d75c231f8e45372e047658c0f392f1f87639b29ef43e072695f91cc9f5edeba SHA512 7e6e012f1c60baf55b6565144dacef25022336f8895731363f561837330dfd60d5e54b6b4d8b2af502a4a87405ccf32eb9d323f8b92db6b75001a8b7191d38a6
+EBUILD cyberjack-3.99.5_p14.ebuild 2076 BLAKE2B 98a47e796c0cd1fffc15d4130390e3ca2db53722fe5414aad35cf1fe2cb7803dddd91851b8be0f99e760f3e7a1206937a876789168f4899b17f87abe06c749cf SHA512 7d71bb42bfdaccb82bf815b324cf2a69e1aa7166890b7024e8f6fc81119fdb97367b778b2ba80721680ed1af0b0c49bb26ae2299c645e21e52428a9ff7c3c679
 MISC metadata.xml 622 BLAKE2B 4238fe4ea370787f4542d53d161afaa0c0df5788d7a2da5ee6b99b788ae6d4456cd43d6ea8df0a174431b4582127fb49712a59ed2acdbeaf4808f57b8fa44930 SHA512 2062ac48ee73a6a58a2663e39f467e8e55f06af48b7a04b5f174e467c3f33d4b92b93b8fff3747447503b3256fc514fc40c8e07f7cbec8e1608d6389d9aed4ba
diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p13.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p13.ebuild
index edde80805904..97f2ad1beba3 100644
--- a/dev-libs/cyberjack/cyberjack-3.99.5_p13.ebuild
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p13.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -7,7 +7,7 @@ MY_PN="pcsc-${PN}"
 MY_PV="${PV/_p/final.SP}"
 MY_P="${MY_PN}_${MY_PV}"
 
-inherit autotools linux-info toolchain-funcs udev
+inherit autotools flag-o-matic linux-info toolchain-funcs udev
 
 DESCRIPTION="REINER SCT cyberJack USB chipcard reader user space driver"
 HOMEPAGE="https://www.reiner-sct.de/"
@@ -32,6 +32,12 @@ S="${WORKDIR}/${MY_P/_/-}"
 
 CONFIG_CHECK="~USB_SERIAL_CYBERJACK"
 
+pkg_setup() {
+	# Add workaround for GCC-10,
+	# by defining narrowing as warning like GCC-9 did.
+	append-cxxflags -Wno-narrowing
+}
+
 src_prepare() {
 	default
 
diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p14.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p14.ebuild
new file mode 100644
index 000000000000..53d0aee2a30f
--- /dev/null
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p14.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="pcsc-${PN}"
+MY_PV="${PV/_p/final.SP}"
+MY_P="${MY_PN}-${MY_PV}"
+
+inherit autotools flag-o-matic linux-info toolchain-funcs udev
+
+DESCRIPTION="REINER SCT cyberJack USB chipcard reader user space driver"
+HOMEPAGE="https://www.reiner-sct.de/"
+SRC_URI="http://kernelport.com/reiner-sct/SP$(ver_cut 5)/${MY_P}.tar.bz2"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+IUSE="static-libs threads tools +udev +usb xml"
+
+RDEPEND="
+	sys-apps/pcsc-lite
+	usb? ( virtual/libusb:1 )
+	udev? ( virtual/udev )
+	xml? ( dev-libs/libxml2:2= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+CONFIG_CHECK="~USB_SERIAL_CYBERJACK"
+
+pkg_setup() {
+	# Add workaround for GCC-10,
+	# by defining narrowing as warning like GCC-9 did.
+	# Upstream is working on that.
+	append-cxxflags -Wno-narrowing
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-debug
+		--disable-error-on-warning
+		--disable-hal
+		--disable-mac-universal
+		--disable-mac-arches-i386
+		--disable-mac-arches-x86_64
+		--disable-visibility
+		--enable-pcsc
+		--enable-release
+		--enable-warnings
+		--sysconfdir="/etc/cyberjack"
+		$(use_enable static-libs static)
+		$(use_enable threads)
+		$(use_enable udev)
+		$(use_enable usb nonserial)
+		$(use_enable xml xml2)
+		--with-usbdropdir="$($(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir)"
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use tools; then
+		# cjBingo can't be compiled, as it's defines stuff, which got dropped
+		cd "${S}"/tools/cjflash && emake
+		cd "${S}"/tools/cjgeldkarte && emake
+	fi
+}
+
+src_install() {
+	default
+
+	use tools && dobin tools/cjflash/cjflash tools/cjgeldkarte/cjgeldkarte
+	use udev && udev_newrules debian/libifd-cyberjack6.udev 99-${PN}.rules
+
+	dodoc debian/changelog doc/{LIESMICH,README}.{pdf,txt,xml}
+
+	docinto html
+	dodoc doc/{LIESMICH,README}.html
+
+	docinto source
+	dodoc doc/*.c*
+
+	find "${D}" -name '*.la' -delete || die
+}