gentoo auto-resync : 12:04:2023 - 05:40:28

2 files changed, 184 insertions, 0 deletions

diff --git a/dev-libs/botan/Manifest b/dev-libs/botan/Manifest
index be02e316444f..a2e439596e71 100644
--- a/dev-libs/botan/Manifest
+++ b/dev-libs/botan/Manifest
@@ -2,6 +2,9 @@ DIST Botan-2.19.2.tar.xz 6063336 BLAKE2B a46fa49c61846e718197ab3a8431a5bdcab0f4c
 DIST Botan-2.19.2.tar.xz.asc 488 BLAKE2B 94d22dff9de02871560649b1d961f4c7ae5fa37a847141554f8da9f0a726d4497cd23e0d84197beb4d176f29aa3a478118d94cd52d2c04733d115828f85d400d SHA512 e25a03ac437a08737ecde541ead4b841ccb507d3198683a1755dab1d4f82e9ce0278473db7c7041a4b808f9dff9927106e30bbad79b1674615254ee78f0b6a06
 DIST Botan-2.19.3.tar.xz 6105896 BLAKE2B 6d7778d9e9a101c76f35c65b0fb0201641cd91967ba934510f3836ee4b924d54cabdc760dd460997679250aa66e1d2a99369cd03f8fb9e7b2fe672d4b355215f SHA512 80012397e2aa7cc88a9536340ac9b770d1195fddda53b9d4cfde82318dd05f9d4f925bbdff773aba99883a701f4d30581e9d5c97e915fa80c3ca2acfa5a92110
 DIST Botan-2.19.3.tar.xz.asc 488 BLAKE2B cd86bf77306aad2956cced6ac4fb96081279af88743e87d8fe5437e72e9fa8db8aaf40d0b5cb9c5b3a85204cb7d63c3baa3054126ab4c9a2db527e6835a069d7 SHA512 9142f932c958138b4bac32f503a550e6c73b61612690a280dcb98efe8c367aa6bd3cd88b4ed4decec376bb87596a780a21bdcb01d4a3573a1c44fbeb0aa49d23
+DIST Botan-3.0.0.tar.xz 8752380 BLAKE2B 06ac29dc0cbaef43a38cc30185f431e1b1f4083469fdea19ee5d77ada6633022746b8ae2419bd00872f9b3892af9c61a455bc88f77bef84f451938dffd27bde3 SHA512 d67ac0f9d67f6869b7a35d4a7c5e96ffcc619f7e44ead36b4cd0906f3d925d12181566aace03ac719ef54d819ae1158febc0b25839beed5f92eade06d510b594
+DIST Botan-3.0.0.tar.xz.asc 488 BLAKE2B 6a34817ec4700983151f97d2e278870736860ac72f3936fcc63e241d89ba758bdf7765d3c877d88019055562a6067c278ecbac263e8d87cc310790089e47f662 SHA512 46ff64bb4d215a48b0549d90ae2461ae39ae5ecf588a7e130876759ec30561c5a2db77ee9cdc7a3dab990927b51ea732f5b56592bdc150062ca25690378ab817
 EBUILD botan-2.19.2.ebuild 4430 BLAKE2B f3ecd4970642c364814e8ecbc7e831c8009b90d06b44dfc3da8abf270d7bd55f07715f86bf155a0e7f31baab03b849ccfbade89e346d8ccd2cb88edaeb7530a2 SHA512 42227dea382c9db6d3623506ab50ee4b3bf4139e419917c0f7e2fc5467b29a86723b1159e8025b982f7d82f057733cc8ac1193834e8a4609a5dfde80563f8205
 EBUILD botan-2.19.3.ebuild 4437 BLAKE2B 6766545b8af7ba09db9058900443863164b3e3bd0ae2805eb1a07d801f5cef52b4a6396270f37af3e1dbc688660c77ed1c8fe76bb1d686d3b89a0aa076893fd0 SHA512 cfc9151b1ee2f3f6c81b48fa64c607589bc004ccc60e0af2b1705bf60ab1e314001d3dbd91ada3a985408586c46568c74a292fa3a0ce805bc5a51798a3b9d623
+EBUILD botan-3.0.0.ebuild 4498 BLAKE2B 30e45b2db6c23184e22cd957553203b2a0dc578241a9cbaf114be2d257a1f8db9e045e80d3d8c6ee9f9ee941f8de1279a14628508cc51e0eba327a5ef285e8ef SHA512 de7a45e5e2b215216bddb1e902a692981faf9f434b9b0d9c32fbac4ba14b5b251d9176c4c3a3ce3eab241b28570c7a3d1ce3ea8f73ef61e500453b468bcd9aad
 MISC metadata.xml 587 BLAKE2B 8d46466fee633fda0f81549a6e512e4ef5963eda31d7c882cee2fe2bfae8b0379509f046d0bdfdb1fe9481eea0585f1754753ed6b509c4f922b8fbf9ae089f39 SHA512 258e04098b9db5821a66e38d02ffb195b57378621fd2a549c8892744cf257be857ebf75c8e4a2f041cd267f07c2f1c3a5fca8df61db0538d8282507cf03a029d
diff --git a/dev-libs/botan/botan-3.0.0.ebuild b/dev-libs/botan/botan-3.0.0.ebuild
new file mode 100644
index 000000000000..79bf305f90f5
--- /dev/null
+++ b/dev-libs/botan/botan-3.0.0.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/botan.asc
+inherit edo python-r1 toolchain-funcs verify-sig
+
+MY_P="Botan-${PV}"
+DESCRIPTION="C++ crypto library"
+HOMEPAGE="https://botan.randombit.net/"
+SRC_URI="https://botan.randombit.net/releases/${MY_P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://botan.randombit.net/releases/${MY_P}.tar.xz.asc )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD-2"
+# New major versions are parallel-installable
+SLOT="$(ver_cut 1)/$(ver_cut 1-2)" # soname version
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~ppc-macos"
+IUSE="doc boost bzip2 lzma python static-libs sqlite test tools zlib"
+RESTRICT="!test? ( test )"
+
+CPU_USE=(
+	cpu_flags_arm_{aes,neon}
+	cpu_flags_ppc_altivec
+	cpu_flags_x86_{aes,avx2,popcnt,rdrand,sha,sse2,ssse3,sse4_1,sse4_2}
+)
+
+IUSE+=" ${CPU_USE[@]}"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# NOTE: Boost is needed at runtime too for the CLI tool.
+DEPEND="
+	boost? ( dev-libs/boost:= )
+	bzip2? ( >=app-arch/bzip2-1.0.5:= )
+	lzma? ( app-arch/xz-utils:= )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3= )
+	zlib? ( >=sys-libs/zlib-1.2.3:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_any_dep '
+		doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	')
+	verify-sig? ( sec-keys/openpgp-keys-botan )
+"
+
+# NOTE: Considering patching Botan?
+# Please see upstream's guidance:
+# https://botan.randombit.net/handbook/packaging.html#minimize-distribution-patches
+
+python_check_deps() {
+	use doc || return 0
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	python_setup
+
+	local disable_modules=(
+		$(usev !boost 'boost')
+	)
+
+	if [[ -z "${DISABLE_MODULES}" ]] ; then
+		elog "Disabling module(s): ${disable_modules[@]}"
+	fi
+
+	local chostarch="${CHOST%%-*}"
+
+	# Arch specific wrangling
+	local myos=
+	case ${CHOST} in
+		*-darwin*)
+			myos=darwin
+			;;
+		*)
+			myos=linux
+
+			if [[ ${CHOST} == *hppa* ]] ; then
+				chostarch=parisc
+			elif [[ ${ABI} == sparc64 ]] ; then
+				chostarch="sparc64"
+			elif [[ ${ABI} == sparc32 ]] ; then
+				chostarch="sparc32"
+			fi
+			;;
+	esac
+
+	local pythonvers=()
+	if use python ; then
+		_append() {
+			pythonvers+=( ${EPYTHON/python/} )
+		}
+
+		python_foreach_impl _append
+	fi
+
+	local myargs=(
+		# Intrinsics
+		# TODO: x86 RDSEED (new CPU_FLAGS_X86?)
+		# TODO: POWER Crypto (new CPU_FLAGS_PPC?)
+		$(usev !cpu_flags_arm_aes '--disable-armv8crypto')
+		$(usev !cpu_flags_arm_neon '--disable-neon')
+		$(usev !cpu_flags_ppc_altivec '--disable-altivec')
+		$(usev !cpu_flags_x86_aes '--disable-aes-ni')
+		$(usev !cpu_flags_x86_avx2 '--disable-avx2')
+		$(usev !cpu_flags_x86_popcnt '--disable-bmi2')
+		$(usev !cpu_flags_x86_rdrand '--disable-rdrand')
+		$(usev !cpu_flags_x86_sha '--disable-sha-ni')
+		$(usev !cpu_flags_x86_sse2 '--disable-sse2')
+		$(usev !cpu_flags_x86_ssse3 '--disable-ssse3')
+		$(usev !cpu_flags_x86_sse4_1 '--disable-sse4.1')
+		$(usev !cpu_flags_x86_sse4_2 '--disable-sse4.2')
+
+		# HPPA's GCC doesn't support SSP (presumably due to stack direction)
+		$(usev hppa '--without-stack-protector')
+
+		$(use_with boost)
+		$(use_with bzip2)
+		$(use_with doc documentation)
+		$(use_with doc sphinx)
+		$(use_with lzma)
+		$(use_enable static-libs static-library)
+		$(use_with sqlite sqlite3)
+		$(use_with zlib)
+
+		--cpu=${chostarch}
+		--docdir=share/doc
+		--disable-modules=$(IFS=","; echo "${disable_modules[*]}")
+		--distribution-info="Gentoo ${PVR}"
+		--libdir="$(get_libdir)"
+
+		# Don't install Python bindings automatically
+		# (do it manually later in the right place)
+		# bug #723096
+		--no-install-python-module
+
+		--os=${myos}
+		--prefix="${EPREFIX}"/usr
+		--with-endian="$(tc-endian)"
+		--with-python-version=$(IFS=","; echo "${pythonvers[*]}")
+	)
+
+	local build_targets=(
+		shared
+		$(usev static-libs static)
+		$(usev tools cli)
+		$(usev test tests)
+	)
+
+	myargs+=(
+		--build-targets=$(IFS=","; echo "${build_targets[*]}")
+	)
+
+	if use elibc_glibc && use kernel_linux ; then
+		myargs+=(
+			--with-os-features=getrandom,getentropy
+		)
+	fi
+
+	tc-export AR CC CXX
+
+	edo ${EPYTHON} configure.py --verbose "${myargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}" ./botan-test || die "Validation tests failed"
+}
+
+src_install() {
+	default
+
+	# Manually install the Python bindings (bug #723096)
+	if use python ; then
+		python_foreach_impl python_domodule src/python/botan2.py
+	fi
+}