gentoo resync : 29.12.2022

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-lang/luajit/luajit-2.1.0_beta3_p20220613.ebuild b/dev-lang/luajit/luajit-2.1.0_beta3_p20220613.ebuild
new file mode 100644
index 000000000000..e5985feb3a90
--- /dev/null
+++ b/dev-lang/luajit/luajit-2.1.0_beta3_p20220613.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GIT_COMMIT=0065cff7e0222c234b75a71e72b8883df5d000c2
+
+inherit pax-utils toolchain-funcs
+
+MY_PV="$(ver_cut 1-5)"
+MY_PV="${MY_PV/_beta/-beta}"
+MY_P="LuaJIT-${MY_PV}"
+
+DESCRIPTION="Just-In-Time Compiler for the Lua programming language"
+HOMEPAGE="https://luajit.org/"
+SRC_URI="https://luajit.org/download/${MY_P}.tar.gz"
+SRC_URI="https://github.com/LuaJIT/LuaJIT/archive/${GIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+# this should probably be pkgmoved to 2.0 for sake of consistency.
+SLOT="2/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 -hppa ~ppc -riscv -sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="lua52compat static-libs"
+
+S="${WORKDIR}/LuaJIT-${GIT_COMMIT}"
+
+_emake() {
+	emake \
+		Q= \
+		PREFIX="${EPREFIX}/usr" \
+		MULTILIB="$(get_libdir)" \
+		DESTDIR="${D}" \
+		CFLAGS="" \
+		LDFLAGS="" \
+		HOST_CC="$(tc-getBUILD_CC)" \
+		HOST_CFLAGS="${BUILD_CPPFLAGS} ${BUILD_CFLAGS}" \
+		HOST_LDFLAGS="${BUILD_LDFLAGS}" \
+		STATIC_CC="$(tc-getCC)" \
+		DYNAMIC_CC="$(tc-getCC) -fPIC" \
+		TARGET_LD="$(tc-getCC)" \
+		TARGET_CFLAGS="${CPPFLAGS} ${CFLAGS}" \
+		TARGET_LDFLAGS="${LDFLAGS}" \
+		TARGET_AR="$(tc-getAR) rcus" \
+		BUILDMODE="$(usex static-libs mixed dynamic)" \
+		TARGET_STRIP="true" \
+		INSTALL_LIB="${ED}/usr/$(get_libdir)" \
+		"$@"
+}
+
+src_compile() {
+	tc-export_build_env
+	_emake XCFLAGS="$(usex lua52compat "-DLUAJIT_ENABLE_LUA52COMPAT" "")"
+}
+
+src_install() {
+	_emake install
+dosym luajit-2.1.0-beta3 /usr/bin/luajit
+	pax-mark m "${ED}/usr/bin/luajit-${MY_PV}"
+
+	HTML_DOCS="doc/." einstalldocs
+}