gentoo auto-resync : 21:04:2024 - 12:05:28

4 files changed, 185 insertions, 3 deletions

diff --git a/dev-embedded/libftdi/Manifest b/dev-embedded/libftdi/Manifest
index a7e1f908a757..940562e6c00d 100644
--- a/dev-embedded/libftdi/Manifest
+++ b/dev-embedded/libftdi/Manifest
@@ -5,6 +5,8 @@ AUX libftdi-1.5-tests-no-cxx.patch 1017 BLAKE2B ff3e05ae2cc48a023c74142f986159f6
 DIST libftdi-0.20.tar.gz 423570 BLAKE2B f0aa420a704e18c4257b99a4593dbaf46a15806d980b24909fe8678b36e74b568cd5915db1e14f8b904541334fbf3d18f069dc479a0bf66b2ea8e113611cb82b SHA512 540e5eb201a65936c3dbabff70c251deba1615874b11ff27c5ca16c39d71c150cf61758a68b541135a444fe32ab403b0fba0daf55c587647aaf9b3f400f1dee7
 DIST libftdi1-1.5.tar.bz2 116297 BLAKE2B 460ab93026e14a452e31fcc6930d305638fdc0ed06cb44fb9d50ad8f80199b17057d2f48a27b8295b43b956934289c872a2ef1ddb7f93fa93c6816511ef7607d SHA512 c525b2ab6aff9ef9254971ae7d57f3549a36a36875765c48f947d52532814a2a004de1232389d4fe824a8c8ab84277b08427308573476e1da9b7db83db802f6f
 EBUILD libftdi-0.20-r2.ebuild 1934 BLAKE2B 33de7434c3034e134dd8dbd6aabf5ebff8749625b44506025561f7669002026c3d0381ed9addb28b3edfcc32dc86855ec7580fc35ffe08eddea389a523a607e3 SHA512 5cf7dc0ef8f0b905dd2cdad429c38d2ddc74dad99629113013d866de278b70e33ba008730222926fe97cfecc3004dbe00e1ce577f105c171527f8d146dfa9b36
+EBUILD libftdi-0.20-r3.ebuild 1949 BLAKE2B d121a2cfe8f8295a4752eeca101d350a885af7d0c2375227b809c40ad13b74bab6a3920976ee2d1fe4507d90b8b12f5b7430084ec7f26f9ef5a7a6241413156a SHA512 04448c65a8de88ad771ddf34a3ae2c2141f0b188a1b3bdfc769f81e62f8a07f7fae8fcd73f620d49004243025d0b56fcc9c4a3bdc7d202e90df6afc597865454
 EBUILD libftdi-1.5-r5.ebuild 1946 BLAKE2B 55d8e7a04218032ea30f68fb0e8d8defd3473252ca6e0680e14e5fa5bf8d0a3dab96f9ff8fd855299d3cb1a442bded5d38c3c1c319262f0b98da95483fc6622a SHA512 66a6412fa2eee65872235f45684c2f3f09caaca07251a9f46ed3df4ae947bad7f3e56143ed32cc925c3ba04cb17d92ae80228149b943411c9be7d03b5dfd3286
-EBUILD libftdi-9999.ebuild 1914 BLAKE2B aaf4e082978649808782ac0e1537b5d4e53a75a5ec0e9e0546e9e31afb7da2c216d1baf1fbb0bc8168c33adf22872f9687afe06ecf9a97b776f3c5455671f4b1 SHA512 5f5b9b107ac5e38f68b65efcfb953ac2273375c46f576e3ae5f92b77d3956b4d01227eca1a5e226990a9f65aa2a48800538f28103c7936394e5864e552962faa
+EBUILD libftdi-1.5-r6.ebuild 1961 BLAKE2B bba0fa29067f593407d08550b60564f846637d6d9574cbd1b1a5fc3d0bf986b81c4c7b1e571349a673a88a7ce42e58b8e07e1e52705c44dd7ae053176ee55be4 SHA512 19c2b17c7208d4c736856d098cfce5203d56beeb76622d6c2b6717f9c4ba97d2a4bc1500580b24a73969d16095780ddede67ef588b67cd446fd7c8e20abbdbe8
+EBUILD libftdi-9999.ebuild 1922 BLAKE2B 2dcd66ae7692b36455886598ddfe4bafe9ed9214a286d9dff7666672ee6b044c1d0e5f634546c00570ed918581cefd4c6c2621a933cd820946c50c513177c7ce SHA512 118f30671a56383ae22c5e943d078b9a450f430ad418bb9f1190f4cd60f0cebea71e1f34f7030f38b866735d9ac941b17c30c3c2d3b6a1941a774f4117856b04
 MISC metadata.xml 318 BLAKE2B c2c9ab83d57a082ed6608367f53f0f9420056c909d4ee50641da5b8f12b6a6ca996740fbdcadb0fa08460cb0cbef36dbedfaaf98acaea3eeeeee6afcf7724f54 SHA512 313b5c5dfcf5feb7dc8e41c1cb74939619451cb0747c1a281c9a0e763d26e0850a43e05d8fd2a836389bd75c2a4f153b80986e11be8171e9d93ca234f9df05f2
diff --git a/dev-embedded/libftdi/libftdi-0.20-r3.ebuild b/dev-embedded/libftdi/libftdi-0.20-r3.ebuild
new file mode 100644
index 000000000000..da4a55f0c65e
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-0.20-r3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake python-single-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="cxx doc examples python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	virtual/libusb:0
+	cxx? ( dev-libs/boost )
+	doc? ( !dev-embedded/libftdi:1[doc] )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( app-text/doxygen )
+	python? ( >=dev-lang/swig-4.2.0 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-cmake-include.patch
+	"${FILESDIR}"/${P}-cmake-version.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if use python; then
+		sed -i \
+			-e "s:[$]{PYTHON_LIB_INSTALL}/../site-packages:$(python_get_sitedir):" \
+			bindings/CMakeLists.txt || die
+	fi
+	sed -i \
+		-e '/SET(LIB_SUFFIX /d' \
+		CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	use python && python_optimize
+	dodoc ChangeLog README
+
+	if use doc ; then
+		# Clean up man pages with too generic names. #356369
+		rm -vf "${BUILD_DIR}"/doc/man/man3/{_,usb_,deprecated}* || die
+
+		doman "${BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${BUILD_DIR}"/doc/html
+	fi
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/${PN}.a || die
+}
diff --git a/dev-embedded/libftdi/libftdi-1.5-r6.ebuild b/dev-embedded/libftdi/libftdi-1.5-r6.ebuild
new file mode 100644
index 000000000000..267cb1a06ce6
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.5-r6.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake python-single-r1
+
+MY_P="${PN}1-${PV}"
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+	PATCHES=(
+		"${FILESDIR}"/${P}-tests-no-cxx.patch
+		"${FILESDIR}"/${P}-cmake-cxx.patch
+	)
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="1"
+IUSE="cxx doc examples python test tools"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	doc? ( !dev-embedded/libftdi:0[doc] )
+	python? ( ${PYTHON_DEPS} )
+	tools? ( dev-libs/confuse:= )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/boost )
+"
+BDEPEND="
+	doc? ( app-text/doxygen )
+	python? ( >=dev-lang/swig-4.2.0 )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DBUILD_TESTS=$(usex test)
+		-DFTDI_EEPROM=$(usex tools)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+		-DSTATICLIBS=OFF
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/test" || die
+	LD_LIBRARY_PATH="${BUILD_DIR}/src" ./test_libftdi1 -l all || die
+}
+
+src_install() {
+	cmake_src_install
+
+	use python && python_optimize
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up man pages with too generic names. #356369
+		rm -vf "${BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${BUILD_DIR}"/doc/html
+	fi
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}
diff --git a/dev-embedded/libftdi/libftdi-9999.ebuild b/dev-embedded/libftdi/libftdi-9999.ebuild
index bb804f1f7033..0430681351f7 100644
--- a/dev-embedded/libftdi/libftdi-9999.ebuild
+++ b/dev-embedded/libftdi/libftdi-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_COMPAT=( python3_{10..12} )
 inherit cmake python-single-r1
 
 MY_P="${PN}1-${PV}"
@@ -42,7 +42,7 @@ DEPEND="${RDEPEND}
 "
 BDEPEND="
 	doc? ( app-text/doxygen )
-	python? ( dev-lang/swig )
+	python? ( >=dev-lang/swig-4.2.0 )
 "
 
 pkg_setup() {