gentoo resync : 20.03.2022

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-libs/boxfort/boxfort-0.1.4.ebuild b/dev-libs/boxfort/boxfort-0.1.4.ebuild
new file mode 100644
index 000000000000..c1d27a92948b
--- /dev/null
+++ b/dev-libs/boxfort/boxfort-0.1.4.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Convenient & cross-platform sandboxing C library"
+HOMEPAGE="https://github.com/Snaipe/BoxFort"
+SRC_URI="https://github.com/Snaipe/BoxFort/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/BoxFort-${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 -riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? (
+		$(python_gen_any_dep 'dev-util/cram[${PYTHON_USEDEP}]')
+	)"
+BDEPEND="virtual/pkgconfig"
+
+python_check_deps() {
+	use test && has_version "dev-util/cram[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test samples)
+		$(meson_use test tests)
+	)
+
+	meson_src_configure
+}